C_CorrespondenceSupplierVH

@AbapCatalog.sqlViewName: 'CCRCRRSPNCSUPPVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.semanticKey:  [ 'CompanyCode' ]
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@AbapCatalog.preserveKey:true
@Consumption.ranked: true
@EndUserText.label: 'Correspondence Supplier Value Help'
// -- This CDS view is a replacement for the search help KREDK

define view C_CorrespondenceSupplierVH as select from I_Supplier {
  @Search: {
    defaultSearchElement: true,
    ranking: #HIGH,
    fuzzinessThreshold: 0.8
  }
  @ObjectModel.text.element: [ 'SupplierName' ]
  @UI.selectionField.position: 2
  key Supplier,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @Consumption.valueHelpDefinition: [{
    entity: {
      name: 'C_CORRESPONDENCECOMPANYCODEVH',
      element: 'CompanyCode'
    },
    label: 'Company Code'
  }]
  @UI.selectionField.position: 3
  key _SupplierCompany.CompanyCode,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @EndUserText.label: 'Search Term'
  @UI.selectionField.position: 1
  _SupplierToBusinessPartner._BusinessPartner.SearchTerm1,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @UI.selectionField.position: 4
  // -- This is NAME1 from LFA1 and maps to MCOD1 which is automatically

  // -- generated from NAME1 - it holds first 25 characters in upper case

  OrganizationBPName1 as SupplierName,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @UI.selectionField.position: 5
  CityName,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @UI.selectionField.position: 6
  PostalCode,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @UI.selectionField.position: 7
  Country,
  @Search: {
    defaultSearchElement: true,
    ranking: #LOW,
    fuzzinessThreshold: 0.75
  }
  @UI.selectionField.position: 8
  Industry,
  // -- This column is necessary for the auto assigned mapping role.

  @UI.hidden: true
  SupplierAccountGroup,
  // -- This column is required only for the DCL.

  @UI.hidden: true
  AuthorizationGroup,
  // -- This column is required only for the DCL.

  @UI.hidden: true
  _SupplierCompany.AuthorizationGroup as CoCodeSpcfcAuthorizationGroup
  }
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_SUPPLIER",
"I_SUPPLIERCOMPANY",
"I_SUPPLIERTOBUSINESSPARTNER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/