C_FldLogsEmptyContainerIDVH

@AbapCatalog.sqlViewName: 'CFLEMPTYCTNVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM: {
viewType: #CONSUMPTION }
@ObjectModel.usageType: {
serviceQuality: #C,
dataClass: #TRANSACTIONAL,
sizeCategory: #L }
@ObjectModel : {
  dataCategory: #VALUE_HELP,
  semanticKey: ['FldLogsContainerID']
  }
@Search.searchable: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Field Logitics for Empty Containers'
@Consumption.ranked: true
@Consumption.valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED
define view C_FldLogsEmptyContainerIDVH
  as select distinct from I_FldLogsShptContainerRecord
  association     to I_FldLogsPlantBasic            as _BasePlant         on $projection.FldLogsCtnCurrentLocation = _BasePlant.SupplyingPlant
  association [1] to I_FldLogsShptCtnCertExpiryDate as _CertificateExpiry on $projection.FldLogsContainerUUID = _CertificateExpiry.FldLogsContainerUUID
{
  key FldLogsContainerUUID,
      @Search: { defaultSearchElement: true,ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @UI.selectionField: [{position: 10 }]
      @EndUserText.label: 'Container ID'
      @UI.lineItem: [{position: 10, label: 'Container ID',importance: #HIGH }]
      @ObjectModel : { text.element: ['FldLogsContainerText'] }
      @UI.textArrangement: #TEXT_FIRST
      FldLogsContainerID,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7,ranking: #LOW }
      @UI.lineItem: [{position: 30,importance: #HIGH }]
      @EndUserText.label: 'Container Type'
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_FldLogsContainerTypeVH'  ,element: 'EquipmentType'}}]
      @ObjectModel : { text.element: ['EquipmentTypeDesc'] }
      @UI.textArrangement: #TEXT_FIRST
      EquipmentType,

      @EndUserText.label: 'Equipment Group'
      EquipmentGroup,
      @EndUserText.label: 'Container Type description'
      _EquipmentTypeText.EquipmentTypeDesc,
      @EndUserText.label: 'Description'
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7,ranking: #LOW }
      @Semantics.text: true
      FldLogsContainerText,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7,ranking: #LOW }
      @UI.selectionField: [{position: 40 }]
      @EndUserText.label: 'Container Category'
      @UI.lineItem: [{position: 20, label: 'Container Category',importance: #HIGH }]
      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_FldLogsContainerCategoryText', element: 'FldLogsContainerCategory' }}]
      @ObjectModel : { text.element: ['FldLogsContainerCategoryText'] }
      @UI.textArrangement: #TEXT_FIRST
      FldLogsContainerCategory,
      @EndUserText.label: 'Container Category description'
      _CtnCategoryText.FldLogsContainerCategoryText,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7,ranking: #LOW }
      @EndUserText.label: 'Container Status'
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_FldLogsShptCtnStatusVH', element: 'FldLogsContainerStatus' } }]
      FldLogsContainerStatus,


      @EndUserText.label: 'Base Plant'
      Plant,

      @EndUserText.label: 'Base Storage Location'
      StorageLocation,

      @UI.selectionField: [{position: 50 }]
      @UI.lineItem: [{position: 50,importance: #HIGH }]
      @EndUserText.label: 'Current Plant'
      @Consumption.valueHelpDefinition: [{entity:{ name: 'C_FldLogsPlantsVH', element: 'Plant' }}]
      FldLogsCtnCurrentLocation,
      @EndUserText.label: 'Current Storage Location'
      FldLogsCtnCurrentStorageLoc,
      @UI.lineItem: [{position: 60,importance: #HIGH }]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7,ranking: #LOW }
      @EndUserText.label: 'Supplier'
      FldLogsContainerOwner,

      @EndUserText.label: 'Expiry Date'
      @UI.lineItem: [{position: 40, label: 'Certificate Expiry Date',importance: #HIGH }]
      _CertificateExpiry.FldLogsCertEndDate

}
where
       FldLogsContainerStatus    = '10' //available container

  and(
       FldLogsCtnCurrentLocation is initial
    or _BasePlant.SupplyingPlant = FldLogsCtnCurrentLocation
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENTTYPETEXT",
"I_FLDLOGSCONTAINERCATEGORYTEXT",
"I_FLDLOGSPLANTBASIC",
"I_FLDLOGSSHPTCONTAINERRECORD",
"I_FLDLOGSSHPTCTNCERTEXPIRYDATE"
],
"ASSOCIATED":
[
"I_FLDLOGSPLANTBASIC",
"I_FLDLOGSSHPTCTNCERTEXPIRYDATE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/