C_EntProjSrvcOrgCntctCard

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Contact Card for Ent Proj Service Org'

@Metadata : {
  ignorePropagatedAnnotations: true,
  allowExtensions: true
}
@ObjectModel : {
  usageType:{
    serviceQuality: #C,
    sizeCategory: #S,
    dataClass: #MIXED
  },
  representativeKey: 'EnterpriseProjectServiceOrg'
}

@VDM.viewType: #CONSUMPTION
define view entity C_EntProjSrvcOrgCntctCard
  as select from I_EngagementProjectSrvcOrg
  association [0..1] to I_CompanyCode            as _CompanyCodeText       on  $projection.CompanyCode = _CompanyCodeText.CompanyCode
  association [0..1] to I_CostCenterText         as _DefaultCostCenterText on  $projection.ServiceOrgDefaultCostCenter  = _DefaultCostCenterText.CostCenter
                                                                           and _DefaultCostCenterText.ValidityEndDate   >= $session.system_date
                                                                           and _DefaultCostCenterText.ValidityStartDate <= $session.system_date
  association [0..1] to I_SalesOrganizationText  as _SalesOrgText          on  $projection.SalesOrganization = _SalesOrgText.SalesOrganization
  association [0..1] to I_PurchasingOrganization as _PurchaseOrgText       on  $projection.PurchasingOrganization = _PurchaseOrgText.PurchasingOrganization
  association [0..1] to I_Plant                  as _PlantText             on  $projection.Plant = _PlantText.Plant

{
      @ObjectModel :{
        text : {element: ['EnterpriseProjectSrvcOrgName']}
      }
      @Semantics : {
        contact : {type:#ORGANIZATION},
        name: { givenName: true }
      }
  key EngagementProjectServiceOrg                                                                                                                        as EnterpriseProjectServiceOrg,
      @Semantics.text: true
      _Text[1:Language = $session.system_language].EngmtProjectServiceOrgName                                                                            as EnterpriseProjectSrvcOrgName,
      @Semantics.booleanIndicator: true
      EngmtProjServiceOrgIsSales,
      @Semantics.booleanIndicator: true
      EngmtProjServiceOrgIsDelivery,
      @ObjectModel.text.association: '_CompanyCodeText'
      cast( _EngagementProjectSrvcOrgDets[1:AssignedOrganisationIsDefault = 'X' and AssignedOrganisationType = 'CC'].AssignedOrganisation as fis_bukrs ) as CompanyCode,
      @ObjectModel.text.association: '_DefaultCostCenterText'
      _EngagementProjectSrvcOrgDets[1:AssignedOrganisationIsDefault = 'X' and AssignedOrganisationType = 'CS'].AssignedOrganisation                      as ServiceOrgDefaultCostCenter,
      @ObjectModel.text.association: '_SalesOrgText'
      cast( _EngagementProjectSrvcOrgDets[1:AssignedOrganisationIsDefault = 'X' and AssignedOrganisationType = 'SO'].AssignedOrganisation   as vkorg )   as SalesOrganization,
      @ObjectModel.text.association: '_PurchaseOrgText'
      cast( _EngagementProjectSrvcOrgDets[1:AssignedOrganisationIsDefault = 'X' and AssignedOrganisationType = 'PO'].AssignedOrganisation   as ekorg )   as PurchasingOrganization,
      @ObjectModel.text.association: '_PlantText'
      cast( _EngagementProjectSrvcOrgDets[1:AssignedOrganisationIsDefault = 'X' and AssignedOrganisationType = 'PL'].AssignedOrganisation as werks_d )   as Plant,
      /* Associations */
      _CompanyCodeAuth,
      _EngagementProjectSrvcOrgDets,
      _CompanyCodeText,
      _DefaultCostCenterText,
      _SalesOrgText,
      _PurchaseOrgText,
      _PlantText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJECTSRVCORGDETS",
"I_ENGAGEMENTPROJECTSRVCORGTEXT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_COSTCENTERTEXT",
"I_ENGAGEMENTPROJECTSRVCORGDETS",
"I_ENGMNTPROJSERVICEORGDETAILS",
"I_PLANT",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATIONTEXT"
],
"BASE":
[
"I_ENGAGEMENTPROJECTSRVCORG"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/