@EndUserText.label: 'Manage External Sales Commissions'
@AccessControl: {
authorizationCheck: #MANDATORY,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Metadata: {
allowExtensions: true,
ignorePropagatedAnnotations: true
}
@Search: {
searchable: true
}
@ObjectModel: {
usageType.serviceQuality: #C,
usageType.dataClass: #MIXED,
usageType.sizeCategory: #XXL,
semanticKey: ['ConditionContract'],
representativeKey: 'ConditionContract'
}
@VDM: {
viewType: #CONSUMPTION,
lifecycle.contract.type: #NONE,
usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
//@Consumption: {
// semanticObject: 'ExtSalesCommissionAgreement'
//}
define root view entity C_ConditionContract_F5989
provider contract transactional_query
as projection on R_ConditionContractTP
{
@Consumption.valueHelpDefinition: [{
entity: { name : 'I_CndnContrExtSlsCommsnStdVH', element : 'ConditionContract' }
}]
@Consumption: {
semanticObject: 'ExtSalesCommissionAgreement',
semanticObjectMapping: { element: 'ConditionContract' }
}
@Search: {
defaultSearchElement: true,
ranking: #HIGH,
fuzzinessThreshold: 0.9
}
key ConditionContract,
@ObjectModel: {
text.element: ['CndnContrTypeDesc']
}
@Consumption.valueHelpDefinition: [{
entity: { name: 'R_CndnContrTypeExtSlsCommsnVH', element: 'CndnContrType' }
}]
CndnContrType,
@Semantics.text: true
@UI.lineItem: [{ hidden: true }]
_CndnContrType._Text.CndnContrTypeDesc as CndnContrTypeDesc : localized,
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcVarStdVH', element: 'CndnContrProcVar' } }]
}
@ObjectModel: { text.element: ['CndnContrProcVarDesc'] }
CndnContrProcVar,
@Semantics.text: true
@Consumption.filter.hidden: true
_CndnContrProcVar._Text.CndnContrProcVarDesc as CndnContrProcVarDesc : localized,
@ObjectModel.text.element: ['SupplierName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }],
semanticObject: 'Supplier'
}
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.9
}
Supplier,
@Semantics.text: true
@Consumption.filter.hidden: true
_Supplier.SupplierName as SupplierName,
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
@Consumption.hidden: true
_Supplier.OrganizationBPName1 as SupplierName_H,
@Consumption.hidden: true
Customer,
@ObjectModel.text.element: ['CndnContrActvtnStatusName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CndnContrActvtnStatus', element: 'CndnContrActvtnStatus' } }]
}
CndnContrActvtnStatus,
@Semantics.text: true
@UI.hidden: true
_CndnContrActvtnStatus._Text.CndnContrActvtnStatusName as CndnContrActvtnStatusName : localized,
@Consumption.filter : {selectionType:#INTERVAL,multipleSelections: false}
CndnContrValidFrom,
@Consumption.filter : {selectionType:#INTERVAL,multipleSelections: false}
CndnContrValidTo,
@ObjectModel.text.element: ['CndnContrClassfctnTypeDesc']
CndnContrClassfctnType,
@Semantics.text: true
@UI.hidden: true
_CndnContrClassfctnType._Text.CndnContrClassfctnTypeDesc as CndnContrClassfctnTypeDesc : localized,
DocumentReferenceID,
CndnContrAssgmtRef,
ExternalDocumentReferenceID,
CndnContrExternalPartner,
@Consumption.valueHelpDefinition: [{
entity: { name : 'I_CndnContrSourceDocCat', element : 'CndnContrSourceDocCat' }
}]
@ObjectModel.text.element: ['CndnContrSourceDocCatName']
CndnContrSourceDocCat,
@Semantics.text: true
@UI.hidden: true
_CndnContrSourceDocCat._Text.CndnContrSourceDocCatName as CndnContrSourceDocCatName : localized,
CndnContrSourceDoc,
CndnContrSourceDocItem,
@UI.hidden: true
CndnContrSourceUUID,
@Semantics.user.createdBy: true
@ObjectModel.text.element: ['CreatedByUserFullName']
@Consumption.semanticObject: 'Employee'
@Consumption.valueHelpDefinition: [{
entity: { name : 'R_ConditionDocumentUserVH', element : 'UserID' }
}]
CreatedByUser,
@Semantics.text: true
@UI.hidden: true
cast( _CreatedByUser.UserDescription as wlf_created_by_fullname preserving type ) as CreatedByUserFullName,
@Semantics.systemTime.createdAt: true
@Consumption.filter : {selectionType:#INTERVAL}
cast( CreationUTCDateTime as wcb_created_on_tstmp preserving type ) as CndnContrCreationDateTime,
@Semantics.user.lastChangedBy: true
@ObjectModel.text.element: ['LastChangedByUserFullName']
@Consumption.semanticObject: 'Employee'
@Consumption.valueHelpDefinition: [{
entity: { name : 'R_ConditionDocumentUserVH', element : 'UserID' }
}]
LastChangedByUser,
@Semantics.text: true
@UI.hidden: true
_LastChangedByUser.UserDescription as LastChangedByUserFullName,
@Semantics.systemTime.lastChangedAt: true
@Consumption.filter : {selectionType:#INTERVAL}
cast( LastChangeUTCDateTime as wcb_changed_on_tstmp preserving type ) as CndnContrLastChangedDateTime,
@ObjectModel.text.element: ['CompanyCodeName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
}
CompanyCode,
@Semantics.text: true
@Consumption.filter.hidden: true
_CompanyCode.CompanyCodeName as CompanyCodeName,
@ObjectModel.text.element: ['PurchasingOrganizationName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_PurchasingOrgValueHelp', element: 'PurchasingOrganization' } }]
}
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
cast( PurchasingOrganization as wlf_ekorg preserving type ) as PurchasingOrganization,
@Semantics.text: true
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
@Consumption.filter.hidden: true
_PurchasingOrganization.PurchasingOrganizationName as PurchasingOrganizationName,
@ObjectModel.text.element: ['PurchasingGroupName']
PurchasingGroup,
@Consumption.filter.hidden: true
@Semantics.text: true
_PurchasingGroup.PurchasingGroupName as PurchasingGroupName,
@ObjectModel.text.element: ['SalesOrganizationName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_SalesOrganizationVH', element: 'SalesOrganization' } }]
}
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
SalesOrganization,
@Semantics.text: true
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
@Consumption.filter.hidden: true
_SalesOrganization._Text.SalesOrganizationName as SalesOrganizationName : localized,
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_Dischannelvaluehelp', element: 'DistributionChannel' } }]
}
@ObjectModel.text.element: ['DistributionChannelName']
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
DistributionChannel,
@Semantics.text: true
@Consumption.filter.hidden: true
_DistributionChannel._Text.DistributionChannelName as DistributionChannelName : localized,
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_OrgDivisionValueHelp', element: 'Division' } }]
}
@ObjectModel.text.element: ['DivisionName']
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
Division,
@Semantics.text: true
@Consumption.filter.hidden: true
_Division._Text.DivisionName as DivisionName : localized,
@ObjectModel.text.element: ['SalesGroupName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_SalesGroupValueHelp', element: 'SalesGroup' } }]
}
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
SalesGroup,
@Semantics.text: true
@Consumption.filter.hidden: true
_SalesGroup._Text.SalesGroupName as SalesGroupName : localized,
@ObjectModel.text.element: ['SalesOfficeName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_SalesOfficeValueHelp', element: 'SalesOffice' } }]
}
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
SalesOffice,
@Semantics.text: true
@Consumption.filter.hidden: true
_SalesOffice._Text.SalesOfficeName as SalesOfficeName : localized,
@ObjectModel.text.element: ['CndnContrSuplrSettlmtCatName']
@Search: {
defaultSearchElement: true,
ranking: #MEDIUM,
fuzzinessThreshold: 0.8
}
CndnContrSuplrSettlmtCat,
@UI.hidden: true
@Semantics.text: true
_CndnContrSuplrSettlmtCat._Text.CndnContrSuplrSettlmtCatName as CndnContrSuplrSettlmtCatName : localized,
// @ObjectModel.text.element: ['CndnContrCustSettlmtCatName']
// @Search: {
// defaultSearchElement: true,
// ranking: #MEDIUM,
// fuzzinessThreshold: 0.8
// }
// CndnContrCustSettlmtCat,
//
// @UI.hidden: true
// @Semantics.text: true
// _CndnContrCustSettlmtCat._Text.CndnContrCustSettlmtCatName as CndnContrCustSettlmtCatName : localized,
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_ProductVH', element: 'Product' } }]
}
@ObjectModel.text.element: ['ProductName']
SettlmtProduct,
@Semantics.text: true
@Consumption.filter.hidden: true
_SettlmtProduct._Text.ProductName as ProductName : localized,
@ObjectModel.text.element: ['FactoryCalendarName']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'C_FactoryCalendarValueHelp', element: 'FactoryCalendar' } }]
}
CndnContrExtensionCalendar,
@Semantics.text: true
@Consumption.filter.hidden: true
_CndnContrExtensionCalendar._Text.FactoryCalendarName as FactoryCalendarName : localized,
@Consumption.hidden: true
PriorSupplier,
@UI.hidden: true
BusVolTableGroup,
@ObjectModel.text.element: ['AmountFieldGroupDesc']
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_AmountFieldGroup', element: 'AmountFieldGroup' } }]
}
AmountFieldGroup,
@Semantics.text: true
@UI.hidden: true
_AmountFieldGroup._Text.AmountFieldGroupDesc as AmountFieldGroupDesc : localized,
@UI.hidden: true
FinalSettlmtCalendar,
@UI.hidden: true
PartialSettlmtCalendar,
@UI.hidden: true
DeltaSettlmtCalendar,
@UI.hidden: true
DeltaAccrualSettlmtCalendar,
@UI.hidden: true
AccrualClearingSettlmtCalendar,
@API.element:{releaseState: #DEPRECATED, successor: 'PrecedingConditionDocument'}
@Consumption: {
semanticObject: 'ConditionContract',
valueHelpDefinition: [{ entity: { name: 'I_CndnContrSuplrRbteStdVH', element: 'ConditionContract' } }]
}
@UI.hidden: true
virtual PrecedingConditionContract : char10,
@Consumption: {
semanticObject: #(UICT_PrecdgCndnContrSemObj),
semanticObjectMapping: { element: 'ConditionContract' },
valueHelpDefinition: [{ entity: { name: 'I_PrecedingConditionDocumentVH', element: 'PrecedingConditionDocument' } }]
}
PrecedingConditionDocument,
@Consumption.hidden: true
CndnContrUUID,
CndnContrPurposeCat,
@ObjectModel.text.element: ['CurrencyName']
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_CurrencyStdVH', element : 'Currency' } }]
@Semantics.currencyCode: true
CndnContrCurrency,
@Semantics.text: true
@UI.hidden: true
_CndnContrCurrency._Text.CurrencyName as CurrencyName : localized,
@Semantics.unitOfMeasure: true
CndnContrUnit,
CndnContrWeightUnit,
CndnContrVolumeUnit,
CndnContrPointsQtyUnit,
ExchangeRate,
ExchangeRateDate,
ExchangeRateType,
PaymentTerms,
CashDiscount1Days,
CashDiscount1Percent,
CashDiscount2Days,
CashDiscount2Percent,
NetPaymentDays,
PaymentMethod,
AccrualUpdateIsRequired,
SettlmtPartTxRegnNmbr,
@ObjectModel.text.element: ['TaxCountryName']
TaxCountry,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_TaxCountry._Text.CountryName as fot_tax_country_descr preserving type ) as TaxCountryName : localized,
@ObjectModel.text.element: ['SettlmtPartTxRegnCntryName']
SettlmtPartTxRegnCntry,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_SettlmtPartTxRegnCntry._Text.CountryName as wcb_tax_country_text preserving type ) as SettlmtPartTxRegnCntryName : localized,
@UI.hidden: true
CndnContrPartnerCat,
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcessCategory', element: 'CndnContrProcessCategory' } }]
}
@ObjectModel: { text.element: ['CndnContrProcessCategoryDesc'] }
CndnContrProcessCategory,
@Semantics.text: true
@UI.hidden: true
_CndnContrProcessCategory._Text.CndnContrProcessCategoryDesc as CndnContrProcessCategoryDesc : localized,
/* Techincally required for DCL */
@Consumption.hidden: true
PersonWorkAgreement,
@Consumption.hidden: true
CndnContrWorkerCostCenter,
/* Virtual (Dynamic) Fields */
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
@ObjectModel: {
text.element: ['CndnContrMainSystemStatusText']
}
virtual CndnContrMainSystemStatus : wcb_main_system_status,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
@Semantics.text: true
virtual CndnContrMainSystemStatusText : wcb_main_syst_status_text,
@ObjectModel: {
virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT',
text.element: ['CnConSettlementLockStatusName']
}
virtual CnConSettlementLockStatus : wcb_cc_status_settl_locked,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
@Semantics.text: true
virtual CnConSettlementLockStatusName : wcb_cc_status_settl_locked_fio,
/* Obsolete Field - no longer needed */
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
@VDM.lifecycle: {
status: #DEPRECATED,
successor: 'CnConSettlementLockStatusName'
}
virtual CndnContrSettlmtIsLockedName : wcb_cc_status_settl_locked_fio,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual CndnContrCurSettlmtNetAmtInDC : wcb_cc_curcontrval,
@Semantics.amount.currencyCode: 'DisplayCurrency'
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual OpenAccrualsAmountInDC : wcb_accruals_open_in_dc,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual DisplayCurrency : displaycurrency,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_PrecdgCndnContrSemObj : /ui2/semantic_object,
/* Technical Fields */
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_ActvtnStatusCriticality : integer1,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CurSettlmtNetAmtInDC : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_OpenAccrualsAmountInDC : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_HDR_Partner_Info : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_HDR_Actvtn_Status : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_HDR_Lock_Status : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_HDR_Main_Status : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_GEN_INFO : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_SETTLMT_PAYMENT_TRMS : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_CONTR_GEN_DATA : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_CONTR_REFERENCES : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_CONTR_ADMIN_DATA : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_PAYMENT_TRMS : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_COLL_SETTLMT_DATA : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_CONTR_DETS : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_CONTR_VALDTY : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_CONTR_SOURCE_DOC : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_ORG_DATA_SLS : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_ORG_DATA_PURG : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_ADMIN_DATA : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_PAY_TERMS : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_PAY_TERMS_FIRST : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_PAY_TERMS_SECOND : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_PAY_TERMS_DAYS : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_CONTR_TAX : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_FLDGRP_CONTR_CURRENCY : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CndnContrSuplrSettlmtCat : boolean,
/* Restriction Fields */
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CndnContrProcVar : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_TaxCountry : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_BusVolTableGroup : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_AmountFieldGroup : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CndnContrUnit : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CndnContrWeightUnit : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CndnContrVolumeUnit : boolean,
@UI.hidden: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_WCB_CC_EC_F5989_EXIT'
virtual UICT_CndnContrPointsQtyUnit : boolean,
/* Associations */
_AmountFieldGroup,
@Consumption.hidden: true
_Customer,
_PriorSupplier,
_Supplier,
@Consumption.hidden: true
_PersonWorkAgreement,
_CndnContrSettlmtCal : redirected to composition child C_CndnContrSettlmtCal_F5989
}
where
CndnContrSemanticCode = '0005'
or(
CndnContrSemanticCode = '0000'
and CndnContrProcessCategory = '3'
)
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_AMOUNTFIELDGROUP",
"I_AMOUNTFIELDGROUPTEXT",
"I_CNDNCONTRACTVTNSTATUS",
"I_CNDNCONTRACTVTNSTATUSTEXT",
"I_CNDNCONTRCLASSFCTNTYPE",
"I_CNDNCONTRCLASSFCTNTYPETEXT",
"I_CNDNCONTRPROCESSCATEGORY",
"I_CNDNCONTRPROCESSCATEGORYTEXT",
"I_CNDNCONTRPROCVAR",
"I_CNDNCONTRPROCVARTEXT",
"I_CNDNCONTRSOURCEDOCCAT",
"I_CNDNCONTRSOURCEDOCCATTEXT",
"I_CNDNCONTRSUPLRSETTLMTCAT",
"I_CNDNCONTRSUPLRSETTLMTCATTXT",
"I_COMPANYCODE",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_DISTRIBUTIONCHANNEL",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISION",
"I_DIVISIONTEXT",
"I_FACTORYCALENDAR",
"I_FACTORYCALENDARTEXT",
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SALESGROUP",
"I_SALESGROUPTEXT",
"I_SALESOFFICE",
"I_SALESOFFICETEXT",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONTEXT",
"I_SUPPLIER",
"I_USER",
"R_CNDNCONTRTYPE",
"R_CNDNCONTRTYPETEXT",
"R_CONDITIONCONTRACTTP"
],
"ASSOCIATED":
[
"C_CNDNCONTRSETTLMTCAL_F5989",
"I_AMOUNTFIELDGROUP",
"I_CUSTOMER",
"I_PERSONWORKAGREEMENT_1",
"I_SUPPLIER",
"R_CNDNCONTRSETTLMTCALTP"
],
"BASE":
[
"R_CONDITIONCONTRACTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/