C_CustomerDepartment

@AbapCatalog.sqlViewName: 'CBPDEPARTMENT'
@AbapCatalog.compiler.compareFilter: true

@AbapCatalog.preserveKey:true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Consumption view for Customer Department'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner', 'Customer', 'CustomerDepartmentForEdit'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Department',
  typeNamePlural: 'Departments',
  title:  { label: 'Department', value: 'CustomerDepartment'}
}

@VDM.viewType: #CONSUMPTION

define view C_CustomerDepartment 
    as select from  I_CustomerDepartmentTP                      as BPCustomerDepartment    
    
   association [1..1] to C_BusinessPartnerCustomer              as _BusinessPartnerCustomer                  on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner

   association [1..1] to C_BusinessPartner                      as _BusinessPartner                          on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
   
   association [0..*] to I_ContactPersonStdDepartmentT          as _ContactPersonStdDepartmentT              on  $projection.CustomerDepartmentForEdit = _ContactPersonStdDepartmentT.ContactPersonStdDepartment
   
   association [0..*] to I_UnitOfMeasureText                    as _UnitOfMeasureText                        on  $projection.RetailLocationSellingAreaUnit = _UnitOfMeasureText.UnitOfMeasure

  association [0..*] to I_RetailLayoutText            as _RetailLayoutText            on $projection.DepartmentLayout = _RetailLayoutText.RetailLayout

  association [0..*] to I_RetailAreaSchemaText        as _RetailAreaSchemaText        on $projection.DepartmentLayoutAreaSchema = _RetailAreaSchemaText.RetailLayoutAreaSchema
{

    key BPCustomerDepartment.Customer,
    key BPCustomerDepartment.CustomerDepartment,
    key BPCustomerDepartment.BusinessPartner,
    
    BPCustomerDepartment.CustomerForEdit,
    
    @ObjectModel.text.association: '_ContactPersonStdDepartmentT'
    BPCustomerDepartment.CustomerDepartmentForEdit,
    BPCustomerDepartment.BusinessPartnerForEdit,
    BPCustomerDepartment.BusinessPartnerUUID,
    
    BPCustomerDepartment.ReceivingPoint,
    
    BPCustomerDepartment.RetailLocationSellingAreaSize,
    @ObjectModel.text.association: '_UnitOfMeasureText'
    BPCustomerDepartment.RetailLocationSellingAreaUnit,
    @ObjectModel.text.association: '_RetailLayoutText'
    BPCustomerDepartment.DepartmentLayout,
    @ObjectModel.text.association: '_RetailAreaSchemaText'
    BPCustomerDepartment.DepartmentLayoutAreaSchema,
     
     @Consumption.hidden: true
     _Customer,
     
     @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
     _BusinessPartnerCustomer,
     @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
     _BusinessPartner,
     
     _ContactPersonStdDepartmentT,
     _UnitOfMeasureText,
      _RetailLayoutText,
      _RetailAreaSchemaText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERDEPARTMENTTP"
],
"ASSOCIATED":
[
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTOMER",
"I_CONTACTPERSONSTDDEPARTMENTT",
"I_CUSTOMER",
"I_RETAILAREASCHEMATEXT",
"I_RETAILLAYOUTTEXT",
"I_UNITOFMEASURETEXT"
],
"BASE":
[
"I_CUSTOMERDEPARTMENTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/