C_CustomerProjectVH

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CCUSTPROJVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'CustomerProject'
@EndUserText.label: 'Customer Project Value Help'
@Search.searchable: true
@Consumption.ranked: true
@Consumption.valueHelpDefault.fetchValues: #AUTOMATICALLY_WHEN_DISPLAYED
@VDM.viewType: #CONSUMPTION
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view C_CustomerProjectVH
  as select from I_CustomerProject
  association [1..1] to I_EngagementProject    as _EngagementProject   on $projection.CustomerProject = _EngagementProject.EngagementProject
  association [1..*] to I_PersnWrkAgreementDet as _PersonWorkAgreement on $projection.EmploymentInternalID = _PersonWorkAgreement.PersonWorkAgreement

{

      @ObjectModel.text.element: 'CustomerProjectName'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key I_CustomerProject.CustomerProject                                                                      as CustomerProject,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      I_CustomerProject.CustomerProjectName                                                                  as CustomerProjectName,
      @UI.hidden: true
      I_CustomerProject.CustProjMgrPersonnelNumber                                                           as EmploymentInternalID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      cast(_PersonWorkAgreement._WorkforcePerson.PersonFullName as /cpd/proj_manager_name  preserving type ) as CustomerProjectManagerName,
      @Consumption.hidden: true  
      I_CustomerProject.CustomerProjectServiceOrg,
      @Consumption.hidden: true
      I_CustomerProject.CustomerProjectVisibility,
      @Consumption.hidden: true
      I_CustomerProject.ProjectProfileCode,
      @Consumption.hidden: true
      I_CustomerProject.EngmntProjectHeaderCompanyCode,
      @Consumption.hidden: true
      I_CustomerProject.CostCenter as EngagementProjectCostCenter,
      @Consumption.hidden: true
      I_CustomerProject.ProfitCenter,
      @Consumption.hidden:true      
      I_CustomerProject._UserInvlmnt.IsMyProject,     
      //Exposing Association For DCL

      _EngagementProject,
      _PersonWorkAgreement     

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERPROJECT",
"I_ENGMNTPROJWITHUSERINVLMNT",
"I_PERSNWRKAGREEMENTDET",
"I_WORKFORCEPERSONDET"
],
"ASSOCIATED":
[
"I_ENGAGEMENTPROJECT",
"I_PERSNWRKAGREEMENTDET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/