C_EHSTechnicalObjectVH

DDL: C_EHSTECHNICALOBJECTVH Type: view_entity CONSUMPTION

EHS Technical Object

C_EHSTechnicalObjectVH is a Consumption CDS View that provides data about "EHS Technical Object" in SAP S/4HANA. It reads from 1 data source (I_TechnicalObject) and exposes 17 fields with key field TechnicalObjectLabel. It has 1 association to related views.

1 data source(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
I_TechnicalObject I_TechnicalObject from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_TechObjIsEquipOrFuncnlLoc _TechObjIsEquipOrFuncnlLoc _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label EHS Technical Object view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view
Search.searchable true view
ObjectModel.representativeKey TechnicalObjectLabel view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY TechnicalObjectLabel I_TechnicalObject TechnicalObjectLabel
TechObjIsEquipOrFuncnlLoc I_TechnicalObject TechObjIsEquipOrFuncnlLoc
TechnicalObject I_TechnicalObject TechnicalObject
FunctionalLocationLabelName
TechObjIsEquipOrFuncnlLocDesc Technical Object Type
TechnicalObjectDescription Technical Object Description
MaintenancePlanningPlant I_TechnicalObject MaintenancePlanningPlant
PlantName _MaintenancePlanningPlant PlantName
Equipment I_TechnicalObject Equipment
MaintenancePlannerGroup MaintenancePlannerGroup
CostCenter _LocationAccountAssignment CostCenter
ControllingArea _LocationAccountAssignment ControllingArea
MaintenancePlant _LocationAccountAssignment MaintenancePlant
AuthorizationGroup AuthorizationGroup
MaintObjectLocAcctAssgmtNmbr I_TechnicalObject MaintObjectLocAcctAssgmtNmbr
_TechObjIsEquipOrFuncnlLoc _TechObjIsEquipOrFuncnlLoc
_LocationAccountAssignment _LocationAccountAssignment 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'EHS Technical Object'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}

@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.representativeKey: 'TechnicalObjectLabel'

define view entity C_EHSTechnicalObjectVH
  as select from I_TechnicalObject 
  association [0..1] to I_TechObjIsEquipOrFuncnlLoc as _TechObjIsEquipOrFuncnlLoc on _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
{
      @ObjectModel.text.element:  [ 'TechnicalObjectDescription' ]
  key I_TechnicalObject.TechnicalObjectLabel,

      @ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
      @ObjectModel.text.element: ['TechObjIsEquipOrFuncnlLocDesc']
      @UI.hidden
      I_TechnicalObject.TechObjIsEquipOrFuncnlLoc,

      @UI.hidden: true
      @Search: {defaultSearchElement: true, ranking: #HIGH }
      I_TechnicalObject.TechnicalObject,

      @UI.hidden: true
      I_TechnicalObject._FunctionalLocationLabel._FuncLocationLabelSearch.FunctionalLocationLabelName,

      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_TechObjIsEquipOrFuncnlLoc',
          -- Note: is corrected via filter transformation
          --       reason: EAMS_EQUI / EAMS_FL should not be shown on UI, but performance is bad when searching with text.
          element: 'TechObjIsEquipOrFuncnlLoc'
        }
      }]
      @ObjectModel.filter.transformedBy: 'CL_EAM_TECHOBJTYPE_FILTER_EXIT'
      @EndUserText.label: 'Technical Object Type'
      _TechObjIsEquipOrFuncnlLoc._Text[1:Language=$session.system_language].TechObjIsEquipOrFuncnlLocDesc,

      @EndUserText.label: 'Technical Object Description'
      @Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
      I_TechnicalObject._TechnicalObjectText[1:Language=$session.system_language].TechnicalObjectDescription,

      I_TechnicalObject.MaintenancePlanningPlant,

      @Search: {defaultSearchElement: true, ranking: #MEDIUM }
      _MaintenancePlanningPlant.PlantName,

      @UI.hidden: true
      I_TechnicalObject.Equipment,

      @Consumption.hidden: true
      MaintenancePlannerGroup,
      @Consumption.hidden: true
      _LocationAccountAssignment.CostCenter,
      @Consumption.hidden: true
      _LocationAccountAssignment.ControllingArea,
      @Consumption.hidden: true
      _LocationAccountAssignment.MaintenancePlant,
      @Consumption.hidden: true
      AuthorizationGroup,
      @Consumption.hidden: true
      I_TechnicalObject.MaintObjectLocAcctAssgmtNmbr,
      @Consumption.filter.hidden
      _TechObjIsEquipOrFuncnlLoc,
      @Consumption.hidden: true
      _LocationAccountAssignment
}
where
  TechObjStatusIsInactive = '';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FUNCLOCATIONLABELSEARCH",
"I_FUNCTIONALLOCATIONLABEL",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_PLANT",
"I_TECHNICALOBJECT",
"I_TECHNICALOBJECTTEXT",
"I_TECHOBJISEQUIPORFUNCNLLOC",
"I_TECHOBJISEQUIPORFUNCNLLOCT"
],
"ASSOCIATED":
[
"I_LOCATIONACCOUNTASSIGNMENT",
"I_TECHOBJISEQUIPORFUNCNLLOC"
],
"BASE":
[
"I_TECHNICALOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More