@AbapCatalog.sqlViewName: 'CDDREPL'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XXL, dataClass: #MIXED}
@Search.searchable: true
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Demand Driven Replenishment'
@UI.headerInfo.typeName: 'Buffer'
@UI.headerInfo.typeNamePlural: 'Buffers'
@UI.headerInfo.title: { type: #STANDARD, value: 'Material' }
@UI.headerInfo.description : { type: #STANDARD, value: 'MaterialName' }
define view C_DemandDrivenReplnmt
as select from P_DemandDrivenCalcValues as calculatedvalues
inner join I_SDMAreaOfResponsibility as _SDMAreaOfResponsibility on calculatedvalues.Plant = _SDMAreaOfResponsibility.Plant
and calculatedvalues.MRPController = _SDMAreaOfResponsibility.MRPController
and _SDMAreaOfResponsibility.UserID = $session.user
association [0..1] to C_DemandDrivenProductVH as _Material on calculatedvalues.Material = _Material.Material
association [0..1] to C_OnHandStockStatusVH as _OnHandStockStatusVH on $projection.OnHandStockStatus = _OnHandStockStatusVH.OnHandStockStatus
association [0..1] to C_ProdPlngPriorityStatusVH as _ProdPlngPriorityStatusVH on $projection.MaterialPlanningPriorityStatus = _ProdPlngPriorityStatusVH.MaterialPlanningPriorityStatus
association [0..1] to C_ProdPlngActionStatusVH as _ProdPlngActionStatusVH on $projection.OrderPlanningStatusText = _ProdPlngActionStatusVH.ProdPlanningActionStatusCode
association [0..1] to C_ProjectedStockOutStatusVH as _ProjectedStockOutStatusVH on $projection.ProjectedStockOutStatus = _ProjectedStockOutStatusVH.ProjectedStockOutStatus
association [0..1] to C_DmndDrivenConsumptionVH as _ConsumptionVH on $projection.ConsumptionCode = _ConsumptionVH.Status
association [0..1] to C_DmndDrivenVariabilityVH as _VariabilityVH on $projection.VariabilityCode = _VariabilityVH.VariabilityIndicator
association [0..1] to C_ReplenishmentLeadTimeVH as _ReplenishmentVH on $projection.ReplenishmentLeadTimeCode = _ReplenishmentVH.ReplenishmentLeadTimeValue
association [0..1] to C_BillOfMaterialUsageVH as _BOMUsageVH on $projection.BOMUsageCode = _BOMUsageVH.BOMUsageIndicator
association [1..1] to C_PlantVH as _PlantVH on $projection.Plant = _PlantVH.Plant
association [1..1] to I_MRPController as _MRPContr on $projection.Plant = _MRPContr.Plant
and calculatedvalues.MRPController = _MRPContr.MRPController
association [1..1] to C_MRPAreaValHelp as _MRPArea on $projection.MRPArea = _MRPArea.MRPArea
association [1..1] to I_UnitOfMeasure as demandDrivenUom on $projection.MaterialBaseUnit = demandDrivenUom.UnitOfMeasure
association [1..1] to I_UnitOfMeasure as _Units on $projection.BaseUnitofMeasure = _Units.UnitOfMeasure
association [0..1] to C_MaterialProcurementTypeVH as _ProcurementTypeVH on $projection.ProcurementType = _ProcurementTypeVH.ProcurementType
association [0..1] to I_DemandDrivenPlanningStatus as _PlanningStatus on $projection.Material = _PlanningStatus.Material
and $projection.Plant = _PlanningStatus.Plant
and _PlanningStatus.UserID = $session.user
//Extensibility Views
association [1..1] to E_Product as _ProductExt on $projection.Material = _ProductExt.Product
association [1..1] to E_Productplant as _ProductPlantExt on $projection.Material = _ProductPlantExt.Product
and $projection.Plant = _ProductPlantExt.Plant
association [1..1] to C_MRPControllerByAreaOfRespyVH as _MRPControllerVH on $projection.Plant = _MRPControllerVH.Plant
and $projection.MRPController = _MRPControllerVH.MRPController
association [1..1] to I_ProductPlantMRPArea as _MaterialInfo on $projection.Material = _MaterialInfo.Material
and $projection.Plant = _MaterialInfo.Plant
and $projection.MRPArea = _MaterialInfo.MRPArea
association [1..1] to C_MRPTypeVH as _MRPTypeVH on $projection.MRPType = _MRPTypeVH.MRPType
association [1..1] to C_MM_MaterialGroupValueHelp as _MaterialGroupVH on $projection.MaterialGroup = _MaterialGroupVH.MaterialGroup
association [0..1] to P_SCMProductLocationMap as _ProductLocation on _ProductLocation.product = $projection.Material
and _ProductLocation.plant = $projection.Plant
and _ProductLocation.mrparea = $projection.MRPArea
{
@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
@Consumption.valueHelpDefinition: [{entity:{name:'C_BufferedMaterialValHelp' , element: 'Material'}}]
@EndUserText:{label: 'Product',quickInfo: 'Product'}
@UI.fieldGroup.position: 10
@ObjectModel:{
text.element: [ 'MaterialName' ],
readOnly: true
}
@UI.textArrangement: #TEXT_LAST
key calculatedvalues.Material,
@Search: { ranking: #HIGH, fuzzinessThreshold: 0.8 }
@Consumption.valueHelpDefinition: [{entity:{name:'C_PlantByAreaOfRespyVH' , element: 'Plant'}}]
@UI.fieldGroup.position: 30
@ObjectModel.text.element: [ 'PlantName' ]
@UI.textArrangement: #TEXT_LAST
key calculatedvalues.Plant,
@Consumption.valueHelpDefinition: [{entity:{name:'C_MRPAreaValHelp' , element: 'MRPArea'}}]
@UI.fieldGroup.position: 40
@ObjectModel.text.element: [ 'MRPAreaText' ]
@UI.textArrangement: #TEXT_LAST
key calculatedvalues.MRPArea,
@Consumption.valueHelpDefinition: [{entity:{name:'C_MM_MaterialGroupValueHelp' , element: 'MaterialGroup'}}]
@EndUserText:{label: 'Product Group',quickInfo: 'Product Group'}
@UI.fieldGroup.position: 20
@ObjectModel.text.element: [ 'MaterialGroupName' ]
@UI.textArrangement: #TEXT_LAST
calculatedvalues.MaterialGroup,
@Consumption.valueHelpDefinition: [{entity:{name:'C_MRPTypeVH' , element: 'MRPType'}}]
@UI.fieldGroup.position: 50
@ObjectModel.text.element: [ 'MRPTypeName' ]
@UI.textArrangement: #TEXT_LAST
calculatedvalues.MRPType,
@UI.selectionField : [ { exclude: true } ]
@Consumption.valueHelpDefinition: [{entity:{name:'C_MRPControllerByAreaOfRespyVH' , element: 'MRPController'}}]
//@EndUserText.label: 'MRP Controller'
@UI.fieldGroup.position: 60
@ObjectModel.text.element: [ 'MRPControllerName' ]
@UI.textArrangement: #TEXT_LAST
calculatedvalues.MRPController,
@Search: {ranking: #HIGH, fuzzinessThreshold: 0.8 }
@UI.selectionField : [ { exclude: true } ]
@Consumption.filter.hidden: true
@EndUserText:{label: 'Product Description',quickInfo: 'Product Description'}
_Material.MaterialName,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.MaterialBaseUnit,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.BaseUnitofMeasure,
@Semantics.quantity.unitOfMeasure: 'DDPercentageBaseUnitCode'
@UI.lineItem.criticality: 'MaterialPlanningPriorityStatus'
@Consumption.filter.hidden: true
calculatedvalues.MaterialPlanningPriority,
@Consumption.filter.hidden: true
@UI.hidden: true
_PlantVH.PlantName,
@Consumption.filter.hidden: true
calculatedvalues.MRPGroup,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@UI.lineItem.criticality: 'MaterialPlanningPriorityStatus'
@Consumption.filter.hidden: true
round(calculatedvalues.NetFlowPositionQuantity, _Units.UnitOfMeasureNumberOfDecimals) as NetFlowPositionQuantity,
@Semantics.quantity.unitOfMeasure: 'BaseUnitOfMeasure'
@Consumption.filter.hidden: true
round(calculatedvalues.ProposedQuantity, _Units.UnitOfMeasureNumberOfDecimals) as ProposedQuantity,
@Semantics.quantity.unitOfMeasure: 'DDPercentageBaseUnitCode'
@Consumption.filter.hidden: true
round(calculatedvalues.OnHandBufferStatusQuantity, demandDrivenUom.UnitOfMeasureNumberOfDecimals) as OnHandBufferStatusQuantity,
@Semantics.quantity.unitOfMeasure: 'BaseUnitOfMeasure'
@Consumption.filter.hidden: true
round(calculatedvalues.OnHandStockQuantity, _Units.UnitOfMeasureNumberOfDecimals) as OnHandStockQuantity,
@Consumption.filter.hidden: true
@UI.hidden: true
round(calculatedvalues.ThresholdPercentage, _Units.UnitOfMeasureNumberOfDecimals) as OnHandAlertThldQty,
@Semantics.quantity.unitOfMeasure: 'BaseUnitOfMeasure'
@Consumption.filter.hidden: true
round(calculatedvalues.OpenSupplyQuantity, _Units.UnitOfMeasureNumberOfDecimals) as OpenSupplyQuantity,
@Consumption.filter.hidden: true
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
round(calculatedvalues.QualifiedDemandQuantity, _Units.UnitOfMeasureNumberOfDecimals) as QualifiedDemandQuantity,
@Consumption.filter.hidden: true
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
round(calculatedvalues.MaterialSafetyStockQty, _Units.UnitOfMeasureNumberOfDecimals) as MaterialSafetyStockQty,
@Consumption.filter.hidden: true
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
round(calculatedvalues.MaterialSafetyStockTodayQty, _Units.UnitOfMeasureNumberOfDecimals) as MaterialSafetyStockTodayQty,
@Consumption.filter.hidden: true
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
round(calculatedvalues.MaterialMaxStockLevelQuantity, _Units.UnitOfMeasureNumberOfDecimals) as MaterialMaxStockLevelQuantity,
@Consumption.filter.hidden: true
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
round(calculatedvalues.ReorderThresholdQuantity, _Units.UnitOfMeasureNumberOfDecimals) as ReorderThresholdQuantity,
@Consumption.filter.hidden: true
calculatedvalues.DecoupledLeadTime,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._ConsumptionText.ConsumptionDescription as ConsumptionDescription,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._ReplnmtText.ReplenishmentLeadTimeDesc as ReplenishmentLeadTimeDesc,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._BOMUsgText.BOMUsageDescription as BOMUsageDescription,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._VarText.VariabilityDescription as VariabilityDescription,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._ProcmtText.ProcurementTypeDescription
as ProcurementTypeDescription,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._OnHandStockStatusText.OnHandStockStatusDescription as OnHandStockStatusDescription,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._ProdPlngPrioStatusText.ProdPlngPrioStatusDescription as ProdPlngPrioStatusDescription,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._ProdPlngActionStatusText.ProdPlngActnStatusDescription as ProdPlngActnStatusDescription,
@Semantics.text: true
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues._ProjectedStockOutStatusText.ProjtdStkOutStsDesc as ProjtdStkOutStsDesc,
@Consumption.valueHelp: '_ProdPlngActionStatusVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'ProdPlngActnStatusDescription' ]
@Consumption.labelElement: 'ProdPlngActnStatusDescription'
@EndUserText.label: 'Planning Action Status'
@UI.selectionField.position: 30
calculatedvalues.OrderPlanningStatusText as OrderPlanningStatusText,
@Consumption.valueHelp: '_ProdPlngPriorityStatusVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'ProdPlngPrioStatusDescription' ]
@Consumption.labelElement: 'ProdPlngPrioStatusDescription'
@EndUserText.label: 'Planning Priority Status'
@UI.selectionField.position: 20
calculatedvalues.MaterialPlanningPriorityStatus,
@Consumption.valueHelp: '_OnHandStockStatusVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'OnHandStockStatusDescription' ]
@Consumption.labelElement: 'OnHandStockStatusDescription'
@EndUserText.label: 'On-Hand Stock Status'
@UI.selectionField.position: 10
calculatedvalues.OnHandStockStatus,
@Consumption.valueHelp: '_ProcurementTypeVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'ProcurementTypeDescription' ]
@Consumption.labelElement: 'ProcurementTypeDescription'
@EndUserText.label: 'Procurement Type'
@UI.selectionField.position: 40
calculatedvalues.ProcurementType,
@Consumption.valueHelp: '_VariabilityVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'VariabilityDescription' ]
@Consumption.labelElement: 'VariabilityDescription'
@EndUserText.label: 'Variability Indicator'
@UI.selectionField.position: 50
calculatedvalues.VariabilityCode,
@Consumption.valueHelp: '_ReplenishmentVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'ReplenishmentLeadTimeDesc' ]
@Consumption.labelElement: 'ReplenishmentLeadTimeDesc'
@EndUserText.label: 'Lead Time Indicator'
@UI.selectionField.position: 60
calculatedvalues.ReplenishmentLeadTimeCode,
@Consumption.valueHelp: '_ConsumptionVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'ConsumptionDescription' ]
@Consumption.labelElement: 'ConsumptionDescription'
@EndUserText.label: 'Value Indicator'
@UI.selectionField.position: 70
calculatedvalues.ConsumptionCode,
@Consumption.valueHelp: '_BOMUsageVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'BOMUsageDescription' ]
@Consumption.labelElement: 'BOMUsageDescription'
@EndUserText.label: 'BOM Usage Indicator'
@UI.selectionField.position: 80
calculatedvalues.BOMUsageCode,
@Consumption.valueHelp: '_ProjectedStockOutStatusVH'
@Consumption.filter.selectionType:#SINGLE
@Consumption.filter.multipleSelections: true
@ObjectModel.text.element: [ 'ProjtdStkOutStsDesc' ]
@Consumption.labelElement: 'ProjtdStkOutStsDesc'
@EndUserText.label: 'Projected On-Hand Alerts'
@UI.selectionField.position: 90
calculatedvalues.ProjectedStockOutStatus,
@UI.hidden: true
@Consumption.filter.hidden: true
demandDrivenUom.UnitOfMeasureNumberOfDecimals,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.PurOrdCrtnIsAllowed,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.SupplyCheckIsAllowed,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.BaseUnitofMeasure as ItemUoM,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.BOMUsageValue,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.ReplenishmentLeadTimeValue,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.VariabilityQuantity,
@UI.hidden: true
@Consumption.filter.hidden: true
@Semantics.amount.currencyCode: 'Currency'
calculatedvalues.ProductConsumptionAmount,
@ObjectModel.readOnly: true
@UI.hidden: true
@Semantics.currencyCode: true
calculatedvalues.Currency as Currency,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.IndividualLeadTime,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.ExpeditedDateTime,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.ExpeditedOnHandStockStatus,
@UI.hidden: true
@Consumption.filter.hidden: true
@Semantics.quantity.unitOfMeasure:'MaterialBaseUnit'
calculatedvalues.ExpeditedQuantity,
//This field is used to check if the buffer has execution action (yes - 1, no - 0)
@UI.hidden: true
@Consumption.filter.hidden: true
case when calculatedvalues.SupplyCheckIsAllowed = 1 and calculatedvalues.OnHandStockStatus <=2 and calculatedvalues.ExpeditedStatus != 1 then 1
else 0 end as BufferStatus,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.ExpeditedStatus,
// @UI.hidden: true
// @Consumption.filter.hidden: true
// case when _PlanningStatus.OrderPlanningStatusText = 'Q' then 1
// else
// case when calculatedvalues.ProposedQuantity > 0
// then 0
// else 2
// end
// end as OrderPlanningStatusText,
@Consumption.filter.hidden: true
@UI.hidden: true
_MRPArea.MRPAreaText as MRPAreaText,
@Consumption.filter.hidden: true
@UI.hidden: true
_MRPContr.MRPControllerName,
@Consumption.filter.hidden: true
@UI.hidden: true
_MaterialGroupVH.MaterialGroupName,
@UI.hidden: true
@Consumption.filter.hidden: true
_MRPTypeVH.MRPTypeName,
@ObjectModel.readOnly: true
@UI.hidden: true
_Material.MaterialAuthorizationGroup as ProductAuthorizationGroup,
@ObjectModel.readOnly: true
@UI.hidden: true
_Material.ProductTypeAuthorizationGroup as ProductTypeAuthorizationGroup,
@ObjectModel.readOnly: true
@UI.hidden: true
_Material.ProductGroupAuthorizationGroup as ProductGroupAuthorizationGroup,
@ObjectModel.readOnly: true
@UI.hidden: true
_MaterialInfo.RoundingProfile,
@ObjectModel.readOnly: true
@UI.hidden: true
_MaterialInfo.LotSizeRoundingQuantity,
// StockOut Alert values
@UI.hidden: true
@EndUserText.label: 'Stockout Alert Flag'
calculatedvalues.StockOutAlertIsPresent,
@Consumption.filter.hidden: true
@EndUserText.label: 'Stockout Alert Date'
cast ( calculatedvalues.FirstStkOutDate as dats ) as FirstStkOutDate,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Projected Stock On Stockout Alert'
calculatedvalues.FirstStkOutProjtdStkQty,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Safety Stock On Stockout Alert'
calculatedvalues.FirstStkOutProjtdSFTQty,
@Semantics.quantity.unitOfMeasure: 'DDPercentageBaseUnitCode'
@Consumption.filter.hidden: true
@EndUserText.label: 'Projected On-Hand Status On Stockout Alert'
calculatedvalues.FirstStkOutProjtdSFTPct,
@UI.hidden: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Stockout Alert In Days'
calculatedvalues.FirstStkOutFromTodayInDays,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.StkOutAlertMicroChartZoneValue,
// Threshold Alert values
@UI.hidden: true
@EndUserText.label: 'Threshold Alert Flag'
calculatedvalues.ThresholdAlertIsPresent,
@Consumption.filter.hidden: true
@EndUserText.label: 'Threshold Alert Date'
cast ( calculatedvalues.FirstBelowThldDate as dats ) as FirstBelowThldDate,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Projected Stock On Threshold Alert'
calculatedvalues.FirstBelowThldProjtdStkQty,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Safety Stock On Threshold Alert'
calculatedvalues.FirstBelowThldProjtdSFTQty,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Threshold On Threshold Alert'
calculatedvalues.FirstBelowThldThldLvlQty,
@Semantics.quantity.unitOfMeasure: 'DDPercentageBaseUnitCode'
@Consumption.filter.hidden: true
@EndUserText.label: 'Projected On-Hand Status On Threshold Alert'
calculatedvalues.FirstBelowThldProjtdSFTPct,
@UI.hidden: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Threshold Alert In Days'
calculatedvalues.FirstBelowThldFromTodayInDays,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.ThldAlertMicroChartZoneValue,
// Below SafetyStock Alert values
@UI.hidden: true
@EndUserText.label: 'Safety Stock Alert Flag'
calculatedvalues.SafetyStockAlertIsPresent,
@Consumption.filter.hidden: true
@EndUserText.label: 'Safety Stock Alert Date'
cast ( calculatedvalues.FirstBelowSFTDate as dats ) as FirstBelowSFTDate,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Projected Stock On Safety Stock Alert'
calculatedvalues.FirstBelowSFTProjtdStkQty,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Safety Stock On Safety Stock Alert'
calculatedvalues.FirstBelowSFTProjtdSFTQty,
@Semantics.quantity.unitOfMeasure: 'BaseUnitofMeasure'
@Consumption.filter.hidden: true
@EndUserText.label: 'Threshold On Safety Stock Alert'
calculatedvalues.FirstBelowSFTThldLvlQty,
@Semantics.quantity.unitOfMeasure: 'DDPercentageBaseUnitCode'
@Consumption.filter.hidden: true
@EndUserText.label: 'Projected On-Hand Status On Safety Stock Alert'
calculatedvalues.FirstBelowSFTProjtdSFTPct,
@UI.hidden: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Safety Stock Alert In Days'
calculatedvalues.FirstBelowSFTFromTodayInDays,
@UI.hidden: true
@Consumption.filter.hidden: true
calculatedvalues.SFTAlertMicroChartZoneValue,
@UI.hidden: true
@Consumption.filter.hidden: true
_ProductLocation.AdvancedPlanningProductName as AdvancedPlanningProductName,
@UI.hidden: true
@Consumption.filter.hidden: true
_ProductLocation.Location as Location,
@ObjectModel.readOnly: true
@UI.hidden: true
@Semantics.unitOfMeasure: true
@Consumption.filter.hidden: true
@EndUserText.label: '%'
cast('%' as unit) as DDPercentageBaseUnitCode,
@Consumption.filter.hidden: true
_Material,
@Consumption.filter.hidden: true
_PlantVH,
@Consumption.filter.hidden: true
_MRPContr,
@Consumption.filter.hidden: true
_ConsumptionVH,
@Consumption.filter.hidden: true
_ReplenishmentVH,
@Consumption.filter.hidden: true
_BOMUsageVH,
@Consumption.filter.hidden: true
_VariabilityVH,
@Consumption.filter.hidden: true
_MRPArea,
@Consumption.filter.hidden: true
_ProcurementTypeVH,
@Consumption.filter.hidden: true
_PlanningStatus,
@Consumption.filter.hidden: true
_MRPControllerVH,
@Consumption.filter.hidden: true
_OnHandStockStatusVH,
@Consumption.filter.hidden: true
_ProdPlngPriorityStatusVH,
@Consumption.filter.hidden: true
_ProdPlngActionStatusVH,
@Consumption.filter.hidden: true
_ProjectedStockOutStatusVH,
@Consumption.filter.hidden: true
_MRPTypeVH,
@Consumption.filter.hidden: true
_MaterialGroupVH
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_DEMANDDRIVENPRODUCTVH",
"C_MM_MATERIALGROUPVALUEHELP",
"C_MRPAREAVALHELP",
"C_MRPTYPEVH",
"C_PLANTVH",
"I_BOMUSAGETEXT",
"I_CONSUMPTIONTEXT",
"I_MRPCONTROLLER",
"I_ONHANDSTOCKSTATUSTEXT",
"I_PROCUREMENTTYPETEXT",
"I_PRODPLNGACTIONSTATUSTEXT",
"I_PRODPLNGPRIOSTATUSTEXT",
"I_PRODUCTPLANTMRPAREA",
"I_PROJECTEDSTOCKOUTSTATUSTEXT",
"I_REPLENISHMENTLEADTIMETEXT",
"I_SDMAREAOFRESPONSIBILITY",
"I_UNITOFMEASURE",
"I_VARIABILITYTEXT",
"P_DEMANDDRIVENCALCVALUES",
"P_SCMPRODUCTLOCATIONMAP"
],
"ASSOCIATED":
[
"C_BILLOFMATERIALUSAGEVH",
"C_DEMANDDRIVENPRODUCTVH",
"C_DMNDDRIVENCONSUMPTIONVH",
"C_DMNDDRIVENVARIABILITYVH",
"C_MATERIALPROCUREMENTTYPEVH",
"C_MM_MATERIALGROUPVALUEHELP",
"C_MRPAREAVALHELP",
"C_MRPCONTROLLERBYAREAOFRESPYVH",
"C_MRPTYPEVH",
"C_ONHANDSTOCKSTATUSVH",
"C_PLANTVH",
"C_PRODPLNGACTIONSTATUSVH",
"C_PRODPLNGPRIORITYSTATUSVH",
"C_PROJECTEDSTOCKOUTSTATUSVH",
"C_REPLENISHMENTLEADTIMEVH",
"E_PRODUCT",
"E_PRODUCTPLANT",
"I_DEMANDDRIVENPLANNINGSTATUS",
"I_MRPCONTROLLER",
"I_PRODUCTPLANTMRPAREA",
"I_UNITOFMEASURE",
"P_SCMPRODUCTLOCATIONMAP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/