C_EHSLocHierarchyPathDEX

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Location Hierarchy Data Extraction'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@ObjectModel.supportedCapabilities: [ #EXTRACTION_DATA_SOURCE ]
@VDM.viewType: #CONSUMPTION
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
      mapping: [{
        table: 'ehfndd_lhr_path',
        role: #MAIN,
        viewElement: ['EHSLocHierarchyPathUUID'],
        tableElement: ['db_key']
      }, {
        table: 'ehfndd_lhr_rev',
        role: #LEFT_OUTER_TO_ONE_JOIN,
        viewElement: ['EHSLocHierarchyRevisionUUID'],
        tableElement: ['db_key']
      }, {
        table: 'ehfndd_loc_root',
        role: #LEFT_OUTER_TO_ONE_JOIN,
        viewElement: ['EHSLocationUUID'],
        tableElement: ['db_key']
      }, {
        table: 'ehfndd_loc_root',
        role: #LEFT_OUTER_TO_ONE_JOIN,
        viewElement: ['EHSParentLocationUUID'],
        tableElement: ['db_key']
      }]
    }
  }
}
@Metadata.allowExtensions: true
define view entity C_EHSLocHierarchyPathDEX
  as select from           I_EHSLocHierarchyPath          as EHSLocHierarchyPath
    left outer to one join I_EHSLocationHierarchyRevision as EHSLocationHierarchyRevision on EHSLocHierarchyPath.EHSLocHierarchyRevisionUUID = EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID
    left outer to one join I_EHSLocationRoot              as EHSLocationRoot              on EHSLocHierarchyPath.EHSLocationUUID = EHSLocationRoot.EHSLocationUUID
    left outer to one join I_EHSLocationRoot              as EHSParentLocationRoot        on EHSLocHierarchyPath.EHSParentLocationUUID = EHSParentLocationRoot.EHSLocationUUID
{
  key EHSLocHierarchyPath.EHSLocHierarchyPathUUID,
      EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID,
      EHSLocationHierarchyRevision.RevisionStartDate,
      EHSLocationHierarchyRevision.RevisionEndDate,
      EHSLocationHierarchyRevision.RevisionDescription,
      EHSLocHierarchyPath.EHSLocationUUID,
      EHSLocationRoot.EHSLocationID,
      EHSLocHierarchyPath.EHSParentLocationUUID,
      EHSParentLocationRoot.EHSLocationID   as EHSParentLocationID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATIONHIERARCHYREVISION",
"I_EHSLOCATIONROOT",
"I_EHSLOCHIERARCHYPATH"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/