@AbapCatalog.sqlViewName: 'CCTRHISTORYFS'
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Purchase Order'
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.authorizationCheck: #CHECK
@UI.headerInfo: {
//typeName: 'Purchase Contract Item', typeName_AsOtr: '005056B2532A1EE588FAC1D4762799B6',
// typeNamePlural: 'Purchase Contract Item', typeNamePlural_asOtr: '005056B2532A1EE588FAC1D4762799B6',
//typeImageUrl: '/sap/bc/ui5_ui5/sap/mm_contritems1/images/contract.jpg',
title.value: 'ReleaseOrder' }
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@Metadata: {
ignorePropagatedAnnotations: true
}
define view C_ContractHistoryFs as select from I_PurchaseContractHistory
association [1..1] to I_PurchaseOrderEnhanced as _PurchaseOrder on
$projection.ReleaseOrder = _PurchaseOrder.PurchaseOrder
association [1..1] to I_PurchaseContractItem as _PurchaseContract on
$projection.PurchaseContract = _PurchaseContract.PurchaseContract
and $projection.PurchaseContractItem = _PurchaseContract.PurchaseContractItem
{
@Consumption.semanticObject: 'PurchaseContract'
key PurchaseContract,
key PurchaseContractItem,
@Consumption.semanticObject: 'PurchaseOrder'
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 10,
importance: #HIGH }]
key ReleaseOrder, // the same as PurchaseOrder ID
key ReleaseOrderItem,
@Semantics.quantity.unitOfMeasure: 'ReleaseOrderItemQuantityUnit'
@DefaultAggregation: #NONE
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 60,
importance: #HIGH }]
ReleaseOrderItemOrderQuantity,
@Semantics.amount.currencyCode: 'ReleaseOrderCurrency'
@DefaultAggregation: #NONE
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 70,
importance: #HIGH }]
ReleaseOrderItemNetAmount,
@Semantics.booleanIndicator: true
ReleaseOrderItemIsDeleted,
@Semantics.businessDate.at: true
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 40,
importance: #HIGH }]
cast ( ReleaseOrderDate as ordered_on ) as ReleaseOrderDate,
@Semantics.unitOfMeasure: true
ReleaseOrderItemQuantityUnit,
@Semantics.currencyCode:true
ReleaseOrderCurrency,
@Semantics.businessDate.lastChangedAt: true
ReleaseOrderItemLastChgDate,
@ObjectModel.text.association: '_Text'
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 20,
label: 'Document Type', label_asOtr: 'FA163EDF73161ED58BF490CA8268EFC3',
importance: #HIGH }]
_PurchaseOrder.PurchaseOrderType,
cast ('F' as bstyp) as PurchasingDocumentCategory,
_PurchaseOrder._PurchaseOrderType.PurchaseOrderType as PurchasingDocumentType,
//Supplier
//--[ GENERATED:012:GlBfhyFV7kY4uDHrD8rHim
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_MM_SupplierValueHelp',
element: 'Supplier' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_Supplier'
@ObjectModel.text.element: [ 'SupplierName' ]
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 30,
importance: #HIGH }]
@Consumption.semanticObject: 'Supplier'
_PurchaseOrder.Supplier,
@Semantics.text: true
_PurchaseOrder._Supplier.SupplierName,
_PurchaseOrder.SupplierAddressID,
//--[ GENERATED:012:GlBfhyFV7kY4uDHrD8rHim
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_MM_SupplierValueHelp',
element: 'Supplier' }
}]
// ]--GENERATED
@ObjectModel.text.element: [ 'SupplierName' ]
@ObjectModel.foreignKey.association: '_SupplyingSupplier'
@Consumption.semanticObject: 'Supplier'
_PurchaseOrder.SupplyingSupplier,
@ObjectModel.foreignKey.association: '_SupplyingPlant'
_PurchaseOrder.SupplyingPlant,
//--[ GENERATED:012:GlBfhyFV7kY4uDHrD8rHim
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_MM_SupplierValueHelp',
element: 'Supplier' }
}]
// ]--GENERATED
@ObjectModel.foreignKey.association: '_InvoicingParty'
@ObjectModel.text.element: [ 'SupplierName' ]
@Consumption.semanticObject: 'Supplier'
_PurchaseOrder.InvoicingParty,
@ObjectModel.text.association: '_StatusText'
@UI.lineItem: [{
qualifier: 'ReleaseOrder',
position: 50,
label: 'Status', label_asOtr: '005056B2532A1EE585B97A4F343C0274',
importance: #HIGH }]
_PurchaseOrder._Status.PurchasingDocumentStatus,
//association
_PurchaseOrder._PurchaseOrderType._Text,
_PurchaseOrder._Status._Text as _StatusText,
@Consumption: {
hidden: true
}
_PurchaseOrder._SupplyingSupplier,
_PurchaseOrder._SupplyingPlant,
@Consumption: {
hidden: true
}
_PurchaseOrder._InvoicingParty,
@Consumption: {
hidden: true
}
_PurchaseOrder._Supplier,
---Added for DCL
@ObjectModel.text.element: [ 'PlantName' ]
@Consumption.semanticObject: 'Plant'
Plant,
@Semantics.text: true
_PurchaseContract._Plant.PlantName,
_PurchaseContract
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"I_PURCHASECONTRACTHISTORY",
"I_PURCHASECONTRACTITEM",
"I_PURCHASEORDERENHANCED",
"I_PURCHASEORDERTYPE",
"I_PURCHASINGDOCUMENTSTATUS",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_PLANT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASEORDERENHANCED",
"I_PURCHASINGDOCUMENTSTATUSTEXT",
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_SUPPLIER"
],
"BASE":
[
"I_PURCHASEORDERENHANCED",
"I_PURCHASEORDERTYPE",
"I_PURCHASINGDOCUMENTSTATUS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/