C_EHSControlImplmtnForTaskList

@AbapCatalog: {
  compiler.compareFilter: true,
  sqlViewName: 'CEHSCIMFTSKLST',
  preserveKey:true 
}
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.semanticObject: 'EHSControlImplementation'
@EndUserText.label: 'EHS Control Implementation for Task List'
@Metadata.allowExtensions: true
@ObjectModel: {
  semanticKey: ['EHSControlTitle'],
  representativeKey: 'EHSControlInstanceUUID',
  usageType:{ serviceQuality: #C,        // < 15 msec

              sizeCategory:   #M,         // < 100.000

              dataClass:      #MIXED }
}
@VDM.viewType: #CONSUMPTION
define view C_EHSControlImplmtnForTaskList
  as select from I_EHSRiskControl
  association [0..*] to I_EHSCtrlImplmtnStatusText     as _EHSCtrlImplmtnStatusText   on $projection.EHSControlImplStatus = _EHSCtrlImplmtnStatusText.EHSControlImplStatus
  association [0..*] to I_CurrentEHSLocationNameText   as _CurrentEHSLocationNameText on $projection.ehslocationuuid = _CurrentEHSLocationNameText.EHSLocationUUID
  association [0..*] to I_HazardText                   as _HazardText                 on $projection.hazard = _HazardText.Hazard
  association [0..*] to I_CurrentEHSAgentNameText      as _CurrentEHSAgentNameText    on $projection.EHSAgentUUID = _CurrentEHSAgentNameText.EHSAgentUUID
  association [0..*] to I_EHSOperationalStatusText     as _EHSOperationalStatusText   on $projection.operationalstatus = _EHSOperationalStatusText.OperationalStatus
  association [0..*] to C_EHSControlImplementationTask as _Tasks                      on $projection.EHSControlInstanceUUIDHex = _Tasks.EHSTaskHostObjectInstance
  association [0..*] to I_EHSTaskDefinitionTP          as _EHSTaskDefinitionTP        on $projection.EHSControlInstanceUUID = _EHSTaskDefinitionTP.EHSTaskHostObjectInstanceUUID
{
  key EHSControlInstanceUUID,
      bintohex(EHSControlInstanceUUID) as EHSControlInstanceUUIDHex,

      case EHSControlIsAdhoc
            when 'X' then EHSControlAdhocTitle
            else _EHSControl._EHSCtrlTitleTxt[1:Language = $session.system_language].EHSControlTitle // EHSControlUUID is UUID of Control Master

      end as EHSControlTitle,

      // Fields whose text should be displayed

      @ObjectModel.text.association: '_EHSCtrlImplmtnStatusText'
      EHSControlImplStatus,
      _EHSCtrlImplementationStatus,
      @ObjectModel.text.association: '_CurrentEHSLocationNameText'
      _EHSRiskRoot.EHSLocationUUID,
      _EHSRiskRoot._EHSLocationRoot,
      @ObjectModel.text.association: '_HazardText'
      _EHSRiskRoot.Hazard,
      
      _EHSRiskRoot._Hazard,
      @ObjectModel.text.association: '_CurrentEHSAgentNameText'
      cast ( case
        when _EHSRiskRoot.ChemicalUUID != hextobin( '00000000000000000000000000000000' )
        then _EHSRiskRoot.ChemicalUUID
        when _EHSRiskRoot.AirborneAgentUUID != hextobin( '00000000000000000000000000000000' )
        then _EHSRiskRoot.AirborneAgentUUID
        when _EHSRiskRoot.PhysicalAgentUUID != hextobin( '00000000000000000000000000000000' )
        then _EHSRiskRoot.PhysicalAgentUUID
        else hextobin( '00000000000000000000000000000000' )
      end as ehhss_agent_combined_uuid_ref preserving type ) as EHSAgentUUID,
      @ObjectModel.text.association: '_EHSOperationalStatusText'
      _EHSRiskRoot.OperationalStatus,
      _EHSRiskRoot._EHSOperationalStatus, 

      // Text Associations

      _EHSCtrlImplmtnStatusText,
      _CurrentEHSLocationNameText,
      _HazardText,
      _CurrentEHSAgentNameText,
      _EHSOperationalStatusText,
     

      // The Tasks

      _Tasks,
      
      // Needed For Auth Check

      //--[ GENERATED:012:29JlHNUf7jY4oS0yl5vKTW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_EHSRiskStdVH',
                     element: 'EHSRiskUUID' }
        }]
      // ]--GENERATED

      EHSRiskUUID,
      _EHSRiskRoot,

      // The Task Definiton BO to get the Function Imports for Creation

      _EHSTaskDefinitionTP

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSCONTROL",
"I_EHSCTRLTITLETEXT",
"I_EHSRISKCONTROL",
"I_EHSRISKROOT"
],
"ASSOCIATED":
[
"C_EHSCONTROLIMPLEMENTATIONTASK",
"I_CURRENTEHSAGENTNAMETEXT",
"I_CURRENTEHSLOCATIONNAMETEXT",
"I_EHSCTRLIMPLMTNSTATUSTEXT",
"I_EHSCTRLIMPLSTATUS",
"I_EHSLOCATIONROOT",
"I_EHSOPERATIONALSTATUS",
"I_EHSOPERATIONALSTATUSTEXT",
"I_EHSRISKROOT",
"I_EHSTASKDEFINITIONTP",
"I_HAZARD",
"I_HAZARDTEXT"
],
"BASE":
[
"I_EHSRISKCONTROL",
"I_EHSRISKROOT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/