@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'CFIFINSSKFPER'
// @AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Statistical Keyfigures per period'
@Analytics.query: true
@VDM.viewType: #CONSUMPTION
//@ObjectModel.representativeKey: 'FiscalPeriod'
//@Analytics: { dataCategory: #CUBE, dataExtraction.enabled: true }
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
define view C_FinStatisticalKeyFigureItem
with parameters
@Consumption.hidden: true
@Environment.systemField: #APPLICATION_USER
P_BusinessUser: syuname,
@Consumption.hidden: true
@Consumption.derivation: { lookupEntity: 'I_UserSetGetParamForCtrlgArea',
resultElement: 'ControllingArea',
binding: [ { targetElement : 'BusinessUser' , type : #PARAMETER, value : 'P_BusinessUser' } ] }
P_ControllingArea: fis_kokrs
//@Consumption.hidden: true
//@Consumption.derivation: { lookupEntity: 'I_ControllingArea',
// resultElement: 'FiscalYearVariant',
// binding: [{ targetElement : 'ControllingArea' , type : #PARAMETER, value : 'P_ControllingArea' } ]
// }
//P_FiscalYearVariant: fis_periv
as select from I_FinStatisticalKeyFigureItem
{
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: false}
@AnalyticsDetails.query.variableSequence : 10
@AnalyticsDetails.query.axis: #COLUMNS
@AnalyticsDetails.query.totals: #SHOW
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.GLRecordType,
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: false}
@AnalyticsDetails.query.variableSequence : 11
I_FinStatisticalKeyFigureItem.PlanningCategory,
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: true}
@AnalyticsDetails.query.variableSequence : 20
I_FinStatisticalKeyFigureItem.Ledger,
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: true}
@AnalyticsDetails.query.variableSequence : 21
I_FinStatisticalKeyFigureItem.CompanyCode,
//@Consumption.hidden: true
//@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: true, hidden: true}
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: false}
@AnalyticsDetails.query.variableSequence : 30
I_FinStatisticalKeyFigureItem.FiscalYearVariant,
@Consumption.filter: {selectionType: #SINGLE, multipleSelections: false, mandatory: true}
@AnalyticsDetails.query.variableSequence : 31
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.FiscalYear,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false , defaultValue: '001' , defaultValueHigh: '012' }
@AnalyticsDetails.query.variableSequence : 32
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.FiscalPeriod,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.variableSequence : 40
@AnalyticsDetails.query.axis: #ROWS
@AnalyticsDetails.query.totals: #SHOW
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.StatisticalKeyFigure,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.variableSequence : 41
@AnalyticsDetails.query.axis: #COLUMNS
@AnalyticsDetails.query.totals: #SHOW
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.StatisticalKeyFigureCategory,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.variableSequence : 50
@AnalyticsDetails.query.axis: #ROWS
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.Segment,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.variableSequence : 60
@AnalyticsDetails.query.axis: #ROWS
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.ProfitCenter,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.variableSequence : 70
@AnalyticsDetails.query.axis: #ROWS
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.CostCenter,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
@Semantics.unitOfMeasure:true
cast( I_FinStatisticalKeyFigureItem.StatisticalKeyFigQtyUnit as fis_ui_seinh preserving type ) as StatisticalKeyFigQtyUnit,
//-----------------------------------------------------------------//
// the Intermediate Quantities are needed only for calculation
@Consumption.hidden: true
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
I_FinStatisticalKeyFigureItem.IntmdStatisticalKeyFigFixedQty,
@Consumption.hidden: true
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
I_FinStatisticalKeyFigureItem.IntmdStatisticalKeyFigSumQty,
@Consumption.hidden: true
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
I_FinStatisticalKeyFigureItem.StstclKeyFigIntmdActlFixedQty,
@Consumption.hidden: true
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
I_FinStatisticalKeyFigureItem.StstclKeyFigIntmdPlanFixedQty,
@Consumption.hidden: true
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
I_FinStatisticalKeyFigureItem.StstclKeyFigIntmdActlSumQty,
@Consumption.hidden: true
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
I_FinStatisticalKeyFigureItem.StstclKeyFigIntmdPlanSumQty,
//-----------------------------------------------------------------//
// Quantity = Fixed Quantity + Sum Quantity
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigFixedQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails: {
exceptionAggregationSteps: [{ exceptionAggregationBehavior : #LAST,
exceptionAggregationElements: ['FiscalPeriod']
}]
}
@AnalyticsDetails.query.formula : '$projection.IntmdStatisticalKeyFigFixedQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_fixed_smexxx_long ) as StatisticalKeyFigFixedQty,
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigSumQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails: {
exceptionAggregationSteps: [{ exceptionAggregationBehavior : #SUM,
exceptionAggregationElements: ['FiscalPeriod']
}]
}
@AnalyticsDetails.query.formula : '$projection.IntmdStatisticalKeyFigSumQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_sum_smexxx_long ) as StatisticalKeyFigSumQty,
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigSumQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails.query.formula : '$projection.StatisticalKeyFigSumQty + $projection.StatisticalKeyFigFixedQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_smexxx_long ) as StatisticalKeyFigureQuantity,
//-----------------------------------------------------------------//
// Actual Quantity = Actual Fixed Quantity + Actual Sum Quantity
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigFixedQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails: {
exceptionAggregationSteps: [{ exceptionAggregationBehavior : #LAST,
exceptionAggregationElements: ['FiscalPeriod']
}]
}
@AnalyticsDetails.query.formula : '$projection.StstclKeyFigIntmdActlFixedQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_act_fixed_smexxx_long ) as StatisticalKeyFigActlFixedQty,
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigSumQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails: {
exceptionAggregationSteps: [{ exceptionAggregationBehavior : #SUM,
exceptionAggregationElements: ['FiscalPeriod']
}]
}
@AnalyticsDetails.query.formula : '$projection.StstclKeyFigIntmdActlSumQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_act_sum_smexxx_long ) as StatisticalKeyFigActlSumQty,
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigSumQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails.query.formula : '$projection.StatisticalKeyFigActlFixedQty + $projection.StatisticalKeyFigActlSumQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_act_smexxx_long ) as StatisticalKeyFigureActlQty,
//-----------------------------------------------------------------//
// Plan Quantity = Plan Fixed Quantity + Plan Sum Quantity
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigFixedQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails: {
exceptionAggregationSteps: [{ exceptionAggregationBehavior : #LAST,
exceptionAggregationElements: ['FiscalPeriod']
}]
}
@AnalyticsDetails.query.formula : '$projection.StstclKeyFigIntmdPlanFixedQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_pln_fixed_smexxx_long ) as StatisticalKeyFigPlanFixedQty,
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigSumQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails: {
exceptionAggregationSteps: [{ exceptionAggregationBehavior : #SUM,
exceptionAggregationElements: ['FiscalPeriod']
}]
}
@AnalyticsDetails.query.formula : '$projection.StstclKeyFigIntmdPlanSumQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_pln_sum_smexxx_long ) as StatisticalKeyFigPlanSumQty,
//@Consumption.hidden: true
@AnalyticsDetails.query.hidden: true // ==> is available but hidden at start of app
@AnalyticsDetails.query.axis: #COLUMNS
//@EndUserText.label: 'StatisticalKeyFigSumQty'
@DefaultAggregation: #FORMULA
//@Semantics: { quantity : {unitOfMeasure: 'StatisticalKeyFigQtyUnit'} }
@Semantics.quantity.unitOfMeasure: 'StatisticalKeyFigQtyUnit'
@AnalyticsDetails.query.formula : '$projection.StatisticalKeyFigPlanFixedQty + $projection.StatisticalKeyFigPlanSumQty'
cast( cast(1 as abap.quan(23,3)) as fis_ui_pln_smexxx_long ) as StatisticalKeyFigurePlanQty,
//-----------------------------------------------------------------------------------------------
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.FunctionalArea,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.BusinessArea,
@Consumption.filter: {selectionType: #RANGE, multipleSelections: true, mandatory: false}
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.BudgetPeriod,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.OrderID,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.CostCtrActivityType,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
@AnalyticsDetails.query.display: #KEY_TEXT
I_FinStatisticalKeyFigureItem.WBSElementExternalID,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.ControllingBusTransacType,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.AccountAssignmentType,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.ControllingObject,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.ControllingObjectClass,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.OrderCategory,
//@AnalyticsDetails.query.axis: #FREE
//@AnalyticsDetails.query.totals: #SHOW
//I_FinStatisticalKeyFigureItem.ProjectNetwork, // not filled
//
//@AnalyticsDetails.query.axis: #FREE
//@AnalyticsDetails.query.totals: #SHOW
//I_FinStatisticalKeyFigureItem.RelatedNetworkActivity, // not filled
//@AnalyticsDetails.query.axis: #FREE
//@AnalyticsDetails.query.totals: #SHOW
//I_FinStatisticalKeyFigureItem.BusinessProcess, // not in cloud
//
//@AnalyticsDetails.query.axis: #FREE
//@AnalyticsDetails.query.totals: #SHOW
//I_FinStatisticalKeyFigureItem.CostObject, // not in cloud
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.Fund,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.GrantID,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.SalesOrder,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.SalesOrderItem,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.ServiceDocumentType,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.ServiceDocument,
@AnalyticsDetails.query.axis: #FREE
@AnalyticsDetails.query.totals: #SHOW
I_FinStatisticalKeyFigureItem.ServiceDocumentItem
//FISCALYEARPERIOD,
//STATISTICALKEYFIGUREITEM,
//ISSPECIALPERIOD,
//CONTROLLINGAREA,
}
// where ControllingArea = :P_ControllingArea and FiscalYearVariant = :P_FiscalYearVariant ;
where ControllingArea = :P_ControllingArea;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINSTATISTICALKEYFIGUREITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/