C_CnsldtnUnitByTimeTP

@Metadata.allowExtensions: false
@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #M
}
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consolidation Unit Time Dependent'
@Metadata.ignorePropagatedAnnotations: true
define view entity C_CnsldtnUnitByTimeTP
  as projection on R_CnsldtnUnitByTimeTP as _CnsldtnUnitByTime
{
  key _CnsldtnUnitByTime.ConsolidationUnit, // no value help required as field is not input enabled on UI



      @EndUserText: {
        label: 'From Fiscal Year and Period',
        quickInfo: 'From Fiscal Year and Period'
      }
      @Semantics.fiscal.yearPeriod: true
  key _CnsldtnUnitByTime.FromFiscalYearPeriod,


      @EndUserText: {
        label: 'To Fiscal Year and Period',
        quickInfo: 'To Fiscal Year and Period'
      }
      @Semantics.fiscal.yearPeriod: true
      _CnsldtnUnitByTime.ToFiscalYearPeriod,


      @Consumption.valueHelpDefinition: [{
        entity:{
          name:'C_CnsldtnCurrencyVH',
          element:'Currency'}
      }]
      @EndUserText: {
        label: 'Local Currency',
        quickInfo: 'Local Currency'
      }
      @ObjectModel.text.element: [ 'CurrencyName' ]
      @UI.textArrangement: #TEXT_LAST
      _CnsldtnUnitByTime.ConsolidationUnitLocalCurrency,


      @Consumption.valueHelpDefinition: [{
        entity:{
          name:'C_CnsldtnCompanyVH',
          element:'Company'}
      }]
      @EndUserText: {
        label: 'Company',
        quickInfo: 'Company'
      }
      @ObjectModel.text.element: [ 'CompanyName' ]
      @UI.textArrangement: #TEXT_LAST
      _CnsldtnUnitByTime.Company,
      

      @UI.hidden: true
      _CnsldtnUnitByTime.ETag,

      // texts

      @EndUserText: {
        label: 'Local Currency Description',
        quickInfo: 'Local Currency Description'
      }
      @Semantics.text:true
      _CnsldtnUnitByTime._Currency._Text.CurrencyName : localized,

      @EndUserText: {
        label: 'Company Description',
        quickInfo: 'Company Description'
      }
      @Semantics.text:true
      _CnsldtnUnitByTime._Company._Text.CompanyName : localized,


      // parent definition

      _CnsldtnUnit as _CnsldtnUnit : redirected to parent C_CnsldtnUnitTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNCOMPANY",
"I_CNSLDTNCOMPANYT",
"I_CURRENCY",
"I_CURRENCYTEXT",
"R_CNSLDTNUNITBYTIMETP"
],
"ASSOCIATED":
[
"C_CNSLDTNUNITTP"
],
"BASE":
[
"R_CNSLDTNUNITBYTIMETP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/