C_DefectMngCharcRslts

@AbapCatalog.sqlViewName: 'CDEFECTCHARCRSLT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #XL, //expected number of rows < 10.000.000

    serviceQuality: #C 
}
@EndUserText.label: 'Defect: Charcteristics Single Results'

define view C_DefectMngCharcRslts  as select from  I_InspSubsetCharacteristic as _InspSubsetChar

left outer join I_InspectionResultValue    as _InspectionResultValue on  _InspSubsetChar.InspectionLot               = _InspectionResultValue.InspectionLot
                                                                         and _InspSubsetChar.InspPlanOperationInternalID = _InspectionResultValue.InspPlanOperationInternalID
                                                                         and _InspSubsetChar.InspectionSubsetInternalID  = _InspectionResultValue.InspectionSubsetInternalID
                                                                         and _InspSubsetChar.InspectionCharacteristic    = _InspectionResultValue.InspectionCharacteristic
{
    @DefaultAggregation: #NONE  
  key _InspSubsetChar.InspectionLot,
  key _InspSubsetChar.InspPlanOperationInternalID,
  key _InspSubsetChar.InspectionCharacteristic,
  key _InspSubsetChar.InspectionSubsetInternalID,
  key _InspSubsetChar._InspectionCharacteristic._InspectionOperation.InspectionOperation,
  key _InspectionResultValue.InspResultValueInternalID,
      
      _InspSubsetChar._InspectionCharacteristic.InspSpecIsQuantitative,
      _InspSubsetChar._InspectionCharacteristic.InspSpecRecordingType,
      _InspSubsetChar._InspectionCharacteristic.InspSpecIsMeasuredValueRqd,
      _InspSubsetChar._InspectionCharacteristic._InspectionSpecificationUnit._Text[1:Language=$session.system_language].UnitOfMeasureTechnicalName                                 as  InspectionSpecificationUnit,
      @UI.hidden: true
      case _InspectionResultValue.InspectionValuationResult
       when 'A' then 3
       when 'R' then 1
       else 0
      end                                                                                                                                          as  UsageDecisionCodeCriticality,


      @UI.dataPoint: {
        title:'Single Results',
        criticality: 'UsageDecisionCodeCriticality'
      }
      @DefaultAggregation: #NONE
      _InspSubsetChar._InspectionCharacteristic.InspSpecDecimalPlaces,
      _InspectionResultValue.InspResultHasMeasuredValue,
      _InspectionResultValue.CharacteristicAttributeCodeGrp,

      case _InspSubsetChar._InspectionCharacteristic.InspSpecIsQuantitative //Quantitative

      when 'X' then case _InspSubsetChar._InspectionCharacteristic.InspSpecRecordingType
                    when '+' then _InspectionResultValue.InspectionValuationResult //'+' is Single

                    else ''
                    end
      else case _InspSubsetChar._InspectionCharacteristic.InspSpecRecordingType //'+' is Single

           when '+' then _InspectionResultValue.InspectionValuationResult
           else ''
           end
      end                                                                                                                                          as  InspectionValuationResult,

      case _InspSubsetChar._InspectionCharacteristic.InspSpecIsQuantitative
      when 'X' then case _InspSubsetChar._InspectionCharacteristic.InspSpecRecordingType //Quantitative

                    when '+' then _InspectionResultValue.InspectionResultMeasuredValue //'+' is Single

                    else cast(0 as abap.fltp)
                    end
      else cast(0 as abap.fltp)
      end                                                                                                                                          as  InspectionResultMeasuredValue,

      case _InspSubsetChar._InspectionCharacteristic.InspSpecIsQuantitative
      when 'X' then '' //Quantitative

      else case _InspSubsetChar._InspectionCharacteristic.InspSpecRecordingType //Qualitive

           when '+' then _InspectionResultValue._CharcAttributeCode.CharacteristicAttributeCode //Single

           else '' //Summary

           end
      end                                                                                                                                          as  CharacteristicAttributeCode,

      case _InspSubsetChar._InspectionCharacteristic.InspSpecIsQuantitative
      when 'X' then '' //Quantitative

      else case _InspSubsetChar._InspectionCharacteristic.InspSpecRecordingType //Qualitive

           when '+' then _InspectionResultValue._CharcAttributeCode.CharacteristicAttributeCodeTxt //Single

           else '' //Summary

           end
      end                                                                                                                                          as  CharacteristicAttributeCodeTxt,

      //Date & Time fields exposed for micro chart sort order

      case
      when (LastChangeDate is not null and LastChangeDate <> '00000000')
        then dats_tims_to_tstmp(LastChangeDate, ChangedTime, abap_system_timezone( $session.client,'NULL' ),  $session.client, 'NULL')
      else dats_tims_to_tstmp(CreationDate, CreationTime, abap_system_timezone( $session.client,'NULL' ),  $session.client, 'NULL')
      end                                                                                                                                          as  ChangedDateTime,



      //associations for DCL

      @Consumption.hidden: true
      _InspSubsetChar._InspectionLot,
      @Consumption.hidden: true
      _InspSubsetChar._InspectionOperation
   
}                                               
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHARCATTRIBUTECODE",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTVALUE",
"I_INSPSUBSETCHARACTERISTIC",
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT"
],
"ASSOCIATED":
[
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION"
],
"BASE":
[
"I_INSPSUBSETCHARACTERISTIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/