C_CollabnApplFreightRFQ

//@AbapCatalog.sqlViewName: 'CCOLLABNFRTRFQ'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

//@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AccessControl.privilegedAssociations: ['_FreightQuotation',
                                        '_CollabnApplFreightRFQNote']

@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel.representativeKey: 'FreightRequestForQuotationUUID'
@ObjectModel.semanticKey: ['FreightRequestForQuotation']
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Freight Request For Quotation'
define root view entity C_CollabnApplFreightRFQ
  as select from P_CollabnApplFreightRFQ
  association [1..*] to C_CollabnApplFrtOrdRFQStop  as _TransportationOrderStop   on  $projection.RefTransportationOrderUUID = _TransportationOrderStop.RefTransportationOrderUUID
                                                                                  and $projection.TenderingUUID              = _TransportationOrderStop.TenderingStopDateGroupUUID
  association [0..*] to C_CollabnApplFreightRFQNote as _CollabnApplFreightRFQNote on  $projection.TransportationOrderUUID = _CollabnApplFreightRFQNote.TransportationOrderUUID
  association [0..*] to C_CollabnApplFreightQtanRef as _FreightQuotation          on  $projection.FreightRequestForQuotation = _FreightQuotation.FreightRequestForQuotation
{
  key FreightRequestForQuotationUUID,
      TenderingUUID,
      FreightRequestForQuotation,
      RefTransportationOrderUUID,
      TransportationOrderUUID,

      @ObjectModel.text.element: ['TenderingManagerFullName']
      TenderingManager,
      @Semantics.text: true
      TenderingManagerFullName,
      TenderingRequestedCarrier,
      TenderingResponseDueDateTime,

      @ObjectModel.text.element: ['PurchasingOrganizationName']
      PurchasingOrgExternalID,
      @Semantics.text: true
      PurchasingOrganizationName,
      @ObjectModel.text.element: ['MeansOfTransportDesc']
      TranspMeansOfTransport,
      @Semantics.text: true
      MeansOfTransportDesc,
      //      @Semantics.unitOfMeasure: true

      TranspOrdDistanceUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdDistanceUnit'
      TranspOrdDistance,
      //      @Semantics.unitOfMeasure: true

      TranspOrdNetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdNetDurationUnit'
      TranspOrdNetDuration,
      TransportationOrderCategory,
      TransportationOrderType,

      //Visibility Settings

      TenderingPriceLimitVisibility,
      TenderingLowestPriceVisibility,
      TenderingStopDateVisibility,
      TenderingSubmdPriceVisibility,
      TenderingSubmdPrCrcyVisibility,

      @ObjectModel.text.element: ['FreightRFQLifecycleStatusDesc']
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_CollabnTndrgReqLifeCycStsVH'  , element: 'FreightRFQLifecycleStatus'}}]
      FreightRFQLifecycleStatus,
      @Semantics.text: true
      _CollabnApplFrtRFQLfcycStatus._Text[1: Language = $session.system_language ].FreightRFQLifecycleStatusDesc as FreightRFQLifecycleStatusDesc,

      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_TransportationLocationVH'  , element: 'Location'}}]
      @ObjectModel.text.element: ['SourceLocationDescription']
      SourceLocation,
      @Semantics.text: true
      SourceLocationDescription,
      SourceLocationAddressDesc,

      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_TransportationLocationVH'  , element: 'Location'}}]
      @ObjectModel.text.element: ['DestinationLocationDescription']
      DestinationLocation,
      @Semantics.text: true
      DestinationLocationDescription,
      DestinationLocationAddressDesc,

      @Semantics.dateTime: true
      TranspOrdDepartureDateTime,

      @Semantics.dateTime: true
      TranspOrdArrivalDateTime,

      //Response Due

      FreightRFQResponseDue,
      FreightRFQResponseDueCritlty,


      @Semantics.amount.currencyCode: 'TenderingPreferredCurrency'
      TndrgReqAbsolutePriceLimitAmt,
      //      @Semantics.currencyCode: true

      TenderingLowestProposedAmtCrcy,
      @Semantics.amount.currencyCode: 'TenderingLowestProposedAmtCrcy'
      TenderingLowestProposedAmount,

      //      @Semantics.currencyCode: true

      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_CurrencyStdVH'  , element: 'Currency'}}]
      TenderingPreferredCurrency,


      TenderingResponseSqncNumber,
      @ObjectModel.text.element: ['TenderingResponseCodeDesc']
      TenderingResponseCode,
      @Semantics.text: true
      TenderingResponseCodeDesc,

      TranspOrdGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossWeightUnit'
      TranspOrdGrossWeight,

      TranspOrdGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossVolumeUnit'
      TranspOrdGrossVolume,

      TranspOrdQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdQuantityUnit'
      TranspOrdQuantity,
      @ObjectModel.text.element: ['TranspOrderDngrsGdsStsDesc'] 
      TranspOrderDngrsGdsSts,
      @Semantics.text: true
      TranspOrderDngrsGdsStsDesc,

      /* Associations */

      _TransportationOrderStop,
      _CollabnApplFreightRFQNote,
      _FreightQuotation,
      _TenderingManager

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COLLABNAPPLFRTRFQLFCYCSTATUS",
"I_COLLABNAPPLFRTRFQLFCYCSTSTXT",
"P_COLLABNAPPLFREIGHTRFQ"
],
"ASSOCIATED":
[
"C_COLLABNAPPLFREIGHTQTANREF",
"C_COLLABNAPPLFREIGHTRFQNOTE",
"C_COLLABNAPPLFRTORDRFQSTOP",
"C_COLLABNAPPLTENDERINGMANAGER"
],
"BASE":
[
"P_COLLABNAPPLFREIGHTRFQ"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/