C_EntProjCostCenterVH

DDL: C_ENTPROJCOSTCENTERVH SQL: CEPCOSTCTRVH Type: view CONSUMPTION

Cost Center

C_EntProjCostCenterVH is a Consumption CDS View that provides data about "Cost Center" in SAP S/4HANA. It reads from 1 data source (I_CostCenter) and exposes 6 fields with key fields ControllingArea, CostCenter, ValidityEndDate.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
I_CostCenter I_CostCenter from

Annotations (17)

NameValueLevelField
AbapCatalog.sqlViewName CEPCOSTCTRVH view
AbapCatalog.preserveKey true view
AbapCatalog.compiler.compareFilter true view
VDM.viewType #CONSUMPTION view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey CostCenter view
ObjectModel.modelingPattern #VALUE_HELP_PROVIDER view
ObjectModel.usageType.dataClass #ORGANIZATIONAL view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Search.searchable true view
Consumption.ranked true view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Cost Center view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY ControllingArea ControllingArea
KEY CostCenter CostCenter
KEY ValidityEndDate ValidityEndDate
ValidityStartDate ValidityStartDate
_Text _Text
_ControllingArea _ControllingArea 
@AbapCatalog.sqlViewName: 'CEPCOSTCTRVH'
@AbapCatalog.preserveKey: true 
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #CONSUMPTION

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'CostCenter'

@ObjectModel.modelingPattern: #VALUE_HELP_PROVIDER
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #VALUE_HELP_PROVIDER ]

@ObjectModel.usageType.dataClass: #ORGANIZATIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L

@AccessControl.authorizationCheck:#MANDATORY 

@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_Text']

@ClientHandling.algorithm: #SESSION_VARIABLE

@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Cost Center'

define view C_EntProjCostCenterVH as select from I_CostCenter {
  @ObjectModel.foreignKey.association: '_ControllingArea'
  @Search: { defaultSearchElement: true,
             fuzzinessThreshold:  0.8,
             ranking: #LOW }
  @UI.lineItem: [{importance: #HIGH, position: 20}]
  key ControllingArea,
  @ObjectModel.text.association: '_Text'
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #HIGH
  @UI.lineItem: [{importance: #HIGH, position: 10}]
  key CostCenter,
  @Semantics.businessDate.to: true
  key ValidityEndDate,
  @Semantics.businessDate.from: true
  ValidityStartDate,
  
  _Text,

  @Consumption.hidden: true
  _ControllingArea
} 
where ValidityStartDate <= $session.system_date
  and   ValidityEndDate >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTER"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_COSTCENTERTEXT"
],
"BASE":
[
"I_COSTCENTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More