C_DeliveryDocItemToBeBilled

DDL: C_DELIVERYDOCITEMTOBEBILLED SQL: CDELDOCITEMTBB Type: view CONSUMPTION

Delivery Document Item to Be Billed

C_DeliveryDocItemToBeBilled is a Consumption CDS View that provides data about "Delivery Document Item to Be Billed" in SAP S/4HANA. It reads from 2 data sources (I_OutboundDeliveryItem, I_BillingDueListItem) and exposes 17 fields with key fields OutboundDelivery, OutboundDeliveryItem.

2 data source(s) 17 fields

Data Sources (2)

SourceAliasJoin Type
I_OutboundDeliveryItem _OutboundDeliveryItem inner
I_BillingDueListItem BillingDueListItem from

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName CDELDOCITEMTBB view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #L view
Metadata.allowExtensions true view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.preserveKey true view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Delivery Document Item to Be Billed view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY OutboundDelivery
KEY OutboundDeliveryItem
BillingDocumentType BillingDocumentType
SalesOrganization SalesOrganization
DeliveryDocumentItemText I_OutboundDeliveryItem DeliveryDocumentItemText
ToBeBilledQuantity
BilledQuantity
TotalQuantity
DeliveryQuantityUnit I_OutboundDeliveryItem DeliveryQuantityUnit
DeliveryDocumentItemCategory I_OutboundDeliveryItem DeliveryDocumentItemCategory
Product I_OutboundDeliveryItem Product
ReferenceSDDocumentCategory I_BillingDueListItem ReferenceSDDocumentCategory
BillingDocumentDate BillingDocumentDate
_DeliveryQuantityUnit _DeliveryQuantityUnit
_ItemCategory _ItemCategory
_Product _Product
_ReferenceSDDocumentCategory I_BillingDueListItem _ReferenceSDDocumentCategory 
@AbapCatalog.sqlViewName: 'CDELDOCITEMTBB'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Delivery Document Item to Be Billed'
define view C_DeliveryDocItemToBeBilled
  as

  select from  I_BillingDueListItem   as BillingDueListItem

    inner join I_OutboundDeliveryItem as _OutboundDeliveryItem on BillingDueListItem.ReferenceSDDocument = _OutboundDeliveryItem.OutboundDelivery
{

  key cast ( _OutboundDeliveryItem.OutboundDelivery as vbeln_vl preserving type )                     as OutboundDelivery,

  key cast ( _OutboundDeliveryItem.OutboundDeliveryItem as posnr_vl preserving type )                 as OutboundDeliveryItem,

      @Consumption.hidden: true
      BillingDocumentType,
      @Consumption.hidden: true
      SalesOrganization,


      _OutboundDeliveryItem.DeliveryDocumentItemText,


      cast ( _OutboundDeliveryItem.ActualDeliveryQuantity as to_be_billed_quantity preserving type )  as ToBeBilledQuantity,

      @Semantics.quantity.unitOfMeasure: 'DeliveryQuantityUnit'
      cast ( _OutboundDeliveryItem.ActualDeliveryQuantity as billed_quantity preserving type )        as BilledQuantity,

      @Semantics.quantity.unitOfMeasure: 'DeliveryQuantityUnit'
      cast ( _OutboundDeliveryItem.ActualDeliveryQuantity as billing_total_quantity preserving type ) as TotalQuantity,

      @Semantics.unitOfMeasure: true
      _OutboundDeliveryItem.DeliveryQuantityUnit                                                      as DeliveryQuantityUnit,
      _OutboundDeliveryItem.DeliveryDocumentItemCategory,
      _OutboundDeliveryItem.Product,

      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      BillingDueListItem.ReferenceSDDocumentCategory,
      BillingDocumentDate,

      _DeliveryQuantityUnit,
      _ItemCategory,
      _Product,
      BillingDueListItem._ReferenceSDDocumentCategory
}
where
       ItemIsBillingRelevant                          = 'K'
  and  BillingDueListItem.ReferenceSDDocumentCategory = 'J'
  and(
       DeliveryRelatedBillingStatus                   = 'B'
    or DeliveryRelatedBillingStatus                   = 'A'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDUELISTITEM",
"I_OUTBOUNDDELIVERYITEM"
],
"ASSOCIATED":
[
"I_PRODUCT",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SDDOCUMENTCATEGORY",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_BILLINGDUELISTITEM",
"I_OUTBOUNDDELIVERYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More