C_DelivProcFlowReturnsDeliv

@AbapCatalog.sqlViewName: 'CDLVPROCFLRETDLV'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Delivery Process Flow - Node Returns Delivery'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'CustomerReturnDelivery'

define view C_DelivProcFlowReturnsDeliv 

with parameters @Consumption.hidden: true
                @Environment.systemField: #SYSTEM_LANGUAGE
                P_Language              :spras

as select from I_CustomerReturnDelivery 

  left outer join C_PutawayStatusText( P_Language: :P_Language ) as StatusText
    on I_CustomerReturnDelivery.OverallPickingStatus = StatusText.PutawayStatus    
  
{
    //Key

    key CustomerReturnDelivery,
    
    ShippingPoint,
      
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    StatusText.Language,
  
    //Category

    'T' as SDDocumentCategory,

    //Status

    OverallGoodsMovementStatus,
    
   //Attribute 1   

    case when OverallGoodsMovementStatus = 'C'
      then cast(ActualGoodsMovementDate as wadat)
      else cast(PlannedGoodsIssueDate   as wadat)
    end as GoodsMovementDate,
    
    //Attribute 2

    I_CustomerReturnDelivery.OverallPickingStatus,
    
    case when OverallGoodsMovementStatus = 'C'
      then cast('' as bezei)
      else case when I_CustomerReturnDelivery.OverallPickingStatus <> '' 
              then StatusText.PutawayStatusName
              else cast('' as bezei)
           end      
    end as OverallPickingStatusDesc,
    
    I_CustomerReturnDelivery._DeliveryDocumentType.DeliveryDocumentType,
    I_CustomerReturnDelivery._DeliveryDocumentType._Text[1: Language = $parameters.P_Language].DeliveryDocumentTypeName as ProcessFlowNodeTitle,
    
    I_CustomerReturnDelivery._DeliveryDocumentType._Text[1: Language = $parameters.P_Language].DeliveryDocumentTypeName as ProcessFlowNodeShortTitle, 
    
    //Associations

    StatusText._Language    
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PUTAWAYSTATUSTEXT",
"I_CUSTOMERRETURNDELIVERY",
"I_DELIVERYDOCUMENTTYPE",
"I_DELIVERYDOCUMENTTYPETEXT"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[
"C_PUTAWAYSTATUSTEXT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/