C_DefectRecordAffectedObject

@AbapCatalog.sqlViewName: 'CDEFRECAFFCDOBJ'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Object Affected by Defect'

@VDM: {
    viewType: #CONSUMPTION
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #C },
    representativeKey: 'DefectAffectedObject',
    semanticKey:  [ 'DefectInternalID', 'DefectAffectedObject' ],

// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated:true,
    
    createEnabled: false,
    updateEnabled: 'EXTERNAL_CALCULATION',
    deleteEnabled: false
// End Draft

}

@Metadata.allowExtensions: true

define view C_DefectRecordAffectedObject as select from I_DefectAffectedObjectTP as _DefectAffectedObjectTP

  association [1..1] to C_DefectRecord as _Defect on $projection.DefectInternalID = _Defect.DefectInternalID

{
      @ObjectModel.foreignKey.association: '_Defect'
  key _DefectAffectedObjectTP.DefectInternalID,
      
  key _DefectAffectedObjectTP.DefectAffectedObject,

      _DefectAffectedObjectTP.DefectAffectedObjectType,

      @ObjectModel.text.element: ['ProductName']
      @Consumption: {
              valueHelpDefinition: [ 
                          { entity:  { name:    'I_ProductVH',
                                       element: 'Product' }
                          },
                          { entity:  { name:    'I_ProductPlantVH',
                                       element: 'Product' },
                            qualifier: 'vh_productplant_vh',
                            additionalBinding: [{ localElement: 'Plant', element: 'Plant', usage: #FILTER }]
                          }
              ],
              semanticObject: 'Material' 
      }
      _DefectAffectedObjectTP.Material,
      @ObjectModel.readOnly: true
      _DefectAffectedObjectTP._Product._Text[1: Language = $session.system_language ].ProductName,
      _DefectAffectedObjectTP.DefectAffectedObjectQuantity,

      
      _DefectAffectedObjectTP.QltyTaskFollowUpAction,
      _DefectAffectedObjectTP.QltyTaskFllwUpActionSts,
      _DefectAffectedObjectTP.QualityTask,
      _DefectAffectedObjectTP.QualityTaskInternalId,
      _DefectAffectedObjectTP.QltyTskFllwUpActnSimlnRslt,

      @ObjectModel.sort.enabled: false
      @ObjectModel.filter.enabled: false
      @Consumption: {
              valueHelpDefinition: [ 
                          { entity:  { name:    'I_ProductUnitsOfMeasureVH',
                                       element: 'AlternativeUnit' },
                            additionalBinding: [{ localElement: 'Material',
                                                  element: 'Product' }]                    
                          },
                          { entity:  { name:    'I_UnitOfMeasureStdVH',
                                       element: 'UnitOfMeasure' },
                            qualifier: 'vh_uom_stdvh'
                          }
                          ]
      }
      _DefectAffectedObjectTP.DefectAffcdObjQuantityUnit,
      
      @Consumption: {
        semanticObject: 'Batch',
        valueHelpDefinition: [
        {   entity: { name: 'I_BatchVH', element: 'Batch' },
            additionalBinding: [{ element: 'Plant', localElement: 'Plant', usage: #FILTER }, { element: 'Material', localElement: 'Material' }]
        }]
      }
      _DefectAffectedObjectTP.Batch,
      
      // Necessary for value help of Batch

      @ObjectModel.readOnly: true
      _Defect.Plant,
      
      @ObjectModel.readOnly: true
      @Semantics.booleanIndicator: true
      _DefectAffectedObjectTP.DefectAffcdObjIsDefective,

      // Associations

      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _Defect,

      _DefectAffectedObjectTP._DefectAffcdObjQuantityUnit,
      _Product,
      _QltyTskFllwUpActnSimlnRslt,
      
      _DefectAffectedObjectTP._QltyTaskFollowUpAction,
      _DefectAffectedObjectTP._QltyTaskFllwUpActionSts
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_DEFECTRECORD",
"I_DEFECTAFFECTEDOBJECTTP",
"I_PRODUCT",
"I_PRODUCTTEXT"
],
"ASSOCIATED":
[
"C_DEFECTRECORD",
"I_PRODUCT",
"I_QLTYTASKFLLWUPACTIONSTS",
"I_QLTYTASKFOLLOWUPACTION",
"I_QLTYTSKFLLWUPACTNSIMLNRSLT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_DEFECTAFFECTEDOBJECTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/