C_DspDocFlwPurchaseDocVH

DDL: C_DSPDOCFLWPURCHASEDOCVH Type: view_entity CONSUMPTION

Purchasing Documents VH for DDF

C_DspDocFlwPurchaseDocVH is a Consumption CDS View that provides data about "Purchasing Documents VH for DDF" in SAP S/4HANA. It reads from 1 data source (I_PurchasingDocument) and exposes 16 fields with key field PurchasingDocument.

1 data source(s) 16 fields

Data Sources (1)

SourceAliasJoin Type
I_PurchasingDocument I_PurchasingDocument from

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #CONSUMPTION view
EndUserText.label Purchasing Documents VH for DDF view
Search.searchable true view
Consumption.ranked true view

Fields (16)

KeyFieldSource TableSource FieldDescription
KEY PurchasingDocument PurchasingDocument
PurchasingDocumentTypeName
CompanyCode CompanyCode
CreationDate
PurchasingOrganization PurchasingOrganization
Supplier Supplier
AnchorDocument
ReferenceDocumentType
IsEndOfPurposeBlocked IsEndOfPurposeBlocked
PurchasingDocumentType PurchasingDocumentType
PurchasingDocumentCategory PurchasingDocumentCategory
PurchasingDocumentOrigin PurchasingDocumentOrigin
PurchasingGroup PurchasingGroup
_CompanyCode _CompanyCode
_PurchasingOrganization _PurchasingOrganization
_Supplier _Supplier 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Purchasing Documents VH for DDF'
@Search.searchable: true
@Consumption.ranked: true
define view entity C_DspDocFlwPurchaseDocVH
  as select from I_PurchasingDocument
{
      @UI.selectionField: [ {position: 10 }]
      @UI.lineItem: [ {position: 10 }]
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
  key PurchasingDocument,
      @UI.lineItem: [ {position: 20 }]
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Semantics.text: true
      _PurchasingDocumentType._Text[1:Language = $session.system_language].PurchasingDocumentTypeName,
      @UI.selectionField: [ {position: 20 }]
      @UI.lineItem: [ {position: 30 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @ObjectModel.text.reference.association: '_CompanyCode'
      CompanyCode,
      @UI.selectionField: [ {position: 30 }]
      @UI.lineItem: [ {position: 40 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      cast( CreationDate as fac_ddf_document_date preserving type )  as CreationDate,
      @UI.selectionField: [ {position: 40 }]
      @UI.lineItem: [ {position: 50 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @ObjectModel.text.reference.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @UI.selectionField: [ {position: 50 }]
      @UI.lineItem: [ {position: 60 }]      
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @ObjectModel.text.reference.association: '_Supplier'
      Supplier,

      @UI.hidden: true
      cast( PurchasingDocument as fac_ddf_anchor_document )          as  AnchorDocument,
      @UI.hidden: true
      cast( 'BUS2012' as swo_objtyp)                                 as  ReferenceDocumentType,

      @Consumption.hidden: true
      IsEndOfPurposeBlocked,
      @Consumption.hidden: true
      PurchasingDocumentType,
      @Consumption.hidden: true
      PurchasingDocumentCategory,
      @Consumption.hidden: true
      PurchasingDocumentOrigin,
      @Consumption.hidden: true
      PurchasingGroup,
      
      _CompanyCode,
      _PurchasingOrganization,
      _Supplier
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGDOCUMENTTYPETEXT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[
"I_PURCHASINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More