C_DelivProcFlowInbDeliv

@AbapCatalog.sqlViewName: 'CDLVPROCFLIBDLV'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK 
@EndUserText.label: 'Delivery Process Flow - Node Inbound Delivery'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'InboundDelivery'

define view C_DelivProcFlowInbDeliv 

with parameters @Consumption.hidden: true
                @Environment.systemField: #SYSTEM_LANGUAGE
                P_Language              :spras
                
as select from I_InboundDelivery 

    left outer join C_PutawayStatusText( P_Language: :P_Language ) as StatusText 
      on I_InboundDelivery.OverallPutawayStatus = StatusText.PutawayStatus    

{
    //Key

    key InboundDelivery,
    
    ShippingPoint,
      
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    StatusText.Language,
  
    //Category

    SDDocumentCategory,

    //Status

    OverallGoodsMovementStatus,
    
   //Attribute 1   

    case when OverallGoodsMovementStatus = 'C'
      then cast(ActualGoodsMovementDate as wadat)
      else cast(PlannedGoodsIssueDate   as wadat)
    end as GoodsMovementDate,    

   //GoodsIssueDate obsolete

    case when OverallGoodsMovementStatus = 'C'
      then cast(ActualGoodsMovementDate as wadat)
      else cast(PlannedGoodsIssueDate   as wadat)
    end as GoodsIssueDate,    
    
    //Attribute 2

    I_InboundDelivery.OverallPutawayStatus,
    
    case when OverallGoodsMovementStatus = 'C'
      then cast('' as bezei)
      else StatusText.PutawayStatusName               
    end as OverallPutawayStatusName,
    
   I_InboundDelivery._DeliveryDocumentType.DeliveryDocumentType,
   I_InboundDelivery._DeliveryDocumentType._Text[1: Language =  :P_Language].DeliveryDocumentTypeName as ProcessFlowNodeTitle,
   
   I_InboundDelivery._DeliveryDocumentType._Text[1: Language =  :P_Language].DeliveryDocumentTypeName as ProcessFlowNodeShortTitle,
    
       
    //Associations

    StatusText._Language
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PUTAWAYSTATUSTEXT",
"I_DELIVERYDOCUMENTTYPE",
"I_DELIVERYDOCUMENTTYPETEXT",
"I_INBOUNDDELIVERY"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[
"C_PUTAWAYSTATUSTEXT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/