C_FixedAssetUsageObjectTP

@EndUserText.label: 'Fixed Asset Usage Object'
@AccessControl.authorizationCheck: #CHECK

@UI: {
  headerInfo: { typeName: 'Usage Object', typeNamePlural: 'Usage Objects', title: { type: #STANDARD, value: 'FixedAssetUsageObject' } } }

@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@Metadata.allowExtensions: true
@Search.searchable: true

@ObjectModel.representativeKey: 'FixedAssetUsageObject'
@ObjectModel.usageType: {
        serviceQuality: #C,
        sizeCategory: #XL,
        dataClass: #MASTER
}

define root view entity C_FixedAssetUsageObjectTP
  provider contract transactional_query 
  as projection on R_FixedAssetUsageObjectTP
  association [0..*] to C_FixedAssetUsageObjWhereUsd as _UsageObjectWhereUsd on  $projection.CompanyCode           = _UsageObjectWhereUsd.CompanyCode
                                                                             and $projection.FixedAssetUsageObject = _UsageObjectWhereUsd.FixedAssetUsageObject

  association [0..*] to C_FixedAssetUsageObjectRmng  as _UsageObjectRmng     on  $projection.CompanyCode           = _UsageObjectRmng.CompanyCode
                                                                             and $projection.FixedAssetUsageObject = _UsageObjectRmng.FixedAssetUsageObject
{
         @ObjectModel.foreignKey.association: '_CompanyCode'
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
         @Search.defaultSearchElement: true
         @Consumption.semanticObject: 'CompanyCode'
         @ObjectModel.text.element: ['CompanyCodeName']
  key    CompanyCode,
         @Search: {
           defaultSearchElement: true,
           //ranking: #HIGH,

           fuzzinessThreshold: 0.8
         }
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_FixedAssetUsageObjectVH', element: 'FixedAssetUsageObject' }
                                                      ,additionalBinding:  [ { localElement: 'CompanyCode', element:'CompanyCode' }
                                                      ]
                                               }]
  key    FixedAssetUsageObject,

         @Consumption.filter.hidden: true
         @UI.hidden: true
         ChangeDocTableKey,


         @Search: {
           defaultSearchElement: true,
           //ranking: #HIGH,

           fuzzinessThreshold: 0.8
         }

         @Consumption.filter.hidden: true
         FixedAssetUsageObjectDesc,

         @ObjectModel.text.element: ['UnitOfMeasureName']
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
         BaseUnit,

         @ObjectModel.text.element: ['FixedAssetUsageObjLfcycName']
         @Consumption.filter.hidden: true
         FixedAssetUsageObjLfcycSts,

         @Semantics.text: true
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_FxdAstUsageObjectLfcycStsVH', element: 'FixedAssetUsageObjLfcycName' },
                                                   additionalBinding:[{localElement: 'FixedAssetUsageObjLfcycSts', element: 'FixedAssetUsageObjLfcycSts', usage: #FILTER }]
                                                  } ]
         _UsageObjectLifecycleStatus._Text[1:Language = $session.system_language].FixedAssetUsageObjLfcycName,
         
         @Consumption.filter.selectionType:  #SINGLE
         CreationDateTime,

         CreatedByUser,
         
         @Consumption.filter.selectionType:  #SINGLE
         LastChangeDateTime,

         //         DraftLastChangedDateTime,


         LastChangedByUser,

         @Consumption.filter.hidden: true
         _UnitOfMeasure._Text[ 1: Language = $session.system_language ].UnitOfMeasureName,

         @Consumption.filter.hidden: true
         _CompanyCode.CompanyCodeName,

         _CompanyCode,

         _UnitOfMeasure,

         _UsageObjectLifecycleStatus,

         _UsageObjectWhereUsd,


         @ObjectModel.filter.enabled: false
         //@ObjectModel.sort.enabled: false

         _UsageObjectRmng,

         _UsageObjectPeriod : redirected to composition child C_FixedAssetUsageObjectPerdTP,
         _UsageObjectTotal  : redirected to composition child C_FixedAssetUsageObjectTotTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_FXDASTUSAGEOBJECTLFCYCSTS",
"I_FXDASTUSAGEOBJLFCYCSTSTEXT",
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT",
"R_FIXEDASSETUSAGEOBJECTTP"
],
"ASSOCIATED":
[
"C_FIXEDASSETUSAGEOBJECTPERDTP",
"C_FIXEDASSETUSAGEOBJECTRMNG",
"C_FIXEDASSETUSAGEOBJECTTOTTP",
"C_FIXEDASSETUSAGEOBJWHEREUSD",
"I_COMPANYCODE",
"I_FXDASTUSAGEOBJECTLFCYCSTS",
"I_UNITOFMEASURE",
"R_FIXEDASSETUSAGEOBJECTPERDTP",
"R_FIXEDASSETUSAGEOBJECTTOTTP"
],
"BASE":
[
"R_FIXEDASSETUSAGEOBJECTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/