C_EHSBusinessUserValueHelp

DDL: C_EHSBUSINESSUSERVALUEHELP Type: view CONSUMPTION

EHS Business User

C_EHSBusinessUserValueHelp is a Consumption CDS View that provides data about "EHS Business User" in SAP S/4HANA. It reads from 1 data source (I_BusinessUserBasic) and exposes 23 fields with key field EHSCombinedBusinessPartner. It has 1 association to related views.

1 data source(s) 23 fields

Data Sources (1)

SourceAliasJoin Type
I_BusinessUserBasic I_BusinessUserBasic from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_PersonWorkAgreement_1 _PersonWorkAgreement_1 $projection.BusinessPartner = _PersonWorkAgreement_1.Person

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName CEHSBUVH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ClientHandling.type #CLIENT_DEPENDENT view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label EHS Business User view
ObjectModel.representativeKey EHSCombinedBusinessPartner view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.dataCategory #VALUE_HELP view
VDM.viewType #CONSUMPTION view
Metadata.allowExtensions true view
Search.searchable true view

Fields (23)

KeyFieldSource TableSource FieldDescription
KEY EHSCombinedBusinessPartner
BusinessPartner BusinessPartner
FirstName FirstName
LastName LastName
PersonFullName PersonFullName
EHSCombinedUserID
AuthorizationGroup AuthorizationGroup
IsBusinessPurposeCompleted IsBusinessPurposeCompleted
DataControllerSet DataControllerSet
DataController1 DataController1
DataController2 DataController2
DataController3 DataController3
DataController4 DataController4
DataController5 DataController5
DataController6 DataController6
DataController7 DataController7
DataController8 DataController8
DataController9 DataController9
DataController10 DataController10
UserID UserID
BusinessPartnerUUID BusinessPartnerUUID
_PersonWorkAgreement_1 _PersonWorkAgreement_1
_WorkplaceAddress _WorkplaceAddress 
@AbapCatalog: {
  sqlViewName: 'CEHSBUVH',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ClientHandling: {
  type: #CLIENT_DEPENDENT,
  algorithm : #SESSION_VARIABLE
}
@EndUserText.label: 'EHS Business User'
@ObjectModel: {
  representativeKey: 'EHSCombinedBusinessPartner',
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #XL,
  usageType.dataClass: #MIXED,
  dataCategory: #VALUE_HELP
}
@VDM.viewType: #CONSUMPTION
//3356813 - allowExtensions

@Metadata.allowExtensions: true
@Search.searchable: true

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
define view C_EHSBusinessUserValueHelp
  as select from I_BusinessUserBasic
  association [0..*] to I_PersonWorkAgreement_1 as _PersonWorkAgreement_1 on $projection.BusinessPartner = _PersonWorkAgreement_1.Person
{
      @UI.hidden: true
  key cast ( concat('C', BusinessPartner) as  abap.char( 13 ) ) as EHSCombinedBusinessPartner,

      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      @Semantics.contact.type: #PERSON
      @ObjectModel.text.element: ['PersonFullName']
      @UI.selectionField: [{position: 10 }]
      BusinessPartner,

      @Semantics.name.givenName: true
      @UI.selectionField: [{position: 20 }]
      FirstName,
      @Semantics.name.familyName: true
      @UI.selectionField: [{position: 30 }]
      LastName,
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.8,
        ranking: #MEDIUM
      }
      @Semantics.name.fullName: true
      @UI.hidden: true
      PersonFullName,

      @Consumption.hidden: true
      cast ( concat('D', UserID) as abap.char( 13 )  )          as EHSCombinedUserID,

      // Required for Authorization check

      @Consumption.hidden: true
      AuthorizationGroup,
      @Consumption.hidden: true
      IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      DataControllerSet,
      @Consumption.hidden: true
      DataController1,
      @Consumption.hidden: true
      DataController2,
      @Consumption.hidden: true
      DataController3,
      @Consumption.hidden: true
      DataController4,
      @Consumption.hidden: true
      DataController5,
      @Consumption.hidden: true
      DataController6,
      @Consumption.hidden: true
      DataController7,
      @Consumption.hidden: true
      DataController8,
      @Consumption.hidden: true
      DataController9,
      @Consumption.hidden: true
      DataController10,

      @UI.hidden: true
      UserID,

      @UI.hidden: true
      BusinessPartnerUUID,

      _PersonWorkAgreement_1,
      _WorkplaceAddress
}
where
  IsBusinessPurposeCompleted = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSERBASIC"
],
"ASSOCIATED":
[
"I_PERSONWORKAGREEMENT_1",
"I_WORKPLACEADDRESS"
],
"BASE":
[
"I_BUSINESSUSERBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More