C_DspDocFlwDeliveryDocVH

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Consumption.ranked: true
@EndUserText.label: 'Delivery Documents VH for DDF'
define view entity C_DspDocFlwDeliveryDocVH
  as select from I_DeliveryDocument as DeliveryDocument
{
      @UI.selectionField: [ {position: 10 }]
      @UI.lineItem: [ {position: 10 }]
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
  key DeliveryDocument,
      @Consumption.filter.hidden: true
      @UI.lineItem: [ {position: 20 }]
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      cast ( _DeliveryDocumentType._Text[1:Language = $session.system_language].DeliveryDocumentTypeName as lfart_bez preserving type ) as DeliveryDocumentTypeName,
      @UI.selectionField: [ {position: 20 }]
      @UI.lineItem: [ {position: 30 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @ObjectModel.foreignKey.association: '_ShippingPoint'
      ShippingPoint,
      @UI.selectionField: [ {position: 30 }]
      @UI.lineItem: [ {position: 40 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @ObjectModel.foreignKey.association: '_ReceivingPlant'
      ReceivingPlant,
      @UI.selectionField: [ {position: 40 }]
      @UI.lineItem: [ {position: 50 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      DeliveryDate,
      @ObjectModel.text.element: ['CustomerName']
      @UI.textArrangement: #TEXT_LAST
      @UI.selectionField: [ {position: 50 }]
      @UI.lineItem: [ {position: 60 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @ObjectModel.foreignKey.association: '_ShipToParty'
      ShipToParty,
      @UI.selectionField: [ {position: 60 }]
      @UI.lineItem: [ {position: 70 }]
      @Semantics.text: true
      DeliveryDocument._ShipToParty.CustomerName,

      @UI.hidden: true
      cast( DeliveryDocument as fac_ddf_anchor_document )                                                                               as AnchorDocument,
      @UI.hidden: true
      cast( 'LIKP' as swo_objtyp)                                                                                                       as ReferenceDocumentType,
      
      _ShippingPoint,
      _ReceivingPlant,
      _ShipToParty
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_DELIVERYDOCUMENT",
"I_DELIVERYDOCUMENTTYPE",
"I_DELIVERYDOCUMENTTYPETEXT"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_PLANT",
"I_SHIPPINGPOINT"
],
"BASE":
[
"I_DELIVERYDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/