C_DspDocFlwJournalEntryVH

@AbapCatalog.sqlViewName: 'CDDFJRNLENTRVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.dataCategory: #VALUE_HELP

@VDM.viewType: #CONSUMPTION

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Journal Entry'
@Search.searchable: true
@Consumption.ranked: true
define view C_DspDocFlwJournalEntryVH
  as select from I_JournalEntrySemanticKeyVH
{
      @Consumption.filter.hidden: true
      @UI.hidden: true
  key SourceLedger,

      @UI.selectionField.position: 10
      @UI.lineItem.position: 10
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.9               
  key AccountingDocument,

      @UI.selectionField.position: 20
      @UI.lineItem.position: 20
      @Consumption.valueHelpDefinition: [{ entity: { name : 'I_CompanyCodeStdVH', element : 'CompanyCode' } }]
      @Consumption.filter.mandatory: true
  key CompanyCode,

      @UI.selectionField.position: 50
      @UI.lineItem.position: 50
      @Consumption.valueHelpDefinition: [{ entity: { name : 'I_LedgerStdVH', element : 'Ledger' } }]
  key Ledger,

      @UI.selectionField.position: 60
      @UI.lineItem.position: 60
      @Consumption.filter.mandatory: true
  key FiscalYear,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      cast( JournalEntrySemanticKey as fac_ddf_anchor_document )  as  AnchorDocument,

      @UI.selectionField.position: 70
      @UI.hidden: true
      @ObjectModel.text.element: ['AccountingDocumentTypeName']
      @Consumption.valueHelpDefinition: [{ entity: { name : 'I_AccountingDocumentTypeStdVH', element : 'AccountingDocumentType' } }]
      AccountingDocumentType,

      @UI.lineItem.position: 70
      @Consumption.filter.hidden: true
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      AccountingDocumentTypeName,
      
      @Consumption.filter.selectionType: #SINGLE
      @Consumption.filter.defaultValue: '' 
      cast('' as xarch)                                           as  DocumentIsArchived,
            
      @Consumption.filter.hidden: true
      @UI.hidden: true
      @Consumption.filter.selectionType: #SINGLE
      IsCommitment,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 60
      @Consumption.filter.selectionType: #SINGLE
      JournalEntryIsInSourceLedger,     

      @Consumption.filter.hidden: true
      @UI.hidden: true
      cast( 'BKPF' as swo_objtyp)                                 as  ReferenceDocumentType
}
where AccountingDocumentCategory <> 'C'  

// documents with AccountingDocumentCategory = C (compressed) are documents that have been archived

// they are no longer in BKPF (I_JournalEntry)

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYSEMANTICKEYVH"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/