@AbapCatalog.sqlViewName: 'CDOCINFRECD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Document Info Record TP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@AccessControl.privilegedAssociations: ['_CreatedUser', '_UserDetails', '_ChangedUser', '_DocTypeText']
@ObjectModel.compositionRoot:true
@ObjectModel.transactionalProcessingDelegated:true
@ObjectModel.createEnabled:true
@ObjectModel.updateEnabled:true
@ObjectModel.draftEnabled:true
@ObjectModel.deleteEnabled:true // New Feature from 1805, visibility in controlled from UI
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION
@ObjectModel.semanticKey: ['DocumentInfoRecordDocType','DocumentInfoRecordDocVersion','DocumentInfoRecordDocPart','DocumentInfoRecordDocNumber']
define view C_DocumentInfoRecordTP
as select from I_DocumentInfoRecordTP as Document
association [0..*] to C_DocumentInfoRecordDescTP as _Desc on $projection.DocumentInfoRecordDocType = _Desc.DocumentInfoRecordDocType
and $projection.DocumentInfoRecordDocNumber = _Desc.DocumentInfoRecordDocNumber
and $projection.DocumentInfoRecordDocVersion = _Desc.DocumentInfoRecordDocVersion
and $projection.DocumentInfoRecordDocPart = _Desc.DocumentInfoRecordDocPart
association [0..*] to C_DocumentInfoRecordObjLinkTP as _ObjLink on $projection.DocumentInfoRecordDocType = _ObjLink.DocumentInfoRecordDocType
and $projection.DocumentInfoRecordDocNumber = _ObjLink.DocumentInfoRecordDocNumber
and $projection.DocumentInfoRecordDocVersion = _ObjLink.DocumentInfoRecordDocVersion
and $projection.DocumentInfoRecordDocPart = _ObjLink.DocumentInfoRecordDocPart
association [0..*] to C_DocumentInfoRecordVersion as _DIRVersion on $projection.DocumentInfoRecordDocType = _DIRVersion.DocumentInfoRecordDocType
and $projection.DocumentInfoRecordDocNumber = _DIRVersion.DocumentInfoRecordDocNumber
and $projection.DocumentInfoRecordDocVersion <> _DIRVersion.DocumentInfoRecordDocVersion
and $projection.DocumentInfoRecordDocPart = _DIRVersion.DocumentInfoRecordDocPart
association [0..1] to I_DocumentInfoRecordDocStatus as _StatusText on $projection.DocumentInfoRecordDocType = _StatusText.DocumentInfoRecordDocType
and $projection.InternalDocumentStatus = _StatusText.InternalDocumentStatus
/* association [0..1] to P_DocumentInfoRecordCalcFields as _DIRCalcFields on $projection.DocumentInfoRecordDocType = _DIRCalcFields.DocumentInfoRecordDocType
and $projection.DocumentInfoRecordDocNumber = _DIRCalcFields.DocumentInfoRecordDocNumber
and $projection.DocumentInfoRecordDocVersion = _DIRCalcFields.DocumentInfoRecordDocVersion
and $projection.DocumentInfoRecordDocPart = _DIRCalcFields.DocumentInfoRecordDocPart
*/
association [0..*] to I_DocumentInfoRecordObjLinkVH as _SAPObjectVH on $projection.DocInfoRecdDocTypeForEdit = _SAPObjectVH.DocumentInfoRecordDocType
and _SAPObjectVH.LinkedSAPObject <> 'STKO_DOC'
association [0..1] to C_DocumentInfoRecordDelInd as _CADValueHelp on $projection.DocumentIsCreatedByCAD = _CADValueHelp.IndicatorValue
association [0..1] to C_DocumentInfoRecordDelInd as _DeletionValueHelp on $projection.DocInfoRecdIsDeleted = _DeletionValueHelp.IndicatorValue
//--[ GENERATED:011:29JlHNUf7jY4gJbXw{Mp80
association [0..*] to I_DocumentInfoRecordDocTypeT as _DocTypeText on $projection.DocInfoRecdDocTypeForEdit = _DocTypeText.DocumentInfoRecordDocType
association [0..*] to I_DocumentInfoRecordDocTypeT as _DocumentTypeText on $projection.DocumentInfoRecordDocType = _DocumentTypeText.DocumentInfoRecordDocType
// ]--GENERATED
association [0..1] to C_ChangeMasterVH as _ChangeMasterVH on $projection.ChangeNumber = _ChangeMasterVH.ChangeNumber
--Get DocumentInfoRecord created user full name
// association [1..1] to I_User as _CreatedUser on $projection.CreatedByUser = _CreatedUser.UserID
{
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@UI.lineItem: { position: 10, importance: #HIGH}
@UI.selectionField: {position: 10}
@UI.fieldGroup: {qualifier: 'Document', position: 30}
@EndUserText.label:'Document Number'
//--
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocPrtVH',
element: 'DocumentInfoRecordDocNumber' },
additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocumentInfoRecordDocVersion',
element: 'DocumentInfoRecordDocVersion' },
{ localElement: 'DocumentInfoRecordDocPart',
element: 'DocumentInfoRecordDocPart' }]
}]
// ]
//@Consumption: { valueHelp: '_DocPart' }
@EndUserText.quickInfo: 'Document number'
key Document.DocumentInfoRecordDocNumber as DocumentInfoRecordDocNumber,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@UI.lineItem: { position: 20, importance: #HIGH}
@UI.selectionField: {position: 20}
//--[
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocTypeVH',
element: 'DocumentInfoRecordDocType' }
}]
@ObjectModel.text.association: '_DocumentTypeText'
// ]
//@Consumption: { valueHelp: '_DocType' }
@EndUserText.label:'Document Type'
@EndUserText.quickInfo: 'Document type'
key Document.DocumentInfoRecordDocType as DocumentInfoRecordDocType,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@UI.lineItem: { position: 30, importance: #HIGH}
@UI.selectionField: {position: 30}
@UI.fieldGroup: {qualifier: 'Document', position: 30}
//--[
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocVersVH',
element: 'DocumentInfoRecordDocVersion' },
additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocumentInfoRecordDocNumber',
element: 'DocumentInfoRecordDocNumber' }]
}]
// ]--GENERATED
//@Consumption: { valueHelp: '_DocVersion'}
@EndUserText.label:'Document Version'
@EndUserText.quickInfo: 'Document version'
key Document.DocumentInfoRecordDocVersion as DocumentInfoRecordDocVersion,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@UI.lineItem: { position: 40, importance: #HIGH}
@UI.selectionField: {position: 40}
@UI.fieldGroup: {qualifier: 'Document', position: 40}
//--
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocPrtVH',
element: 'DocumentInfoRecordDocPart' },
additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocumentInfoRecordDocNumber',
element: 'DocumentInfoRecordDocNumber' },
{ localElement: 'DocumentInfoRecordDocVersion',
element: 'DocumentInfoRecordDocVersion' }]
}]
// ]
//@Consumption: { valueHelp: '_DocPart' }
@EndUserText.label:'Document Part'
@EndUserText.quickInfo: 'Document part'
key Document.DocumentInfoRecordDocPart as DocumentInfoRecordDocPart,
@Consumption.filter.hidden: true
@ObjectModel.mandatory: false
@UI.identification: {position: 10, importance: #HIGH, label: 'Document Number'}
//--
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocPrtVH',
element: 'DocumentInfoRecordDocNumber' },
additionalBinding: [{ localElement: 'DocInfoRecdDocTypeForEdit',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocInfoRecdDocPartForEdit',
element: 'DocumentInfoRecordDocPart' },
{ localElement: 'DocInfoRecdDocVersionForEdit',
element: 'DocumentInfoRecordDocVersion' }]
}]
@EndUserText.quickInfo: 'Document number'
Document.DocInfoRecdDocNumberForEdit as DocInfoRecdDocNumberForEdit,
@Consumption.filter.hidden: true
@UI.identification: {position: 20, importance: #HIGH, label: 'Document Type'}
//--[
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocTypeVH',
element: 'DocumentInfoRecordDocType' }
}]
@ObjectModel.text.association: '_DocTypeText'
@ObjectModel.text.control: #('ASSOCIATED_TEXT_UI_HIDDEN')
// ]
//@Consumption.valueHelpDefinition: [{ entity: { name : 'I_DocumentInfoRecordDocType', element : 'DocumentInfoRecordDocType' } }]
@ObjectModel.mandatory: true
@UI.fieldGroup: {qualifier: 'Document', position: 20}
@EndUserText.quickInfo: 'Document type'
Document.DocInfoRecdDocTypeForEdit as DocInfoRecdDocTypeForEdit,
@Consumption.filter.hidden: true
@ObjectModel.mandatory: false
@UI.identification: {position: 30, importance: #HIGH, label: 'Document Part'}
//--
/* @Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocInfoRecdDocPrtStdVH', //'I_DocumentInfoRecordDocPrtVH',
element: 'DocumentInfoRecordDocPart' },
additionalBinding: [{ localElement: 'DocInfoRecdDocTypeForEdit',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocInfoRecdDocNumberForEdit',
element: 'DocumentInfoRecordDocNumber' },
{ localElement: 'DocInfoRecdDocVersionForEdit',
element: 'DocumentInfoRecordDocVersion' }]
}] */
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordDocPrtVH',
element: 'DocumentInfoRecordDocPart' },
additionalBinding: [{ localElement: 'DocInfoRecdDocTypeForEdit',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocInfoRecdDocNumberForEdit',
element: 'DocumentInfoRecordDocNumber' },
{ localElement: 'DocInfoRecdDocVersionForEdit',
element: 'DocumentInfoRecordDocVersion' }]
}]
// ]
// @Consumption.valueHelpDefinition: [{ entity: { name : 'I_DocumentInfoRecordDocPrt', element : 'DocumentInfoRecordDocPart' },
// additionalBinding: [{localElement: 'DocInfoRecdDocTypeForEdit', element : 'DocumentInfoRecordDocType'},
// {localElement: 'DocInfoRecdDocNumberForEdit', element : 'DocumentInfoRecordDocNumber'},
// {localElement: 'DocInfoRecdDocVersionForEdit', element : 'DocumentInfoRecordDocVersion'}] }]
@EndUserText.quickInfo: 'Document part'
Document.DocInfoRecdDocPartForEdit as DocInfoRecdDocPartForEdit,
//--[ GENERATED:011:GlBfhyFV7jY4gRmvB6oo}W
@Consumption.filter.hidden: true
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocInfoRecdDocVersStdVH',
element: 'DocumentInfoRecordDocVersion' },
additionalBinding: [{ localElement: 'DocInfoRecdDocTypeForEdit',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocInfoRecdDocNumberForEdit',
element: 'DocumentInfoRecordDocNumber' }]
}]
// ]--GENERATED
@EndUserText.quickInfo: 'Document version'
@UI.identification: {position: 40, importance: #HIGH, label: 'Document Version'}
Document.DocInfoRecdDocVersionForEdit as DocInfoRecdDocVersionForEdit,
//***Starting from 1905 virtual/calculated elements must be read-only********
/* @ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CV_DMS_DESCRIPTIONFOREDIT' */
//*******
@ObjectModel.mandatory: false
@ObjectModel.enabled: true
@EndUserText.quickInfo: 'Document Draft Description'
@EndUserText.label: 'Document Draft Description'
Document.DocumentDescriptionForEdit,
@Consumption.filter.hidden: true
@EndUserText.quickInfo: 'Document Status'
Document.ExternalDocumentStatusForEdit,
//concatenation of all key values. required for download originals
@ObjectModel.readOnly: true
@Consumption.filter.hidden: true
Document.DocumentInfoRecord as DocumentInfoRecord,
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 100, importance: #HIGH }]
Document.ChangedDateTime as ChangedDateTime,
@ObjectModel.text.element: [ 'LastChangedByUserFullName' ]
//--
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordUserVH',
element: 'LastChangedByUser' },
additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocumentInfoRecordDocNumber',
element: 'DocumentInfoRecordDocNumber' },
{ localElement: 'DocumentInfoRecordDocVersion',
element: 'DocumentInfoRecordDocVersion' },
{ localElement: 'DocumentInfoRecordDocPart',
element: 'DocumentInfoRecordDocPart' }]
}]
// ]--
//@Consumption: { valueHelp: '_ChangedUserVH' }
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 110, importance: #HIGH }]
Document.LastChangedByUser as LastChangedByUser,
@ObjectModel.readOnly: true
@EndUserText.label:'Last Changed By User Full Name'
@Consumption.filter.hidden: true
Document._ChangedUser.UserDescription as LastChangedByUserFullName,
//@ObjectModel.foreignKey.association:'_CreatedUser'
//--
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordUserVH',
element: 'ResponsiblePersonName' },
additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocumentInfoRecordDocNumber',
element: 'DocumentInfoRecordDocNumber' },
{ localElement: 'DocumentInfoRecordDocVersion',
element: 'DocumentInfoRecordDocVersion' },
{ localElement: 'DocumentInfoRecordDocPart',
element: 'DocumentInfoRecordDocPart' }]
}]
// ]--
//@Consumption: { valueHelp: '_CreatedUserVH' }
@Consumption.filter.hidden: true
Document.CreatedByUser as CreatedByUser,
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 90, importance: #HIGH }]
Document.CreationDateTime as CreationDateTime,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
//--
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_DocumentInfoRecordUserVH',
element: 'ResponsiblePersonName' },
additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
element: 'DocumentInfoRecordDocType' },
{ localElement: 'DocumentInfoRecordDocNumber',
element: 'DocumentInfoRecordDocNumber' },
{ localElement: 'DocumentInfoRecordDocVersion',
element: 'DocumentInfoRecordDocVersion' },
{ localElement: 'DocumentInfoRecordDocPart',
element: 'DocumentInfoRecordDocPart' }]
}]
// ]--
//@Consumption: { valueHelp: '_UserDetailsVH' }
@UI.selectionField: {position: 70}
@UI.lineItem: { position: 70, importance: #HIGH}
//@ObjectModel.readOnly: true
@UI.fieldGroup: [ { qualifier: 'DDsection2', position: 10, importance: #HIGH }]
@ObjectModel.text.element: [ 'ResponsiblePersonFullName' ]
Document.ResponsiblePersonName as ResponsiblePersonName,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@ObjectModel.readOnly: true
@EndUserText.label:'User Name'
@Consumption.filter.hidden: true
Document._UserDetails.UserDescription as ResponsiblePersonFullName,
@Consumption.filter.hidden: true
Document.DocInfoRecdSourceDocPart as DocInfoRecdSourceDocPart,
@Consumption.filter.hidden: true
Document.DocInfoRecdSourceDocVersion as DocInfoRecdSourceDocVersion,
@Consumption.filter.hidden: true
@EndUserText.quickInfo: 'DocumentInfoRecord Structure Indicator'
Document.IsDocInfoRecdStructure as IsDocInfoRecdStructure,
@Consumption.filter.hidden: true
Document.DocInfoRecdSourceDocNumber as DocInfoRecdSourceDocNumber,
@Consumption.valueHelpDefinition: [{ entity: { name : 'C_DocumentInfoRecordDescVH', element : 'DocumentDescription' },
additionalBinding: [{localElement: 'DocumentInfoRecordDocType' , element : 'DocumentInfoRecordDocType'},
{localElement: 'DocumentInfoRecordDocNumber' , element : 'DocumentInfoRecordDocNumber'},
{localElement: 'DocumentInfoRecordDocPart' , element : 'DocumentInfoRecordDocPart'},
{localElement: 'DocumentInfoRecordDocVersion', element : 'DocumentInfoRecordDocVersion'}] }]
//@UI.fieldGroup: [{ qualifier: 'DDsection1', groupLabel: 'Data Description', position: 10, importance: #HIGH }]
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@Semantics.text: true
@ObjectModel.readOnly: true
@UI.lineItem: { position: 50, importance: #HIGH}
@UI.selectionField: {position: 50}
@EndUserText.label: 'Document Description'
@EndUserText.quickInfo: 'Document Description'
@ObjectModel.enabled: true
@ObjectModel.mandatory: false
_Desc[1: Language = $session.system_language].DocumentDescription,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
// @UI.hidden: true
@ObjectModel.readOnly: true
@Consumption.filter.hidden: true
@Consumption.hidden: true
Document._DocType._Text[1: Language = $session.system_language].DocumentTypeDescription,
@UI.hidden: true
Document.InternalDocumentStatus as InternalDocumentStatus,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@ObjectModel.readOnly: true
@UI.dataPoint: {title: 'Document Status'}
@EndUserText.label: 'Document Status Description'
@UI.dataPoint.criticality: 'CheckStatusCriticality'
@EndUserText.quickInfo: 'Document Status Name SAP'
@Consumption.filter.hidden: true
Document._DocStatus._Text[1: Language = $session.system_language].DocumentStatusName as DocumentStatusName,
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@Search.fuzzinessThreshold: 0.8
@ObjectModel.mandatory: true
@ObjectModel.readOnly: true
@UI.selectionField: {position: 60}
//@UI.selectionField: {position: 60, label: 'Document Status'}
@UI.lineItem: { position: 60,label: 'Status (Code)', importance: #HIGH}
@ObjectModel.text.element: [ 'DocumentStatusName' ]
@Consumption.valueHelpDefinition: [{ entity: { name : 'C_DocumentInfoRecordStatusVH', element : 'ExternalDocumentStatus' },
additionalBinding: [{localElement: 'DocumentStatusName' , element : 'DocumentStatusName'}]}]
//@UI.fieldGroup: [ { qualifier: 'DDsection1', groupLabel: 'Data Description', position: 20, importance: #HIGH }]
@EndUserText.label: 'Document Status'
@EndUserText.quickInfo: 'Document Status'
Document._DocStatus._Text[1: Language = $session.system_language].ExternalDocumentStatus as ExternalDocumentStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast( '' as abap.numc( 1 )) as Criticality,
// Document.
// _DIRCalcFields.Criticality,
@UI.hidden: true
@ObjectModel.readOnly: true
// InternalDocumentStatus
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast( '' as abap.numc(1)) as CheckStatusCriticality,
// _DIRCalcFields.CheckStatusCriticality,
@ObjectModel.text.element: [ 'CADStatusDescription' ]
//@ObjectModel.filter.enabled:false -> Fields
@Consumption.filter.hidden: true
Document.IsDocInfoRecdCreatedFromCAD as IsDocInfoRecdCreatedFromCAD,
@ObjectModel.readOnly: true
@UI.dataPoint: {title: 'CAD Indicator'}
@EndUserText.label:'CAD Status Description'
@EndUserText.quickInfo: 'CAD Status Description'
@Consumption.filter.hidden: true
Document._Indicator._Text._CadStatusText[1: Language = $session.system_language].CADStatusDescription as CADStatusDescription,
@ObjectModel.text.element: [ 'DeleteStatusDescription' ]
@EndUserText.quickInfo: 'Deletion Indicator'
@Consumption.filter.hidden: true
Document.DocInfoRecdIsMarkedForDeletion as DocInfoRecdIsMarkedForDeletion,
@ObjectModel.readOnly: true
@UI.dataPoint: {title: 'Deletion Flag'}
@UI.dataPoint.criticality: 'Criticality'
@EndUserText.label:'Delete Status Description'
@EndUserText.quickInfo: 'Delete Status Description'
@Consumption.filter.hidden: true
Document._Indicator._Text._DeltnStatusText[1: Language = $session.system_language].DeleteStatusDescription as DeleteStatusDescription,
@ObjectModel.readOnly: true
@Consumption.valueHelp: '_CADValueHelp'
@Consumption: { filter:{ selectionType: #SINGLE, multipleSelections: false} }
@EndUserText.label:'Created from CAD'
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 30, importance: #HIGH }]
@EndUserText.quickInfo: 'Created from CAD'
cast( Document.IsDocInfoRecdCreatedFromCAD as xfeld ) as DocumentIsCreatedByCAD,
// cast( _DIRCalcFields.DocumentIsCreatedByCAD as xfeld ) as DocumentIsCreatedByCAD,
@ObjectModel.readOnly: true
@Consumption.valueHelp: '_DeletionValueHelp'
@Consumption: { filter:{ selectionType: #SINGLE, multipleSelections: false} }
@EndUserText.label:'Marked for Deletion'
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 10, importance: #HIGH }]
@EndUserText.quickInfo: 'Marked for Deletion'
// cast( _DIRCalcFields.DocInfoRecdIsDeleted as xfeld ) as DocInfoRecdIsDeleted,
cast( Document.DocInfoRecdIsMarkedForDeletion as xfeld ) as DocInfoRecdIsDeleted,
// Field for Interim Classification UI Direct Refresh
@UI.hidden: true
Document.ClassificationSideEffect,
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_DocumentInfoRecordLbtryOffc', element : 'LaboratoryOrDesignOffice' } }]
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 120, importance: #HIGH },
{ qualifier: 'DDsection2', position: 20, importance: #MEDIUM }]
@ObjectModel.text.element: [ 'LaboratoryOrDesignOfficeName' ]
Document.LaboratoryOrDesignOffice as LaboratoryOrDesignOffice,
@ObjectModel.readOnly: true
@Consumption.filter.hidden: true
@EndUserText.label:'Description of the Laboratory/Office'
_LabOffice._Text[1: Language = $session.system_language].LaboratoryOrDesignOfficeName as LaboratoryOrDesignOfficeName,
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_DocumentInfoRecordAuthznGrp', element : 'AuthorizationGroup' } }]
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 130, importance: #HIGH },
{ qualifier: 'DDsection2', position: 30, importance: #MEDIUM }]
@ObjectModel.text.element: [ 'AuthorizationGroupName' ]
@EndUserText.quickInfo: 'Authorization Group Name'
Document.AuthorizationGroup as AuthorizationGroup,
@ObjectModel.readOnly: true
@EndUserText.quickInfo: 'Authorization Group Name'
@Consumption.filter.hidden: true
Document._AuthGroup._Text[1: Language = $session.system_language].AuthorizationGroupName as AuthorizationGroupName,
@UI.fieldGroup: [ { qualifier: 'LogData', groupLabel: 'Document Info Record', position: 140, importance: #HIGH },
{ qualifier: 'DDsection2', position: 40, importance: #MEDIUM }]
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_ChangeMasterVH',
element: 'ChangeNumber' }
}]
Document.ChangeNumber as ChangeNumber,
-- Original Handling
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast ( 1 as ux_field_control preserving type) as IsAttachmentsEnabled,
-- Object Links
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast ( 1 as ux_field_control preserving type) as IsSAPObjectLinkEnabled,
-- Classification
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast ( 1 as ux_field_control preserving type) as IsClassificationEnabled,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast ( 1 as ux_field_control preserving type) as DescriptionProperty,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_I_D_DOCUMENTINFORECORDTP_AC'
cast ( 'X' as boole_d preserving type ) as AutoClassificationIsEnabled,
@Consumption.filter.hidden: true
Document._ChangedUser,
@Consumption.filter.hidden: true
Document._CreatedUser,
@Consumption.filter.hidden: true
Document._UserDetails,
@Consumption.filter.hidden: true
Document._ChangedUserVH,
@Consumption.filter.hidden: true
Document._CreatedUserVH,
@Consumption.filter.hidden: true
Document._UserDetailsVH,
@Consumption.filter.hidden: true
Document._DocNumber,
@Consumption.filter.hidden: true
Document._DocPart,
@Consumption.filter.hidden: true
Document._DocType,
@Consumption.filter.hidden: true
Document._DocVersion,
@Consumption.filter.hidden: true
Document._Indicator,
@Consumption.filter.hidden: true
Document._AuthGroup,
@Consumption.filter.hidden: true
Document._LabOffice,
@Consumption.filter.hidden: true
_SAPObjectVH,
@Consumption.filter.hidden: true
_CADValueHelp,
@Consumption.filter.hidden: true
_DeletionValueHelp,
@Consumption.filter.hidden: true
_StatusText,
@Consumption.filter.hidden: true
_DIRVersion,
Document._LogAccMObjectTypeActive,
Document._LogAccMObjectUserAuthzn,
Document._LogAccMObjSecureIDAssgmt,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_Desc,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_ObjLink,
//--[ GENERATED:011:29JlHNUf7jY4gJbXw{Mp80
@Consumption.filter.hidden: true
_DocTypeText,
@Consumption.filter.hidden: true
_DocumentTypeText,
// ]--GENERATED
_ChangeMasterVH
}