C_EDCDocumentList

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'EDC Consistency List'
@VDM.viewType:#CONSUMPTION
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}

define view entity C_EDCDocumentList
  as select from           I_EDCRecords  as _EDCRecords
    left outer to one join I_EDCRelation as _EDCRelationElectronicDocument on  _EDCRecords.EDCRecordUUID                            = _EDCRelationElectronicDocument.EDCRecordUUID
                                                                           and _EDCRelationElectronicDocument.EDCRepresentationType = 'EDOCUMENT'
                                                                           and _EDCRecords.EDCType                                  = _EDCRelationElectronicDocument.EDCType
    left outer to one join I_EDCRelation as _EDCRelationTaxAuthDocument    on  _EDCRecords.EDCRecordUUID                         = _EDCRelationTaxAuthDocument.EDCRecordUUID
                                                                           and _EDCRelationTaxAuthDocument.EDCRepresentationType = 'TAXAUTHDOC'
                                                                           and _EDCRecords.EDCType                               = _EDCRelationTaxAuthDocument.EDCType

  association [1..*] to I_EDCRelation          as _EDCRelation          on  $projection.EDCRecordUUID = _EDCRelation.EDCRecordUUID

  association [0..1] to R_EDCElectronicDoc     as _ElectronicDoc        on  _EDCRelationElectronicDocument.EDCRepresentationKey = _ElectronicDoc.ElectronicDocUUID
  association [1..1] to C_CompanyCodeValueHelp as _CompanyCodeValueHelp on  $projection.EDCCompany = _CompanyCodeValueHelp.CompanyCode
  association [1..1] to R_EDCMetaStatusText    as _EDCMetaStatusText    on  $projection.EDCMetaStatus   = _EDCMetaStatusText.EDCMetaStatus
                                                                        and _EDCMetaStatusText.Language = $session.system_language
  association [1..1] to R_EDCType              as _EDCType              on  $projection.EDCType = _EDCType.EDCType
  association [1..1] to I_TaxAuthorityDocument as _TaxAuthorityDocument on  _EDCRelationTaxAuthDocument.EDCRepresentationKey = _TaxAuthorityDocument.EDCTaxAuthRecordUUID

  //    left outer to one join I_EDCRelation as _EDCRelationAccountingDocument on  _EDCRecords.EDCRecordUUID                            = _EDCRelationAccountingDocument.EDCRecordUUID

  //                                                                           and _EDCRelationAccountingDocument.EDCRepresentationType = 'FI_DOC'


  //  association [0..1] to I_ElectronicDocAccountingDoc as _AccountingDocument   on  _EDCRelationAccountingDocument.EDCRepresentationKey = _AccountingDocument.AccountingDocument

  //                                                                              and '2022'                                              = _AccountingDocument.FiscalYear

  //                                                                              and 'ES01'                                              = _AccountingDocument.CompanyCode

  //  association [1..*] to I_EDCResult                  as _EDCResult            on  $projection.EDCRecordUUID = _EDCResult.EDCRecordUUID

  //                                                                              and $projection.EDCSqncNmbr   = _EDCResult.EDCSqncNmbr


{
          // General Fields

          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
  key     _EDCRecords.EDCRecordUUID,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCRunID,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          @ObjectModel.text.element: ['CompanyCodeName']
          @UI.textArrangement: #TEXT_LAST
          _EDCRecords.EDCCompany,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCCommercialKey,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          @ObjectModel.text.element: ['EDCMetaStatusText']
          @UI.textArrangement: #TEXT_ONLY
          _EDCRecords.EDCMetaStatus,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCCreatedByUser,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCCreatedOnDateTime,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCChangedByUser,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCChangedOnDateTime,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _EDCRecords.EDCCheckDateTime,
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_EDCDOCUMENTLIST'

          cast(0 as  abap.int8 ) as EDCNumberOfExecutedChecks,
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_EDCDOCUMENTLIST'

          cast(0 as  abap.int8 ) as EDCNumberOfTotalChecks,
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_EDCDOCUMENTLIST'

          cast(0 as  abap.int8 ) as EDCNumberOfInProcessResults,
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_EDCDOCUMENTLIST'

          cast(0 as  abap.int8 ) as EDCNumberOfAllResults,


          // Electronic Document Fields

          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _ElectronicDoc.ElectronicDocPostingDate,
          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _ElectronicDoc.ElectronicDocCreationDate,


          // Tax Authority Document Fields

          @UI.fieldGroup                 : [ { qualifier: 'General'} ]
          _TaxAuthorityDocument.EDCDocumentPeriod,


          // Association

          _EDCRelation,

          // The fields below do not appear on the list page

          //          _AccountingDocument.AccountingDocument,

          //          _AccountingDocument.AccountingDocumentType,

          //          _AccountingDocument.DocumentDate,

          //          _AccountingDocument.FiscalYear,

          //          _AccountingDocument.FiscalPeriod,

          //          _AccountingDocument.LedgerGroup,


          _EDCRecords.EDCSqncNmbr,
          _CompanyCodeValueHelp.CompanyCodeName,
          _EDCRecords.EDCType,
          _EDCMetaStatusText.EDCMetaStatusText,
          _EDCType.EDCCountry,
          _ElectronicDoc.ElectronicDocUUID,
          @ObjectModel.text.element: ['ElectronicDocSourceTypeText']
          @UI.textArrangement: #TEXT_ONLY
          _ElectronicDoc.ElectronicDocSourceType,
          _ElectronicDoc.ElectronicDocSourceTypeText,
          @ObjectModel.text.element: ['ElectronicDocTypeText']
          @UI.textArrangement: #TEXT_ONLY
          _ElectronicDoc.ElectronicDocType,
          _ElectronicDoc.ElectronicDocTypeText,
          _ElectronicDoc.ElectronicDocProcessStatus,
          @ObjectModel.text.element: ['ElectronicDocProcessText']
          @UI.textArrangement: #TEXT_ONLY
          _ElectronicDoc.ElectronicDocProcess,
          _ElectronicDoc.ElectronicDocProcessText,
          _ElectronicDoc.ElectronicDocStatus,
          _ElectronicDoc.ElectronicDocSourceKey,
          _ElectronicDoc.ElectronicDocMetaStatus,
          _TaxAuthorityDocument.EDCTaxAuthDocumentKey,
          _TaxAuthorityDocument.EDCTaxAuthDocumentType,
          _TaxAuthorityDocument.EDCBusinessPartnerID

}
where
  _ElectronicDoc.ElectronicDocProcess is null or _ElectronicDoc.ElectronicDocProcess != 'ESSIIDEREG'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_COMPANYCODEVALUEHELP",
"I_EDCRECORDS",
"I_EDCRELATION",
"I_ES_ELECTRONICDOCSIISINGLEDOC",
"I_TAXAUTHORITYDOCUMENT",
"R_EDCELECTRONICDOC",
"R_EDCMETASTATUSTEXT",
"R_EDCTYPE"
],
"ASSOCIATED":
[
"I_EDCRELATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/