C_EWM_HandlingUnitLabel

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Form Data Provider for EWM HU Label'
@Metadata.ignorePropagatedAnnotations: true

@VDM.viewType: #CONSUMPTION

@ObjectModel.supportedCapabilities: [ #OUTPUT_FORM_DATA_PROVIDER ]
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #L

define view entity C_EWM_HandlingUnitLabel as select from I_EWM_HandlingUnitHdr as huhdr
      association [0..1] to mara as material on huhdr.PackagingMaterialUUID = material.scm_matid_guid16
{
  key huhdr.Warehouse,
  key huhdr.HandlingUnitNumber,
  key huhdr.HandlingUnitIndicator,
  material.matnr as PackagingMaterial,
  cast ( abap.char'        ' as /scwm/de_rf_sled preserving type) as ShelfLifeExpirationDate,
  cast ( abap.char'          ' as /scwm/de_charg preserving type) as Batch,
    
  cast ( abap.char'                                        ' as /scwm/de_matnr preserving type) as Product,
  cast ( abap.char'                                        ' as /scwm/de_ui_maktx preserving type) as ProductDescription,
  
  @Semantics.quantity.unitOfMeasure: 'EWMSTOCKQUANTITYBASEUNIT'
  cast ( 0 as /lime/quantity ) as EWMStockQuantity,
  cast ( '   ' as /scwm/de_base_uom ) as EWMStockQuantityBaseUnit,
  
  @Semantics.quantity.unitOfMeasure: 'EWMSTOCKQUANTITYBASEUNIT'
  cast ( 0 as ewm_de_quantityinaltunit ) as EWMStockQuantityInAltvUnit,
  cast ( '   ' as /scwm/de_aunit ) as EWMStockQuantityAltvUnit,
  
  @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT' 
huhdr.GrossWeight,
  @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT' 
huhdr.NetWeight,
  huhdr.WeightUnit,
  @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITTAREWEIGHTUNIT' 
huhdr.HandlingUnitTareWeight, 
  huhdr.HandlingUnitTareWeightUnit,
  @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT' 
huhdr.GrossVolume, 
  @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT' 
huhdr.HandlingUnitNetVolume,
  huhdr.VolumeUnit, 
  @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITTAREVOLUMEUNIT' 
huhdr.HandlingUnitTareVolume,
  huhdr.HandlingUnitTareVolumeUnit,
  @Semantics.quantity.unitOfMeasure: 'UNITOFMEASUREDIMENSION'
  huhdr.HandlingUnitLength, 
  @Semantics.quantity.unitOfMeasure: 'UNITOFMEASUREDIMENSION'
  huhdr.HandlingUnitWidth,
  @Semantics.quantity.unitOfMeasure: 'UNITOFMEASUREDIMENSION'
  huhdr.HandlingUnitHeight,
  huhdr.UnitOfMeasureDimension, 
  @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT' 
huhdr.HandlingUnitMaxWeight,
@Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT' 
  huhdr.HandlingUnitWeightTolerance, 
  @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT' 
huhdr.HandlingUnitMaxVolume,
@Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT' 
  huhdr.HandlingUnitVolumeTolerance, 
  huhdr.HandlingUnitIsClosed, 
  @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITMAXDIMENSIONUNIT' 
huhdr.HandlingUnitMaxLength,
  @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITMAXDIMENSIONUNIT' 
huhdr.HandlingUnitMaxWidth,
  @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITMAXDIMENSIONUNIT' 
huhdr.HandlingUnitMaxHeight,
  huhdr.HandlingUnitMaxDimensionUnit,
  huhdr.HandlingUnitType,
  huhdr.ConsolidationGroup,
  huhdr.WorkloadIdentification, 
  huhdr.EntitledToDisposeParty, 
  huhdr.StorageType, 
  huhdr.StorageSection,  
  huhdr.StorageBin, 
  huhdr.PackagingMaterialType,
  huhdr.HandlingUnitPackingGroup,
  huhdr.HazardousSubstanceIndicator, 
  huhdr.HandlingUnitLogicalPosition
  
} where huhdr.PackagingMaterialUUID <> hextobin('00000000000000000000000000000000')
union all 
select from I_EWM_HandlingUnitHdr as huhdr {
  key huhdr.Warehouse,
  key huhdr.HandlingUnitNumber,
  key huhdr.HandlingUnitIndicator,
  
  cast ( '                                        ' as matnr preserving type) as PackagingMaterial,
  cast ( abap.char'        ' as /scwm/de_rf_sled preserving type) as ShelfLifeExpirationDate,
  cast ( abap.char'          ' as /scwm/de_charg preserving type) as Batch,
    
  cast ( abap.char'                                        ' as /scwm/de_matnr preserving type) as Product,
  cast ( abap.char'                                        ' as /scwm/de_ui_maktx preserving type) as ProductDescription,
  
  cast ( 0 as /lime/quantity ) as EWMStockQuantity,
  cast ( '   ' as /scwm/de_base_uom ) as EWMStockQuantityBaseUnit,
  
  cast ( 0 as ewm_de_quantityinaltunit ) as EWMStockQuantityInAltvUnit,
  cast ( '   ' as /scwm/de_aunit ) as EWMStockQuantityAltvUnit,
  
  huhdr.GrossWeight,
  huhdr.NetWeight,
  huhdr.WeightUnit,
  huhdr.HandlingUnitTareWeight, 
  huhdr.HandlingUnitTareWeightUnit,
  huhdr.GrossVolume, 
  huhdr.HandlingUnitNetVolume,
  huhdr.VolumeUnit, 
  huhdr.HandlingUnitTareVolume,
  huhdr.HandlingUnitTareVolumeUnit, 
  huhdr.HandlingUnitLength, 
  huhdr.HandlingUnitWidth,
  huhdr.HandlingUnitHeight,
  huhdr.UnitOfMeasureDimension, 
  huhdr.HandlingUnitMaxWeight,
  huhdr.HandlingUnitWeightTolerance, 
  huhdr.HandlingUnitMaxVolume,
  huhdr.HandlingUnitVolumeTolerance, 
  huhdr.HandlingUnitIsClosed, 
  huhdr.HandlingUnitMaxLength,
  huhdr.HandlingUnitMaxWidth,
  huhdr.HandlingUnitMaxHeight,
  huhdr.HandlingUnitMaxDimensionUnit,
  huhdr.HandlingUnitType,
  huhdr.ConsolidationGroup,
  huhdr.WorkloadIdentification, 
  huhdr.EntitledToDisposeParty, 
  huhdr.StorageType, 
  huhdr.StorageSection,  
  huhdr.StorageBin, 
  huhdr.PackagingMaterialType,
  huhdr.HandlingUnitPackingGroup,
  huhdr.HazardousSubstanceIndicator, 
  huhdr.HandlingUnitLogicalPosition 
  } where huhdr.PackagingMaterialUUID = hextobin('00000000000000000000000000000000')
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EWM_HANDLINGUNITHDR",
"MARA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/