C_DfsScenClfnObjectCharcVal

@AbapCatalog.sqlViewName:            'CDFSSCNCLFNVAL'
@Metadata.allowExtensions:           true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:            true
@EndUserText.label:                  'Consumption View for Scenario Classification values'

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm:  #SESSION_VARIABLE
@VDM.viewType:              #CONSUMPTION

@ObjectModel.usageType.dataClass:      #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory:   #L

define view C_DfsScenClfnObjectCharcVal
  as select from    I_ClfnObjectCharcValForKeyDate(P_KeyDate:$session.system_date)        as _ClfnObjectCharcVal

    inner join      I_ClfnCharcDescForKeyDate(P_KeyDate:$session.system_date)             as _ClfnCharcDesc      on  _ClfnObjectCharcVal.CharcInternalID      = _ClfnCharcDesc.CharcInternalID
                                                                                                                 and _ClfnCharcDesc.Language                  = $session.system_language
    left outer to one join I_ClfnCharcValueForKeyDate(P_KeyDate:$session.system_date)     as _ClfnCharcValue     on  _ClfnObjectCharcVal.CharcInternalID      = _ClfnCharcValue.CharcInternalID
                                                                                                                 and _ClfnObjectCharcVal.CharcValue           = _ClfnCharcValue.CharcValue
    left outer to one join I_ClfnCharcValueDescForKeyDate(P_KeyDate:$session.system_date) as _ClfnCharcValueDesc on  _ClfnObjectCharcVal.CharcInternalID      = _ClfnCharcValueDesc.CharcInternalID
                                                                                                                 and _ClfnCharcValue.CharcValuePositionNumber = _ClfnCharcValueDesc.CharcValuePositionNumber
                                                                                                                 and _ClfnCharcValueDesc.Language             = $session.system_language

{

  key _ClfnObjectCharcVal.ClfnObjectID,
  key _ClfnObjectCharcVal.ClfnObjectTable,
      @UI.hidden: true
  key _ClfnObjectCharcVal.CharcInternalID,
  key _ClfnObjectCharcVal.ClassType,
  key _ClfnObjectCharcVal.CharcValue,
      _ClfnCharcValue.CharcValuePositionNumber,
      _ClfnCharcDesc.CharcDescription,
      _ClfnCharcValueDesc.CharcValueDescription,

      _ClfnObjectCharcVal.CharcFromNumericValue,
      _ClfnObjectCharcVal.CharcFromNumericValueUnit,
      _ClfnObjectCharcVal.CharcToNumericValue,
      _ClfnObjectCharcVal.CharcToNumericValueUnit,
      _ClfnObjectCharcVal._Characteristic,
      
      @ObjectModel.sort.enabled: true
      @ObjectModel.filter.enabled: true
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_DFS_SCENARIO_CLF'
      cast( '' as abap.char(70) ) as DfsScenarioCharacteristicValue

}
where
  (
       ClassType = 'SCN'
    or ClassType = 'SCA'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCHARCDESCFORKEYDATE",
"I_CLFNCHARCVALUEDESCFORKEYDATE",
"I_CLFNCHARCVALUEFORKEYDATE",
"I_CLFNOBJECTCHARCVALFORKEYDATE"
],
"ASSOCIATED":
[
"I_CLFNCHARACTERISTICFORKEYDATE"
],
"BASE":
[
"I_CLFNOBJECTCHARCVALFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/