@AbapCatalog.sqlViewName: 'CCUSTRETDELFS'
@ClientHandling.algorithm:#SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#CHECK
@AccessControl.privilegedAssociations: [ '_Partner', '_ShipToParty', '_SoldToParty' ]
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Returns Delivery Object Page'
@Search.searchable: true
@ObjectModel: {
compositionRoot: true,
semanticKey: ['ReturnsDelivery'],
representativeKey: 'ReturnsDelivery',
usageType.dataClass: #MIXED,
usageType.serviceQuality: #D,
usageType.sizeCategory: #XL
}
@UI.headerInfo: {
typeName: 'Returns Delivery',
typeNamePlural: 'Returns Delivery',
title: {
type: #STANDARD,
value: 'ReturnsDelivery'
},
description.value: 'DeliveryDocumentTypeName'
}
@Consumption.semanticObject: 'ReturnsDelivery'
define view C_CustomerReturnDeliveryFS as select from I_CustomerReturnDelivery as _CustomerReturnDelivery
association [0..*] to C_SDDocumentPartnerCard as _Partner on $projection.ReturnsDelivery = _Partner.SDDocument and _Partner.SDDocumentItem = '000000'
association [0..*] to C_CustomerReturnDeliveryItemFS as _CustomerReturnDeliveryItemFs on $projection.ReturnsDelivery = _CustomerReturnDeliveryItemFs.CustomerReturnDelivery
//Extensibility
association [1] to E_DeliveryDocument as _Extension on $projection.ReturnsDelivery = _Extension.DeliveryDocument
association[0..1] to C_SDDocumentPartnerCard as _ShipToParty on _CustomerReturnDelivery.CustomerReturnDelivery = _ShipToParty.SDDocument
and _ShipToParty.PartnerFunction = 'WE'
and _ShipToParty.SDDocumentItem is initial
association[0..1] to C_SDDocumentPartnerCard as _SoldToParty on _CustomerReturnDelivery.CustomerReturnDelivery = _SoldToParty.SDDocument
and _SoldToParty.PartnerFunction = 'AG'
and _SoldToParty.SDDocumentItem is initial
{
// ********** FILTER FACET DEFINITION **********
@UI.facet:[
{
id:'GenericFilter',
purpose: #FILTER,
type: #FIELDGROUP_REFERENCE,
targetQualifier: 'GenericFilter'
}
]
//Header
//**********************************************************************************************
@Search.defaultSearchElement: true
@Search.ranking: #HIGH
@UI.lineItem:[{position:1}]
@UI.fieldGroup: { qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }
@Consumption.semanticObject: 'ReturnsDelivery'
key CustomerReturnDelivery as ReturnsDelivery,
@UI.hidden: true
cast( _CustomerReturnDelivery._DeliveryDocumentType._Text[1: Language=$session.system_language].DeliveryDocumentTypeName as bezei20) as DeliveryDocumentTypeName,
@Consumption.semanticObject: 'Customer'
@UI.fieldGroup: [{ qualifier: 'HeaderColumn1', position: 10, importance: #HIGH, label: 'Ship-to Party/Returning Party'},
{ qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@Consumption.valueHelpDefinition: [ { entity: { name: 'D_CustomerCVH', element: 'Customer' } } ]
@UI.textArrangement: #TEXT_FIRST
@ObjectModel.text.element: ['ShipToPartyFullName']
ShipToParty,
@EndUserText.label: 'Full Name Ship-to Party'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LE_PARTNER_FULLNAME_F0234A'
cast('' as ad_namtext ) as ShipToPartyFullName,
@Consumption.semanticObject: 'Customer'
@UI:{ dataPoint:{ description: 'Sold-To Party' } }
@UI.fieldGroup: [{ qualifier: 'HeaderColumn1', position: 20, importance: #HIGH},
{ qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@Consumption.valueHelpDefinition: [ { entity: { name: 'D_CustomerCVH', element: 'Customer' } } ]
@UI.textArrangement: #TEXT_FIRST
@ObjectModel.text.element: ['SoldToPartyFullName']
SoldToParty,
@EndUserText.label: 'Full Name Sold-to Party'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_LE_PARTNER_FULLNAME_F0234A'
cast('' as ad_namtext ) as SoldToPartyFullName,
@UI.fieldGroup: [{ qualifier: 'HeaderColumn2', position: 10, importance: #MEDIUM, label: 'Receiving Point'},
{ qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShippingPointStdVH', element: 'ShippingPoint' } } ]
@UI.textArrangement: #TEXT_FIRST
ShippingPoint,
@UI.fieldGroup: [{ qualifier: 'HeaderColumn2', position: 10, importance: #MEDIUM, criticality: 'OvrlSDProcessStatusCriticality'},
{ qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
OverallSDProcessStatus,
@UI.hidden
cast(
case OverallSDProcessStatus
when '' then 0
when 'A' then 2
when 'B' then 2
when 'C' then 3
else 0
end as abap.int1
)as OvrlSDProcessStatusCriticality,
@UI:{ dataPoint:{ description: 'Delivery Date' } }
@UI.fieldGroup: { qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }
DeliveryDate,
//General Information
//**********************************************************************************************
@UI.fieldGroup: [{ qualifier: 'GeneralInfoBlock1', position: 10, importance: #HIGH},
{ qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
SalesOrganization,
@UI.fieldGroup: {qualifier: 'GeneralInfoBlock1', position: 20, importance: #HIGH}
@Semantics.quantity: { unitOfMeasure: 'HeaderWeightUnit'}
@Consumption.filter.hidden: true
cast(HeaderGrossWeight as le_brgew) as HeaderGrossWeight,
@UI.fieldGroup: {qualifier: 'GeneralInfoBlock1', position: 30, importance: #HIGH}
@Semantics.quantity: { unitOfMeasure: 'HeaderWeightUnit'}
@Consumption.filter.hidden: true
HeaderNetWeight,
@Semantics.unitOfMeasure: true
@Consumption.filter.hidden: true
HeaderWeightUnit,
@UI.fieldGroup: {qualifier: 'GeneralInfoBlock1', position: 40, importance: #HIGH}
@Semantics.quantity: { unitOfMeasure: 'HeaderVolumeUnit'}
@Consumption.filter.hidden: true
HeaderVolume,
@Semantics.unitOfMeasure: true
@Consumption.filter.hidden: true
HeaderVolumeUnit,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock2', position: 10, importance: #HIGH},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
DocumentDate,
@ObjectModel.text.element: ['DeliveryDocumentTypeName']
@UI.fieldGroup: {qualifier: 'GeneralInfoBlock2', position: 20, importance: #HIGH}
_CustomerReturnDelivery._DeliveryDocumentType.DeliveryDocumentType as DeliveryDocumentType,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock2', position: 30, importance: #HIGH, label: 'Planned Goods Movement Date'},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@EndUserText.label: 'Planned Goods Movement Date'
cast (PlannedGoodsIssueDate as wadak_plan) as PlannedGoodsIssueDate,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock2', position: 40, importance: #HIGH, label: 'Actual Goods Movement Date'},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@EndUserText.label: 'Actual Goods Movement Date'
ActualGoodsMovementDate,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock3', position: 10, importance: #HIGH, label: 'Putaway Status' },
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@EndUserText.label: 'Putaway Status'
OverallPutawayStatus,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock3', position: 20, importance: #HIGH, label: 'Putaway Confirmation Status'},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@EndUserText.label: 'Putaway Confirmation Status'
OverallPickingConfStatus,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock3', position: 30, importance: #HIGH, label: 'Warehouse Management Status'},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@EndUserText.label: 'Warehouse Management Status'
OverallWarehouseActivityStatus,
@UI.fieldGroup: [{qualifier: 'GeneralInfoBlock3', position: 40, importance: #HIGH, label: 'Goods Movement Status', criticality: 'OvrlGdsMovementStsCriticality'},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' }]
@EndUserText.label: 'Goods Movement Status'
OverallGoodsMovementStatus,
@UI.hidden
cast(
case OverallGoodsMovementStatus
when '' then 0
when 'A' then 2
when 'B' then 2
when 'C' then 3
else 0
end as abap.int1
)as OvrlGdsMovementStsCriticality,
@ObjectModel.foreignKey.association: '_DelivAdvncdShipgRcvgRlvnce'
@UI.fieldGroup: [ {qualifier: 'GeneralInfoBlock3', position: 100, importance: #HIGH},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' } ]
@EndUserText.label: 'Advanced Shipping and Receiving Relevance'
DelivAdvncdShipgRcvgRlvnce,
@ObjectModel.foreignKey.association: '_WarehouseExecutionStatus'
@UI.fieldGroup: [ {qualifier: 'GeneralInfoBlock3', position: 110, importance: #HIGH},
{qualifier: 'GenericFilter', groupLabel: 'Returns Delivery' } ]
@EndUserText.label: 'Warehouse Execution Status'
ReadyForWarehouseExecStatus,
@Consumption.filter.hidden: true
_Partner,
@Consumption.filter.hidden: true
_ShipToParty,
@Consumption.filter.hidden: true
_SoldToParty,
@Consumption.filter.hidden: true
_ShippingPoint,
@Consumption.filter.hidden: true
_SalesOrganization,
@Consumption.filter.hidden: true
_OverallPutawayStatus,
@Consumption.filter.hidden: true
_OvrlWarehouseActyStatus,
@Consumption.filter.hidden: true
_OverallPickingConfStatus,
@Consumption.filter.hidden: true
_OverallGoodsMovementStatus,
@Consumption.filter.hidden: true
_OverallSDProcessStatus,
@Consumption.filter.hidden: true
_CustomerReturnDeliveryItemFs,
_WarehouseExecutionStatus,
@Consumption.filter.hidden: true
_DelivAdvncdShipgRcvgRlvnce
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURNDELIVERY",
"I_DELIVERYDOCUMENTTYPE",
"I_DELIVERYDOCUMENTTYPETEXT"
],
"ASSOCIATED":
[
"C_CUSTOMERRETURNDELIVERYITEMFS",
"C_SDDOCUMENTPARTNERCARD",
"E_DELIVERYDOCUMENT",
"I_ADVSHIPRECEIVERLVNCE",
"I_OVERALLGOODSMOVEMENTSTATUS",
"I_OVERALLPICKINGCONFSTATUS",
"I_OVERALLSDPROCESSSTATUS",
"I_OVRLWAREHOUSEACTYSTATUS",
"I_PUTAWAYSTATUS",
"I_SALESORGANIZATION",
"I_SHIPPINGPOINT",
"I_WAREHOUSEEXECUTIONSTATUS"
],
"BASE":
[
"I_CUSTOMERRETURNDELIVERY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/