C_ElectronicDocByMetaStatus

DDL: C_ELECTRONICDOCBYMETASTATUS Type: view_entity CONSUMPTION

eDocument by Metastatus

C_ElectronicDocByMetaStatus is a Consumption CDS View that provides data about "eDocument by Metastatus" in SAP S/4HANA. It reads from 1 data source (I_ElectronicDoc) and exposes 14 fields with key field ElectronicDocUUID. It has 3 associations to related views.

1 data source(s) 14 fields

Data Sources (1)

SourceAliasJoin Type
I_ElectronicDoc I_ElectronicDoc from

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_ElectronicDocCockpitActvProc _ElectronicDocCockpitActvProc $projection.ElectronicDocProcess = _ElectronicDocCockpitActvProc.ElectronicDocProcess
[0..*] I_ElectronicDocProcessText _ElectronicDocProcessText $projection.ElectronicDocProcess = _ElectronicDocProcessText.ElectronicDocProcess
[0..1] I_ElectronicDocMetaStatusText _ElectronicDocMetaStatusText $projection.ElectronicDocMetaStatus = _ElectronicDocMetaStatusText.ElectronicDocMetaStatus and _ElectronicDocMetaStatusText.Language = $session.system_language

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label eDocument by Metastatus view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY ElectronicDocUUID I_ElectronicDoc ElectronicDocUUID
ElectronicDocCompanyCode I_ElectronicDoc ElectronicDocCompanyCode
ElectronicDocCreationDate I_ElectronicDoc ElectronicDocCreationDate
ElectronicDocProcess I_ElectronicDoc ElectronicDocProcess Process
Country I_ElectronicDoc ElectronicDocCountry
ElectronicDocMetaStatus I_ElectronicDoc ElectronicDocMetaStatus
ElectronicDocMetaStatusText _ElectronicDocMetaStatusText ElectronicDocMetaStatusText
ElectronicDocMetaStatusIntgr _ElectronicDocMetaStatusText ElectronicDocMetaStatusIntgr Status
NumberOfElectronicDocs Number of Electronic Documents
int4asNumberOfIncmpltElectronicDocs
ElectronicDocNegativeCritlty
ElectronicDocIsActive _ElectronicDocCockpitActvProc ElectronicDocIsActive
_ElectronicDocProcessText _ElectronicDocProcessText
_ElectronicDocMetaStatusText _ElectronicDocMetaStatusText 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'eDocument by Metastatus'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION

define view entity C_ElectronicDocByMetaStatus
  as select from I_ElectronicDoc
  association [0..1] to I_ElectronicDocCockpitActvProc as _ElectronicDocCockpitActvProc on  $projection.ElectronicDocProcess     = _ElectronicDocCockpitActvProc.ElectronicDocProcess 
  association [0..*] to I_ElectronicDocProcessText     as _ElectronicDocProcessText     on  $projection.ElectronicDocProcess     = _ElectronicDocProcessText.ElectronicDocProcess
  association [0..1] to I_ElectronicDocMetaStatusText  as _ElectronicDocMetaStatusText  on  $projection.ElectronicDocMetaStatus  = _ElectronicDocMetaStatusText.ElectronicDocMetaStatus
                                                                                       and _ElectronicDocMetaStatusText.Language = $session.system_language
{

  key I_ElectronicDoc.ElectronicDocUUID,
      I_ElectronicDoc.ElectronicDocCompanyCode,
      I_ElectronicDoc.ElectronicDocCreationDate,

      @EndUserText.label: 'Process'
      @ObjectModel.text.association: '_ElectronicDocProcessText'
      I_ElectronicDoc.ElectronicDocProcess,

      I_ElectronicDoc.ElectronicDocCountry                     as Country,

      @UI.hidden: true
      I_ElectronicDoc.ElectronicDocMetaStatus,

      _ElectronicDocMetaStatusText.ElectronicDocMetaStatusText as ElectronicDocMetaStatusText,

      @ObjectModel.text.element: ['ElectronicDocMetaStatusText']
      @EndUserText.label: 'Status'
      _ElectronicDocMetaStatusText.ElectronicDocMetaStatusIntgr as ElectronicDocMetaStatusIntgr,

      @EndUserText.label: 'Number of Electronic Documents'
      @Aggregation.default: #SUM
      cast(1 as abap.int4)                                     as NumberOfElectronicDocs,

      @UI.hidden: true
      @Aggregation.default: #SUM
      cast(
      case I_ElectronicDoc.ElectronicDocMetaStatus
          when '0002' then 1
          when '' then 1
          when '0003' then 1
          else 0
      end as abap.int4)                                        as NumberOfIncmpltElectronicDocs,

      @UI.hidden: true
      cast(1 as abap.int4)                                     as ElectronicDocNegativeCritlty,     
    
      @UI.hidden: true
      _ElectronicDocCockpitActvProc.ElectronicDocIsActive      as ElectronicDocIsActive,

      //Associations

      _ElectronicDocProcessText,
      _ElectronicDocMetaStatusText
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ELECTRONICDOC",
"I_ELECTRONICDOCCOCKPITACTVPROC",
"I_ELECTRONICDOCMETASTATUSTEXT"
],
"ASSOCIATED":
[
"I_ELECTRONICDOCMETASTATUSTEXT",
"I_ELECTRONICDOCPROCESSTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More