C_GLDisplayItemChangeLog

@AbapCatalog.sqlViewName: 'CGLITEMCHGLOG'
@EndUserText.label: 'Display G/L Item ChangeLog Ovw'
@AbapCatalog.compiler.compareFilter: true
@Metadata.ignorePropogatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

@Consumption.dbHints: ['NO_SUBPLAN_SHARING','USE_OLAP_PLAN','NO_JOIN_THRU_JOIN','NO_CYCLIC_JOIN','NO_JOIN_THRU_AGGR']

@VDM.viewType: #CONSUMPTION

@UI.presentationVariant: [{
    qualifier: 'presentVar',
  sortOrder: [
    { by: 'LastChangeDate', direction: #DESC },
    { by: 'LastChangeTime', direction: #DESC }

    ]
    }]

define view C_GLDisplayItemChangeLog
  with parameters
//    @Consumption.hidden: true

//    @Environment.systemField: #SYSTEM_DATE

//    P_KeyDate    : vdm_v_key_date,

    @Consumption.hidden: true
    @Consumption.derivation: {
      lookupEntity : 'P_GLFiscalYearByKeyDate',
      resultElement : 'FiscalYear',
      binding : [
      {
        targetParameter : 'P_KeyDate',
        type :  #SYSTEM_FIELD,
        value : '#SYSTEM_DATE'
      }]
    }
    P_FiscalYear : gjahr
  as select from I_JournalEntryHistory
{
      @Consumption.semanticObject: 'AccountingJournalList'
      @UI.identification: {
        importance: #HIGH,
        type: #FOR_INTENT_BASED_NAVIGATION,
        semanticObjectAction: 'displayAuditJournal'
      }
  key CompanyCode,
  key Ledger,
      //      GLAccount,

  key AccountingDocument,
      @UI.lineItem:[{position: 40}]
  key cast ('' as abap.char(50)) as FreeDefinedAttribute01Label,
      @UI.lineItem:[{position: 10}]
      //      cast ('' as abap.char(31))       as GLAccountInfo,

  key cast ('' as abap.char(25)) as JournalEntryItemText,
      @UI.lineItem:[{position: 20}]
  key UserName,
      @UI.lineItem:[{position: 30}]
  key cast ('' as abap.char(30)) as FreeDefinedAttribute02Label,
      @UI.lineItem:[{position: 60}]
  key cast ('' as abap.char(20)) as LastChangeDateYearMonthName,
      @UI.lineItem:[{position: 50}]
  key cast ('' as abap.char(60)) as DatabaseTableFieldText,

  key FiscalYear,
  key DatabaseTable,
  key DatabaseTableField,
  key ChangeDocument,
  key ChangeDocTableKey,
  key AccountingDocumentItem,
      LastChangeDate,
      LastChangeTime,
      NewFieldContent,
      OldFieldContent
}
where
      CompanyCode        <> ''
  and AccountingDocument <> ''
  and Ledger             <> ''
  and FiscalYear         =  :P_FiscalYear
group by
  CompanyCode,
  Ledger,
  AccountingDocument,
  LastChangeDate,
  LastChangeTime,
  NewFieldContent,
  OldFieldContent,
  UserName,
  DatabaseTableField,
  DatabaseTable,
  FiscalYear,
  ChangeDocument,
  ChangeDocTableKey,
  AccountingDocumentItem
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYHISTORY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/