@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.semanticKey: ['DeliveryDocument', 'DeliveryDocumentItem']
@ObjectModel.representativeKey: 'DeliveryDocumentItem'
@EndUserText.label: 'Delivery Doc Item Incomplete Data'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@Search.searchable: false
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CDELIVDOCITMDE03'
define view C_DelivDocItemIncomplete
as select from I_DeliveryDocumentItem as Item
inner join I_SalesOrderInDelivIncomplete as Issue
on Item.DeliveryDocument = Issue.DeliveryDocument
and Item.DeliveryDocumentItem = Issue.DeliveryDocumentItem
//Extensibility
association [0..1] to E_DeliveryDocumentItem as _Extension on $projection.DeliveryDocument = _Extension.DeliveryDocument
and $projection.DeliveryDocumentItem = _Extension.DeliveryDocumentItem
{
//Key
//SDF4
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_DeliveryDocumentStdVH', element: 'DeliveryDocument' }}]
@ObjectModel.foreignKey.association: '_DeliveryDocument'
key Item.DeliveryDocument,
key Item.DeliveryDocumentItem,
//Category
Item.DeliveryDocumentItemCategory,
Item.DeliveryDocumentItemText,
//DueDays
@DefaultAggregation: #NONE
Issue.DueDays,
//Product
//SDF4
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' }}]
@ObjectModel.text.element: [ 'MaterialName' ]
@Consumption.semanticObject: 'Material'
cast(Item.Material as productnumber preserving type ) as Material,
@UI.hidden: true
Item._Material._Text[1:Language=$session.system_language].MaterialName,
Item.MaterialByCustomer,
cast(Item.MaterialGroup as productgroup preserving type ) as MaterialGroup,
@Consumption.semanticObject: 'Batch'
Item.Batch,
Item.Plant,
//SDF4
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_WarehouseStdVH', element: 'Warehouse' }}]
@ObjectModel.text.element: 'WarehouseName'
Item.Warehouse,
@UI.hidden: true
Item._Warehouse._Text[1:Language=$session.system_language].WarehouseName,
Item.StorageLocation,
//Delivery
@DefaultAggregation: #NONE
Item.ActualDeliveryQuantity,
Item.DeliveryQuantityUnit,
@DefaultAggregation: #NONE
Item.ItemGrossWeight,
@DefaultAggregation: #NONE
Item.ItemNetWeight,
Item.ItemWeightUnit,
@DefaultAggregation: #NONE
Item.ItemVolume,
Item.ItemVolumeUnit,
Item.LoadingGroup,
Item.TransportationGroup,
Item.GoodsMovementType,
Item.InventorySpecialStockType,
Item.StockType,
//SDF4
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_WarehouseStagingAreaStdVH', element: 'WarehouseStagingArea' },
additionalBinding: [{ localElement: 'Warehouse', element: 'Warehouse' }]}]
@ObjectModel.text.element: 'WarehouseStagingAreaName'
Item.WarehouseStagingArea,
@UI.hidden: true
Item._WarehouseStagingArea._Text[1:Language=$session.system_language].WarehouseStagingAreaName,
Item.OverdelivTolrtdLmtRatioInPct,
Item.UnderdelivTolrtdLmtRatioInPct,
//Billing
Item.ItemBillingBlockReason,
//Status
Item.PickingStatus,
Item.DeliveryRelatedBillingStatus,
Item.PackingStatus,
Item.PickingConfirmationStatus,
Item.WarehouseActivityStatus,
Item.GoodsMovementStatus,
@ObjectModel.foreignKey.association: '_ItemGeneralIncompletionStatus'
cast(Item.ItemGeneralIncompletionStatus as item_general_incompletion_sts preserving type) as ItemGeneralIncompletionStatus,
@ObjectModel.foreignKey.association: '_ItemDelivIncompletionSts'
cast(Item.ItemDeliveryIncompletionStatus as itm_deliv_incompletion_status preserving type) as ItemDeliveryIncompletionStatus,
@ObjectModel.foreignKey.association: '_ItemPickingIncompletionStatus'
cast(Item.ItemPickingIncompletionStatus as itm_pickg_incompletion_status preserving type) as ItemPickingIncompletionStatus ,
@ObjectModel.foreignKey.association: '_ItemPackingIncompletionStatus'
cast(Item.ItemPackingIncompletionStatus as itm_packg_incompletion_status preserving type) as ItemPackingIncompletionStatus,
@ObjectModel.foreignKey.association: '_ItemBillingIncompletionStatus'
cast(Item.ItemBillingIncompletionStatus as itms_incompltn_sts_billg preserving type) as ItemBillingIncompletionStatus,
@ObjectModel.foreignKey.association: '_ItemGdsMvtIncompletionSts'
cast(Item.ItemGdsMvtIncompletionSts as itm_gdsmvt_incompletion_status preserving type) as ItemGdsMvtIncompletionSts ,
//Criticality
@UI.hidden: true
cast(
case
when ItemGeneralIncompletionStatus <> 'C' and DueDays > 0 then 2
when ItemGeneralIncompletionStatus <> 'C' and DueDays <= 0 then 1
else 3
end as abap.int1
) as ItmGenIncompltnStsCriticality,
@UI.hidden: true
cast(
case
when ItemDeliveryIncompletionStatus <> 'C' and DueDays > 0 then 2
when ItemDeliveryIncompletionStatus <> 'C' and DueDays <= 0 then 1
else 3
end as abap.int1
) as ItmDelivIncompltnStsCritlty,
@UI.hidden: true
cast(
case
when ItemPickingIncompletionStatus <> 'C' and DueDays > 0 then 2
when ItemPickingIncompletionStatus <> 'C' and DueDays <= 0 then 1
else 3
end as abap.int1
) as ItmPickingIncompltnStsCritlty,
@UI.hidden: true
cast(
case
when ItemPackingIncompletionStatus <> 'C' and DueDays > 0 then 2
when ItemPackingIncompletionStatus <> 'C' and DueDays <= 0 then 1
else 3
end as abap.int1
) as ItmPackgIncompltnStsCritlty,
@UI.hidden: true
cast(
case
when ItemGdsMvtIncompletionSts <> 'C' and DueDays > 0 then 2
when ItemGdsMvtIncompletionSts <> 'C' and DueDays <= 0 then 1
else 3
end as abap.int1
) as ItmGdsMvtIncompltnStsCritlty,
@UI.hidden: true
cast(
case
when ItemBillingIncompletionStatus <> 'C' and DueDays > 0 then 2
when ItemBillingIncompletionStatus <> 'C' and DueDays <= 0 then 1
else 3
end as abap.int1
) as ItmBillingIncompltnStsCritlty,
//Associations
@Consumption.filter.hidden: true
_DeliveryDocument,
@Consumption.filter.hidden: true
_ItemCategory,
@Consumption.filter.hidden: true
_Material,
@Consumption.filter.hidden: true
_MaterialGroup,
@Consumption.filter.hidden: true
_Plant,
@Consumption.filter.hidden: true
_Warehouse,
@Consumption.filter.hidden: true
_StorageLocation,
@Consumption.filter.hidden: true
_DeliveryQuantityUnit,
@Consumption.filter.hidden: true
_ItemWeightUnit,
@Consumption.filter.hidden: true
_ItemVolumeUnit,
@Consumption.filter.hidden: true
_LoadingGroup,
@Consumption.filter.hidden: true
_TransportationGroup,
@Consumption.filter.hidden: true
_GoodsMovementType,
@Consumption.filter.hidden: true
_InventorySpecialStockType,
@Consumption.filter.hidden: true
_WarehouseStagingArea,
@Consumption.filter.hidden: true
_ItemBillingBlockReason,
@Consumption.filter.hidden: true
_PickingStatus,
@Consumption.filter.hidden: true
_DeliveryRelatedBillingStatus,
@Consumption.filter.hidden: true
_PackingStatus,
@Consumption.filter.hidden: true
_PickingConfirmationStatus,
@Consumption.filter.hidden: true
_WarehouseActivityStatus,
@Consumption.filter.hidden: true
_GoodsMovementStatus,
@Consumption.filter.hidden: true
_ItemGeneralIncompletionStatus,
@Consumption.filter.hidden: true
_ItemDelivIncompletionSts,
@Consumption.filter.hidden: true
_ItemPickingIncompletionStatus,
@Consumption.filter.hidden: true
_ItemPackingIncompletionStatus,
@Consumption.filter.hidden: true
_ItemBillingIncompletionStatus,
@Consumption.filter.hidden: true
_ItemGdsMvtIncompletionSts
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENTITEM",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_SALESORDERINDELIVINCOMPLETE",
"I_WAREHOUSE",
"I_WAREHOUSESTAGINGAREA",
"I_WAREHOUSESTAGINGAREATEXT",
"I_WAREHOUSETEXT"
],
"ASSOCIATED":
[
"E_DELIVERYDOCUMENTITEM",
"I_BILLINGBLOCKREASON",
"I_DELIVERYDOCUMENT",
"I_DELIVERYRELATEDBILLGSTATUS",
"I_GOODSMOVEMENTSTATUS",
"I_GOODSMOVEMENTTYPE",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_ITEMBILLINGINCOMPLETIONSTS",
"I_ITEMDELIVINCOMPLETIONSTS",
"I_ITEMGDSMVTINCOMPLETIONSTS",
"I_ITEMGENINCOMPLETIONSTATUS",
"I_ITEMPACKINGINCOMPLETIONSTS",
"I_ITEMPICKINGINCOMPLETIONSTS",
"I_LOADINGGROUP",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PACKINGSTATUS",
"I_PICKINGCONFIRMATIONSTATUS",
"I_PICKINGSTATUS",
"I_PLANT",
"I_SALESDOCUMENTITEMCATEGORY",
"I_STORAGELOCATION",
"I_TRANSPORTATIONGROUP",
"I_UNITOFMEASURE",
"I_WAREHOUSE",
"I_WAREHOUSEACTIVITYSTATUS",
"I_WAREHOUSESTAGINGAREA"
],
"BASE":
[
"I_DELIVERYDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/