C_Defect

@AbapCatalog.sqlViewName: 'CDEFECT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Defect Consumption View'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: 
{
        dataClass: #TRANSACTIONAL,
        sizeCategory: #S, 
        serviceQuality: #B }
        
define view C_Defect as select from I_QualityDefectUnion 
{
       @UI.hidden: true
       @ObjectModel.readOnly:true
       key I_QualityDefectUnion.Notification as DefectInternalID,
   
       @ObjectModel.readOnly:true
       key I_QualityDefectUnion.NotificationItem,
       
       @ObjectModel.readOnly: true
        cast( substring(I_QualityDefectUnion.Notification,2,11) as qdefectid preserving type ) as Defect,
       
      //--[ GENERATED:011:GlBfhyFV7jY4gqQmcmHUzm

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_DefectCodeGroupStdVH',
                     element: 'DefectCodeGroup' }
        }]
      // ]--GENERATED

       @ObjectModel: { readOnly: true, foreignKey.association: '_DefectCodeGroup' }
       I_QualityDefectUnion.DefectCodeGroup, 
       
      //--[ GENERATED:011:GlBfhyFV7jY4gqQmcmHUzm

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_DefectCodeStdVH',
                     element: 'DefectCode' },
          additionalBinding: [{ localElement: 'DefectCodeGroup',
                                element: 'DefectCodeGroup' }]
        }]
      // ]--GENERATED

       @ObjectModel: { readOnly: true, foreignKey.association: '_DefectCode' }
       I_QualityDefectUnion.DefectCode, 
      
       @ObjectModel.readOnly: true 
       I_QualityDefectUnion.NumberOfDefects,
        
       @ObjectModel.readOnly: true 
       I_QualityDefectUnion.InspPlanOperationInternalID, 
        
       @ObjectModel.readOnly: true 
       I_QualityDefectUnion.InspectionCharacteristic, 
       
       @ObjectModel.readOnly: true
       I_QualityDefectUnion.InspectionLot, 
       
       @UI.hidden: true
       @ObjectModel.readOnly: true       
       I_QualityDefectUnion.Plant,
       
       //Getting count for defects

        @UI.hidden: true 
         cast (1 as abap.int8) as  InspectionLotSum,

       // Fields for authorization checks

       @Consumption.hidden: true
       I_QualityDefectUnion.DefectCategory,
       @Consumption.hidden: true
       I_QualityDefectUnion.WorkCenterTypeCode,
       @Consumption.hidden: true
       I_QualityDefectUnion.MainWorkCenterInternalID,
       @Consumption.hidden: true
       I_QualityDefectUnion.MainWorkCenter,
       @Consumption.hidden: true
       I_QualityDefectUnion.MainWorkCenterPlant,
       
       /* Associations */
       I_QualityDefectUnion._InspectionLot,
       _DefectCode,      
       _DefectCodeGroup
      
    
} where IsDeleted <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_QUALITYDEFECTUNION"
],
"ASSOCIATED":
[
"I_DEFECTCODE",
"I_DEFECTCODEGROUP",
"I_INSPECTIONLOT"
],
"BASE":
[
"I_QUALITYDEFECTUNION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/