@AbapCatalog.sqlViewName: 'CGLACCTLNITIMPCT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'GL Accounting Impact'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.semanticKey: ['SourceLedger', 'CompanyCode', 'FiscalYear', 'AccountingDocument', 'LedgerGLLineItem', 'Ledger' ]
@Metadata.allowExtensions: true
////// Presentation variants ///
@UI.presentationVariant: [
{
text: '',
qualifier: '',
includeGrandTotal: true,
sortOrder: [
{ by: 'CompanyCode', direction: #ASC},
{ by: 'Ledger', direction: #ASC},
{ by: 'FiscalYear', direction: #ASC }
]
}
]
define view C_GLAccountLineItemImpact
as select from I_GLAccountLineItem as GLAccountLineItem
association [1..1] to I_GLAccountLineItem as _GLAccountLineItem on $projection.Ledger = _GLAccountLineItem.Ledger
and $projection.SourceLedger = _GLAccountLineItem.SourceLedger
and $projection.CompanyCode = _GLAccountLineItem.CompanyCode
and $projection.FiscalYear = _GLAccountLineItem.FiscalYear
and $projection.AccountingDocument = _GLAccountLineItem.AccountingDocument
and $projection.LedgerGLLineItem = _GLAccountLineItem.LedgerGLLineItem
association [1..1] to I_GLAccountInChartOfAccounts as _GLAccountInChartOfAccounts on $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
and $projection.GLAccount = _GLAccountInChartOfAccounts.GLAccount
association [1..1] to E_JournalEntryItem as _Extension on $projection.SourceLedger = _Extension.SourceLedger
and $projection.CompanyCode = _Extension.CompanyCode
and $projection.FiscalYear = _Extension.FiscalYear
and $projection.AccountingDocument = _Extension.AccountingDocument
and $projection.LedgerGLLineItem = _Extension.LedgerGLLineItem
{
@ObjectModel.text.element: ['SourceLedgerName']
@UI.textArrangement: #TEXT_LAST
key SourceLedger,
@UI.selectionField.position: 10
@UI.lineItem.position: 40
@ObjectModel.text.element: ['CompanyCodeName']
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_CompanyCodeStdVH', element : 'CompanyCode' } }]
key CompanyCode,
@UI.lineItem.position: 60
key FiscalYear,
@UI.selectionField.position: 20
@UI.lineItem.position: 10
@Consumption.semanticObject: 'AccountingDocument'
@Consumption.filter.hidden: true
key AccountingDocument,
@UI.lineItem.position: 20
key LedgerGLLineItem,
@UI.selectionField.position: 30
@UI.lineItem.position: 50
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_LedgerStdVH', element : 'Ledger' } }]
@ObjectModel.text.element: ['LedgerName']
@UI.textArrangement: #TEXT_LAST
key Ledger,
@ObjectModel.text.element: ['GLAccountName']
@UI.textArrangement: #TEXT_LAST
@UI.lineItem.position: 30
@Consumption.semanticObject: 'GLAccount'
@UI.identification:
{
importance: #MEDIUM,
type: #WITH_INTENT_BASED_NAVIGATION, //Specify the intent-based navigation
semanticObjectAction: 'display' //Specify the Semantic Object Action
}
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_GLAccountStdVH', element : 'GLAccount' } }]
GLAccount,
cast (_GLAcctInChartOfAccountsText[1:Language = $session.system_language ].GLAccountName as fin_aci_accname ) as GLAccountName,
@UI.hidden: true
_GLAcctInChartOfAccountsText[1:Language = $session.system_language ].GLAccountLongName,
PostingDate,
GLAccountType,
@Consumption.filter.selectionType:#INTERVAL
CreationDateTime,
cast (SourceReferenceDocument as fis_aci_awref) as SourceReferenceDocument,
cast (SourceReferenceDocumentType as fins_aci_src_awtyp) as SourceReferenceDocumentType,
@UI.hidden: true
DebitCreditCode,
@ObjectModel.text.element: ['AccountingDocumentTypeName']
@UI.textArrangement: #TEXT_LAST
AccountingDocumentType,
@UI.hidden: true
cast (_AccountingDocumentType._Text[1:Language = $session.system_language ].AccountingDocumentTypeName as fin_aci_doctpname) as AccountingDocumentTypeName,
_CompanyCodeText.CompanyCodeName,
//currencies
@UI.hidden: true
cast (CompanyCodeCurrency as fins_aci_currh) as CompanyCodeCurrency,
@UI.hidden: true
TransactionCurrency,
@UI.hidden: true
GlobalCurrency,
@UI.hidden: true
cast (BalanceTransactionCurrency as fins_aci_currt) as BalanceTransactionCurrency,
@UI.hidden: true
FreeDefinedCurrency1,
@UI.hidden: true
FreeDefinedCurrency2,
@UI.hidden: true
FreeDefinedCurrency3,
@UI.hidden: true
FreeDefinedCurrency4,
@UI.hidden: true
FreeDefinedCurrency5,
@UI.hidden: true
FreeDefinedCurrency6,
@UI.hidden: true
FreeDefinedCurrency7,
@UI.hidden: true
FreeDefinedCurrency8,
WBSElementInternalID,
@ObjectModel.text.element: ['WBSDescription']
@UI.textArrangement: #TEXT_LAST
cast( WBSElement as fis_wbs_no_conv preserving type ) as WBSElement,
_WBSElementBasicData.WBSDescription,
@ObjectModel.text.element: ['CostCenterDescription']
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_CostCenterStdVH', element : 'CostCenter' } }]
CostCenter,
@UI.hidden: true
_CurrentCostCenter._Text[ 1:Language = $session.system_language].CostCenterDescription,
@ObjectModel.text.element: ['ProfitCenterLongName']
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_ProfitCenterStdVH', element : 'ProfitCenter' } }]
ProfitCenter,
@UI.hidden: true
_CurrentProfitCenter._Text[ 1:Language = $session.system_language].ProfitCenterLongName,
AssignmentReference,
ReferenceDocument,
@ObjectModel.text.element: ['FundName']
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_FundStdVH', element : 'Fund' } }]
Fund, //RFUND
@UI.hidden: true
_Fund._Text[ 1:Language = $session.system_language].FundName,
@ObjectModel.text.element: ['BudgetPeriodName']
@UI.textArrangement: #TEXT_LAST
BudgetPeriod, //RBUDGET_PD
@UI.hidden: true
_BudgetPeriod._Text[ 1:Language = $session.system_language].BudgetPeriodName,
@ObjectModel.text.element: ['GrantName']
@UI.textArrangement: #TEXT_LAST
GrantID, //rgrant_nbr
@UI.hidden: true
cast ( _Grant._Text[ 1:Language = $session.system_language].GrantName as fins_aci_grant_name preserving type ) as GrantName,
//asset accounting
@ObjectModel.text.element: ['MasterFixedAssetDescription']
@UI.textArrangement: #TEXT_LAST
cast( MasterFixedAsset as fis_aci_anln1 preserving type ) as MasterFixedAsset,
@UI.hidden: true
_MasterFixedAssetText.MasterFixedAssetDescription,
@ObjectModel.text.element: ['FixedAssetDescription']
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_FixedAssetStdVH', element : 'FixedAsset' } }]
FixedAsset,
@UI.hidden: true
_FixedAssetText.FixedAssetDescription,
@UI.hidden: true
_Ledger._Text[ 1:Language = $session.system_language].LedgerName,
@UI.hidden: true
cast ( _SourceLedger._Text[ 1:Language = $session.system_language].LedgerName as fin_aci_src_ledger_name preserving type ) as SourceLedgerName,
AssetTransactionType,
@ObjectModel.text.element: ['SubLedgerAcctLineItemTypeName']
@UI.textArrangement: #TEXT_LAST
SubLedgerAcctLineItemType,
@UI.hidden: true
cast ( _SubLedgerAccLineItemType._Text[ 1:Language = $session.system_language].SubLedgerAcctLineItemTypeName as fin_aci_slalitype_desc preserving type ) as SubLedgerAcctLineItemTypeName,
AssetClass,
@ObjectModel.text.element: ['OriginProductName']
@UI.textArrangement: #TEXT_LAST
OriginProduct,
OriginCostCenter,
OriginCostCtrActivityType,
VarianceOriginGLAccount,
@UI.hidden: true
cast ( _OriginProduct._Text[ 1:Language = $session.system_language].ProductName as fin_aci_orig_prod_name preserving type ) as OriginProductName,
LedgerFiscalYear,
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_SegmentStdVH', element : 'Segment' } }]
Segment,
//1
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInCompanyCodeCurrency
else 0
end as fis_aci_hsl_cr preserving type ) as CreditAmountInCoCodeCrcy,
//2
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInCompanyCodeCurrency
else 0
end as fis_aci_hsl_dr preserving type ) as DebitAmountInCoCodeCrcy,
//3
@Semantics.amount.currencyCode: 'GlobalCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInGlobalCurrency
else 0
end as fis_aci_ksl_cr preserving type ) as CreditAmountInGlobalCrcy,
//4
@Semantics.amount.currencyCode: 'GlobalCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInGlobalCurrency
else 0
end as fis_aci_ksl_dr preserving type ) as DebitAmountInGlobalCrcy,
//5
@Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInBalanceTransacCrcy
else 0
end as fis_aci_tsl_cr preserving type ) as CreditAmountInBalanceTransCrcy,
//6
@Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInBalanceTransacCrcy
else 0
end as fis_aci_tsl_dr preserving type ) as DebitAmountInBalanceTransCrcy,
//7
@Semantics.amount.currencyCode: 'TransactionCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInTransactionCurrency
else 0
end as fis_aci_wsl_cr preserving type ) as CreditAmountInTransCrcy,
//8
@Semantics.amount.currencyCode: 'TransactionCurrency'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInTransactionCurrency
else 0
end as fis_aci_wsl_dr preserving type ) as DebitAmountInTransCrcy,
//Amounts in Free Defined Currencies
@Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency1
else 0
end as fis_aci_osl_cr preserving type ) as CreditAmountInFreeDfndCrcy1,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency1
else 0
end as fis_aci_osl_dr preserving type ) as DebitAmountInFreeDfndCrcy1,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency2
else 0
end as fis_aci_vsl_cr preserving type ) as CreditAmountInFreeDfndCrcy2,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency2
else 0
end as fis_aci_vsl_dr preserving type ) as DebitAmountInFreeDfndCrcy2,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency3
else 0
end as fis_aci_bsl_cr preserving type ) as CreditAmountInFreeDfndCrcy3,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency3
else 0
end as fis_aci_bsl_dr preserving type ) as DebitAmountInFreeDfndCrcy3,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency4
else 0
end as fis_aci_csl_cr preserving type ) as CreditAmountInFreeDfndCrcy4,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency4
else 0
end as fis_aci_csl_dr preserving type ) as DebitAmountInFreeDfndCrcy4,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency5
else 0
end as fis_aci_dsl_cr preserving type ) as CreditAmountInFreeDfndCrcy5,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency5
else 0
end as fis_aci_dsl_dr preserving type ) as DebitAmountInFreeDfndCrcy5,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency6
else 0
end as fis_aci_esl_cr preserving type ) as CreditAmountInFreeDfndCrcy6,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency6
else 0
end as fis_aci_esl_dr preserving type ) as DebitAmountInFreeDfndCrcy6,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency7
else 0
end as fis_aci_fsl_cr preserving type ) as CreditAmountInFreeDfndCrcy7,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency7
else 0
end as fis_aci_fsl_dr preserving type ) as DebitAmountInFreeDfndCrcy7,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'H' then -AmountInFreeDefinedCurrency8
else 0
end as fis_aci_gsl_cr preserving type ) as CreditAmountInFreeDfndCrcy8,
@Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
@DefaultAggregation: #SUM
cast ( case
when DebitCreditCode = 'S' then AmountInFreeDefinedCurrency8
else 0
end as fis_aci_gsl_dr preserving type ) as DebitAmountInFreeDfndCrcy8,
@UI.hidden: true
_GLAccountInChartOfAccounts.IsBalanceSheetAccount,
@Consumption.hidden: true
ChartOfAccounts,
//FOR DCL
/* Associations */
@Consumption.hidden: true
_GLAccountLineItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_BUDGETPERIOD",
"I_BUDGETPERIODTEXT",
"I_COMPANYCODE",
"I_COSTCENTER",
"I_COSTCENTERTEXT",
"I_FIXEDASSET",
"I_FUND",
"I_FUNDTEXT",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTLINEITEM",
"I_GLACCOUNTTEXT",
"I_GRANT",
"I_GRANTTEXT",
"I_LEDGER",
"I_LEDGERTEXT",
"I_MASTERFIXEDASSET",
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_PROFITCENTER",
"I_PROFITCENTERTEXT",
"I_SUBLEDGERACCLINEITEMTYPE",
"I_SUBLEDGERACCLINEITEMTYPET",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"E_JOURNALENTRYITEM",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTLINEITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/