C_IHBFeeRejectedEmail

@AbapCatalog.sqlViewName: 'CIHBFEEEML4'
@EndUserText.label: 'IHB Fee Email Template Data Provider'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType : #CONSUMPTION
@ObjectModel.supportedCapabilities:[ #OUTPUT_EMAIL_DATA_PROVIDER ]
@Metadata.ignorePropagatedAnnotations:true
define view C_IHBFeeRejectedEmail
  as select from           I_WorkflowTask           as _Workflowtask
    join                   I_WorkflowTaskApplObject as _WorkflowTaskApplObject    on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                                  and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                                  and _WorkflowTaskApplObject.TechnicalWrkflwObjectType     = '/PF1/CL_IHB_FEE_WORKFLOW'
                                                                                  and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
  //    to get approver's comments from workitem log

    left outer to one join I_WorkflowTaskApplObject as _WorkflowTaskApplObject_WI on  _WorkflowTaskApplObject_WI.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                                  and _WorkflowTaskApplObject_WI.WorkflowObjectRole            = '99'
                                                                                  and _WorkflowTaskApplObject_WI.TechnicalWrkflwObjectType     = 'WORKINGWI'
                                                                                  and _WorkflowTaskApplObject_WI.TechnicalWrkflwObjectCategory = 'BO'
    left outer to one join I_WorkflowTask           as _WorkflowTask_WI           on _WorkflowTask_WI.WorkflowTaskInternalID = _WorkflowTaskApplObject_WI.TechnicalWrkflwObject
    join                   R_IHBMasterDataObjectTP  as _IHBMasterDataObjectTP     on  _WorkflowTaskApplObject.TechnicalWrkflwObject =  bintohex(
      _IHBMasterDataObjectTP.IHBObjectReferenceUUID
    )
                                                                                  and _IHBMasterDataObjectTP.IHBReleaseStatus       <> '02'
  association [0..1] to I_WorkflowTaskURL as _WorkflowTaskURL on $projection.WorkflowTaskInternalID = _WorkflowTaskURL.WorkflowTaskInternalID
  association [0..1] to I_User            as _User            on $projection.IHBObjectReleasedByUser = _User.UserID
{
  key _Workflowtask.WorkflowTaskInternalID,
      _IHBMasterDataObjectTP.IHBBankArea,
      _IHBMasterDataObjectTP.IHBObjectLevel,
      _IHBMasterDataObjectTP._IHBObjectLevel._IHBObjectLevelT[1:Language = $session.system_language ].IHBObjectLevelText,
      _IHBMasterDataObjectTP._IHBAccount.IHBAccountNumber,
      _IHBMasterDataObjectTP._IHBAccount._IHBAccountText[1:IHBAccountLanguage = $session.system_language ].IHBAccountDescription,
      _IHBMasterDataObjectTP._IHBGroupType.InhouseBankGroupID,
      _IHBMasterDataObjectTP._IHBGroupType._IHBGroupTypeText[1:IHBGroupLanguage = $session.system_language ].IHBGroupDescription,

      case _IHBMasterDataObjectTP.IHBObjectLevel
      when '01' then concat_with_space('Single Fee For Account', _IHBMasterDataObjectTP._IHBAccount.IHBAccountNumber, 1 ) //Single

      when '02' then concat_with_space('Group Fee', _IHBMasterDataObjectTP._IHBGroupType.InhouseBankGroupID, 1 ) //Group

      when '03' then concat_with_space('Bank Area Fee', _IHBMasterDataObjectTP.IHBBankArea, 1 ) //Bank area

      end                                                                                         as IHBObjectEmailHeaderText,

      case _IHBMasterDataObjectTP.IHBObjectLevel
      when '01' then concat_with_space('Account:', _IHBMasterDataObjectTP._IHBAccount.IHBAccountNumber, 1 ) //Single

      when '02' then concat_with_space('Group:', _IHBMasterDataObjectTP._IHBGroupType.InhouseBankGroupID, 1 ) //Group

      end                                                                                         as IHBObjectLevelEmailText,

      _IHBMasterDataObjectTP.IHBObjectReleaseDateTime                                             as IHBObjectReleaseDateTime,

      cast(tstmp_to_dats( IHBObjectReleaseDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as IHBObjectReleaseDate,
      cast(tstmp_to_tims( IHBObjectReleaseDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as IHBObjectReleaseTime,

      _IHBMasterDataObjectTP.IHBObjectReleasedByUser                                              as IHBObjectReleasedByUser,
      case _IHBMasterDataObjectTP._ReleasedBy.UserDescription
        when '' then IHBObjectReleasedByUser
        else _IHBMasterDataObjectTP._ReleasedBy.UserDescription
       end                                                                                        as IHBObjectReleasedByUserText,

      _WorkflowTask_WI._WorkflowTaskResult.WorkflowTaskResultComment
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_IHBACCOUNTCOMPOSITE",
"I_IHBACCOUNTT",
"I_IHBGROUPTYPE",
"I_IHBGROUPTYPETEXT",
"I_IHBOBJECTLEVEL",
"I_IHBOBJECTLEVELT",
"I_USER",
"I_WORKFLOWTASK",
"I_WORKFLOWTASKAPPLOBJECT",
"I_WORKFLOWTASKRESULT",
"R_IHBMASTERDATAOBJECTTP"
],
"ASSOCIATED":
[
"I_USER",
"I_WORKFLOWTASKURL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/