C_CtrlgObjectSettlementRule

@AbapCatalog.sqlViewName: 'CCTLOBJSTLMTRULE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Controlling Object Settlement Rule'

define view C_CtrlgObjectSettlementRule
  as select distinct from I_CtrlgObjSettlmtDistrRule
{
      @UI.hidden: true
  key ControllingObject,
      @UI.hidden: true
  key Ledger,
      @UI.lineItem: { position: 60 }
      @Semantics.fiscal.period: true
  key SettlmtDistrRuleSequence,
      @UI.hidden: true
  key SettlementDistributionRuleGrp,
  
  key LedgerGroup,
      @UI.hidden: true
      AccountAssignmentType,
      @UI.hidden: true
      SettlementTransaction,
      @UI.hidden: true
      SettlementDefaultRule,
      @UI.hidden: true
      SettlementReceiver,
      @UI.lineItem: { position: 10 }
      @ObjectModel.text.element: 'SettlementReceiverText'
      @UI.textArrangement: #TEXT_LAST
      @ObjectModel: {
          readOnly: true,
          virtualElement,
          virtualElementCalculatedBy: 'ABAP:CL_FCO_SETTL_REC_INFO_CDS_EXIT'
       }
      cast( '' as fco_stlmnt_receiver_id_out ) as SettlementReceiverObject,

      @ObjectModel: {
                readOnly: true,
                virtualElement,
                virtualElementCalculatedBy: 'ABAP:CL_FCO_SETTL_REC_INFO_CDS_EXIT'
             }
      @UI.lineItem: { position: 15 }       
      cast( '' as fco_stlmnt_receiver_txt )   as SettlementReceiverText,

      @UI.lineItem: { position: 20 }
      @Semantics.text: true
      cast( _AccountAssignmentTypeT.AccountAssignmentTypeName as fco_settlmt_rec_type_text ) as SettlementReceiverTypeText,
      @UI.lineItem: { position: 30 }
      SettlementPercentageRate,
      @UI.lineItem: { position: 40 }
      SettlementAmount,
      @UI.hidden: true
      SettlementAmountCurrency,
      @UI.lineItem: { position: 50 }
      @ObjectModel.text.element: 'SettlementTypeDesc'
      @UI.textArrangement: #TEXT_ONLY
      SettlementType,
      @UI.hidden: true
      @Semantics.text: true
      cast( _SettlementTypeText.SettlementTypeDesc as ddtext )                               as SettlementTypeDesc,
      @UI.lineItem: { position: 70, importance: #HIGH }
      @Semantics.fiscal.yearPeriod: true
      cast( case ValidityStartFiscalYear when '0000' then ''
                                                     else concat( ValidityStartFiscalYear, ValidityStartFiscalPeriod )
                                                     end as fco_stlmt_start_fyearperiod )    as ValidityStartFiscalYearPeriod,
      @UI.lineItem: { position: 80, importance: #HIGH }
      @Semantics.fiscal.yearPeriod: true
      cast( case ValidityEndFiscalYear   when '0000' then ''
                                                     else concat( ValidityEndFiscalYear, ValidityEndFiscalPeriod )
                                                     end as fco_stlmt_end_fyearperiod )      as ValidityEndFiscalYearPeriod,
      @UI.hidden: true
      ValidityStartFiscalPeriod,
      @UI.hidden: true
      ValidityStartFiscalYear,
      @UI.hidden: true
      ValidityEndFiscalPeriod,
      @UI.hidden: true
      ValidityEndFiscalYear,

      @UI.hidden: true
      ControllingArea,
      @UI.hidden: true
      ProfitCenter,
      @UI.hidden: true
      GLAccount,
      @UI.hidden: true
      MasterFixedAsset,
      @UI.hidden: true
      FixedAsset,
      @UI.hidden: true
      CostCenter,
      @UI.hidden: true
      Material,
      @UI.hidden: true
      BusinessProcess,
      @UI.hidden: true
      ProjectNetwork,
      @UI.hidden: true
      SalesOrder,
      @UI.hidden: true
      SalesOrderItem,
      @UI.hidden: true
      CompanyCode,
      @UI.hidden: true
      WBSElementExternalID,
      @UI.hidden: true
      WBSElementInternalID,
      @UI.hidden: true
      OrderID,
      @UI.hidden: true
      ProfitabilitySegment,
      @UI.hidden: true
      CostObject,
      @UI.hidden: true
      OrderItem
}
where
     Ledger = '00'
  or Ledger = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTASSIGNMENTTYPET",
"I_CTRLGOBJSETTLMTDISTRRULE",
"I_SETTLEMENTTYPETEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/