C_EntProjectRankingProjectVH

@AbapCatalog: {
  sqlViewName: 'CPPMENTRNKPVH',
  compiler.compareFilter: true
}

@VDM.viewType: #CONSUMPTION
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   usageType: {
     serviceQuality:  #C,  // required due to text search for ProcessingStatus and ProfitCenter  

     sizeCategory:    #L,
     dataClass:       #MIXED
   },
   updateEnabled: false,
   deleteEnabled: false,
   createEnabled: false,
   dataCategory:      #VALUE_HELP,
   representativeKey: 'ProjectUUID',
   semanticKey:       [ 'Project' ]
}

@UI.presentationVariant: [{
    sortOrder: [{ by: 'Project', direction: #ASC }] ,
    requestAtLeast: ['Project']
}]

@Search.searchable: true
@EndUserText.label: 'Ent. Project Ranking Project Value Help'
@Consumption.ranked: true

define view C_EntProjectRankingProjectVH
  as select from I_EnterpriseProject as Project

  association [0..*] to I_ProfitCenterText  as _ProfitCenterText  on  $projection.ControllingArea = _ProfitCenterText.ControllingArea
                                                                  and $projection.ProfitCenter    = _ProfitCenterText.ProfitCenter
                                                                  and _ProfitCenterText.ValidityEndDate   > $session.system_date
                                                                  and _ProfitCenterText.ValidityStartDate < $session.system_date
                                                                  
  association [0..*] to I_EntProjProcessingStatusText as _ProcessingStatusText on $projection.ProcessingStatus = _ProcessingStatusText.DomainValue
                                                                    
{
      @UI.hidden: true
      @ObjectModel: {
          text.element: ['Project']
      }
  key Project.ProjectUUID,

      @EndUserText: {
        label: 'Project',
        quickInfo: 'Project'
      }
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
      Project.Project,


      @EndUserText: {
        label: 'Project Name',
        quickInfo: 'Project Name'
      }
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      Project.ProjectDescription, // ProjectName,


      @Search: {
          defaultSearchElement: true,
          ranking: #LOW,
          fuzzinessThreshold: 0.7
      }
      @EndUserText: {
        label: 'Profit Center',
        quickInfo: 'Profit Center'
      }
      Project.ProfitCenter,

      @Search: {
          defaultSearchElement: true,
          ranking: #LOW,
          fuzzinessThreshold: 0.7
      }
      @UI.hidden: true
      _ProfitCenterText[1: Language = $session.system_language ].ProfitCenterName,

      @EndUserText: {
        label: 'Controlling Area',
        quickInfo: 'Controlling Area'
      }
      @UI.hidden: true
      Project.ControllingArea,

      @UI.hidden: true
      Project.ProcessingStatus,

      @Search: {
      defaultSearchElement: true,
      ranking: #LOW,
      fuzzinessThreshold: 0.7
      }
      @EndUserText: {
        label: 'Processing Status',
        quickInfo: 'Processing Status'
      }
      @UI.hidden: false
      cast ( _ProcessingStatusText[ 1:Language = $session.system_language ].ProcessingStatusText as val_text preserving type ) as ProcessingStatusText,


      // Authorization Related Properties

      @Consumption.hidden: true
      Project.ProjectSummaryTaskUUID,
      @Consumption.hidden: true
      Project.ProjectProfileCode,
      @Consumption.hidden: true
      Project.EnterpriseProjectType,
      @Consumption.hidden: true
      Project.CompanyCode,
      @Consumption.hidden: true
      Project.ResponsibleCostCenter,
      @Consumption.hidden: true
      Project.Plant,
      @Consumption.hidden: true
      Project.FunctionalArea,       
      @Consumption.hidden: true
      Project._AuthUser,
      @Consumption.hidden: true
      Project._AuthSubst,
      @Consumption.hidden: true
      Project._AuthRole,
      @Consumption.hidden: true
      Project._AuthGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENTERPRISEPROJECT",
"I_ENTPROJPROCESSINGSTATUSTEXT",
"I_PROFITCENTERTEXT"
],
"ASSOCIATED":
[
"I_ENTPROJPROCESSINGSTATUSTEXT",
"I_PPM_AUTHZNBYSUBSTITH",
"I_PPM_AUTHZNBYUSERROLEH",
"I_PPM_AUTHZNBYUSRGRPH",
"I_PPM_AUTHZNBYUSRH",
"I_PROFITCENTERTEXT"
],
"BASE":
[
"I_ENTERPRISEPROJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/