// Object Pages CDS views for PSM MD are now obsolete, starting 1709 use _TP views
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.semanticKey: ['FinancialManagementArea', 'FinMgmtAreaFiscalYear', 'CommitmentItem']
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@AbapCatalog.sqlViewName: 'CCOMMITIOBJP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Additional Selection - Commitment Item'
@UI.headerInfo: {
typeName: 'Commitment Item',
typeNamePlural: 'Commitment Items',
title: {
value:'CommitmentItem'
},
description: {
value:'CommitmentItemName'
}
}
//Comments:
// - Commitment Item is not in ACDOCA! Association is done to I_OperationalAcctgDocItem (=BSEG)
// - BSEG update is mandatory for PSM-FM in OP1610
define view C_CommitmentItem_ObjP
as select from I_CommitmentItem
association [0..*] to C_GlAccountByFinMgmtArea as _GLAccount on $projection.FinancialManagementArea = _GLAccount.FinancialManagementArea
and $projection.CommitmentItemShortID = _GLAccount.CommitmentItemShortID
association [0..*] to C_OplAcctgDocItemForObjp as _AccountingLine on $projection.FinancialManagementArea = _AccountingLine.CompanyCode
and $projection.CommitmentItemShortID = _AccountingLine.CommitmentItemShortID
association [0..*] to C_BudDocItemForObjP as _BudgetEntryDocument on $projection.FinancialManagementArea = _BudgetEntryDocument.FinancialManagementArea
and $projection.CommitmentItem = _BudgetEntryDocument.BudgetedCommitmentItem
association [0..*] to C_PurchaseOrderByFMAA as _PurchaseOrder on $projection.FinancialManagementArea = _PurchaseOrder.FinancialManagementArea
and $projection.CommitmentItem = _PurchaseOrder.PostedCommitmentItem
association [0..*] to C_PurchaseRequisitionByFMAA as _PurchaseRequisition on $projection.FinancialManagementArea = _PurchaseRequisition.FinancialManagementArea
and $projection.CommitmentItem = _PurchaseRequisition.PostedCommitmentItem
association [0..*] to C_EarmarkedFundsItemForObjP as _EarmarkedFundsItem on $projection.FinancialManagementArea = _EarmarkedFundsItem.FinancialManagementArea
and $projection.CommitmentItem = _EarmarkedFundsItem.CommitmentItem
association [0..1] to C_LastValidFundsCenterWST as _FundsCenter on $projection.FinancialManagementArea = _FundsCenter.FinancialManagementArea
and $projection.CmtmtItmDefaultFundsCenter = _FundsCenter.FundsCenter
association [0..*] to C_SetLeafForCIObjP as _Sets on _Sets.SetClass = '0311'
and $projection.CommitmentItem = _Sets.CommitmentItem
and $projection.FinancialManagementArea = _Sets.SetSubClass
{
@UI:{ fieldGroup: {qualifier: 'General Information', position: 10, importance: #HIGH} }
@UI.lineItem: [{
position: 10,
importance: #HIGH }]
@EndUserText.label: 'Financial Management Area'
key I_CommitmentItem.FinancialManagementArea,
@EndUserText.label: 'Financial Management Area Fiscal Year'
//@UI.hidden: true
key I_CommitmentItem.FinMgmtAreaFiscalYear,
@UI.lineItem: [{
position: 20,
importance: #HIGH }]
key I_CommitmentItem.CommitmentItem,
@EndUserText.label: 'Internal Commitment Item Name'
@Consumption.hidden: true
I_CommitmentItem.CommitmentItemShortID,
@EndUserText.label: 'Directly Postable'
@Consumption.hidden: true
I_CommitmentItem.CommitmentItemIsPostingEnabled,
@UI:{ fieldGroup: {qualifier: 'General Information', position: 40, importance: #HIGH, multiLineText} }
@UI.lineItem: [{
position: 40,
importance: #HIGH }]
@EndUserText.label: 'Financial Transaction'
I_CommitmentItem.CmtmtItmFinancialTransaction,
@Semantics.text: true
@UI:{ fieldGroup: {qualifier: 'General Information', position: 50, importance: #HIGH, multiLineText} }
@UI.lineItem: [{
position: 50,
importance: #HIGH }]
@EndUserText.label: 'Financial Transaction Description'
I_CommitmentItem._FinancialTransaction._Text[1:Language = $session.system_language].CmtmtItmFinTransactionText,
@UI:{ fieldGroup: {qualifier: 'General Information', position: 60, importance: #HIGH} }
@EndUserText.label: 'Commitment Item Category'
I_CommitmentItem.CommitmentItemCategory,
@Semantics.text: true
@UI:{ fieldGroup: {qualifier: 'General Information', position: 70, importance: #HIGH} }
@EndUserText.label: 'Commitment Item Category Name'
I_CommitmentItem._CommitmentItemCategory._Text[1:Language = $session.system_language].CommitmentItemCategoryName,
@EndUserText.label: 'Commitment Item Type'
@UI.lineItem: [{
position: 60,
importance: #HIGH }]
I_CommitmentItem.CommitmentItemType,
@EndUserText.label: 'Parent Commitment Item'
@Consumption.hidden: true
I_CommitmentItem.ParentCommitmentItem,
@EndUserText.label: 'Internal Commitment Item Number'
@Consumption.hidden: true
I_CommitmentItem.CommitmentItemInternalId,
@EndUserText.label: 'Default Funds Center'
@UI:{ fieldGroup: {qualifier: 'General Information', position: 100, importance: #HIGH} }
I_CommitmentItem.CmtmtItmDefaultFundsCenter,
@Semantics.text: true
@UI:{ fieldGroup: {qualifier: 'General Information', position: 110, importance: #HIGH} }
@EndUserText.label: 'Default Funds Center Name'
_FundsCenter.FundsCenterName,
@Semantics.text: true
@EndUserText.label: 'Default Funds Center Description'
@Consumption.hidden: true
_FundsCenter.FundsCenterDescription,
@UI:{ fieldGroup: {qualifier: 'General Information', position: 90, importance: #HIGH} }
@EndUserText.label: 'Carry Forward Item Category'
I_CommitmentItem.CmtmtItmCarryFwdItmCategory,
@UI:{ fieldGroup: {qualifier: 'General Information', position: 120, importance: #HIGH} }
I_CommitmentItem.CommitmentItemAuthznGrp,
@UI:{ fieldGroup: {qualifier: 'General Information', position: 80, importance: #HIGH} }
@EndUserText.label: 'Statistical Commitment Item'
I_CommitmentItem.CommitmentItemIsStatistical,
@UI:{ fieldGroup: {qualifier: 'General Information', position: 180, importance: #HIGH} }
I_CommitmentItem.CommitmentItemRequestType,
@UI:{ fieldGroup: {qualifier: 'Administrative Data', position: 20, importance: #HIGH} }
I_CommitmentItem._CommitmentItemHierarchy[1:CommitmentItemHierarchyVariant = '000'].CreatedByUser,
@UI:{ fieldGroup: {qualifier: 'Administrative Data', position: 10, importance: #HIGH} }
@Consumption.filter.selectionType: #INTERVAL
I_CommitmentItem._CommitmentItemHierarchy[1:CommitmentItemHierarchyVariant = '000'].CreationDate,
//Service items
@Consumption.hidden: true
I_CommitmentItem._FinMgmtArea.FinMgmtAreaFiscalYearVariant,
@Consumption.hidden: true
I_CommitmentItem.CmtmtItemFinMgmtAreaForAuthzn,
//Text
@Semantics.text: true
@EndUserText.label: 'Financial Management Area Name'
@UI:{ fieldGroup: {qualifier: 'General Information', position: 20, importance: #HIGH} }
I_CommitmentItem._FinMgmtArea._Text[1:Language = $session.system_language].FinancialManagementAreaName,
@Semantics.text: true
@Consumption.hidden: true
cast( concat_with_space(FinancialManagementArea, _FinMgmtArea._Text[1:Language = $session.system_language].FinancialManagementAreaName, 1) as fmis_fmaextendedname )
as FinMgmtAreaExtendedName,
@Semantics.text: true
@UI:{ fieldGroup: {qualifier: 'General Information', position: 30, importance: #HIGH} }
@UI.lineItem: [{
position: 30,
importance: #HIGH }]
_Text[1:Language=$session.system_language].CommitmentItemName,
@UI:{ fieldGroup: {qualifier: 'Validity', position: 10, importance: #HIGH} }
@Consumption.filter.selectionType: #INTERVAL
I_CommitmentItem.ValidityEndDate,
@UI:{ fieldGroup: {qualifier: 'Validity', position: 20, importance: #HIGH} }
@Consumption.filter.selectionType: #INTERVAL
I_CommitmentItem.ValidityStartDate,
@UI:{ fieldGroup: {qualifier: 'Validity', position: 30, importance: #HIGH} }
@Consumption.filter.selectionType: #INTERVAL
I_CommitmentItem.CommitmentItemExpirationDate,
//GL Account
_GLAccount,
//Facet Accounting Document
_AccountingLine,
//Facet Budget Entry Document
_BudgetEntryDocument,
//Facet Purchase Order
_PurchaseOrder,
//Facet Purchase Requisition
_PurchaseRequisition,
//Earmarked Funds
_EarmarkedFundsItem,
//Sets
_Sets
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_LASTVALIDFUNDSCENTERWST",
"I_CMTMTITMFINANCIALTRANSACTION",
"I_CMTMTITMFINTRANSACTIONTEXT",
"I_COMMITMENTITEM",
"I_COMMITMENTITEMCATEGORY",
"I_COMMITMENTITEMCATEGORYTEXT",
"I_COMMITMENTITEMHIERARCHY",
"I_COMMITMENTITEMTEXT",
"I_FINANCIALMANAGEMENTAREA",
"I_FINANCIALMANAGEMENTAREATEXT"
],
"ASSOCIATED":
[
"C_BUDDOCITEMFOROBJP",
"C_EARMARKEDFUNDSITEMFOROBJP",
"C_GLACCOUNTBYFINMGMTAREA",
"C_LASTVALIDFUNDSCENTERWST",
"C_OPLACCTGDOCITEMFOROBJP",
"C_PURCHASEORDERBYFMAA",
"C_PURCHASEREQUISITIONBYFMAA",
"C_SETLEAFFORCIOBJP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/