C_ClearedItem

@AbapCatalog.sqlViewName: 'CCLRDITM'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Cleared Item'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
// ILM: BSEG et.al. belong to archiving object FI_DOCUMNT (deletion available according to SEC-12)

@AccessControl.personalData.blocking:#BLOCKED_DATA_EXCLUDED

@UI.headerInfo:{
  typeName: 'Clearing Journal Entry Item',
  typeNamePlural: 'Clearing Journal Entry Items',
  title: { type: #STANDARD }
}

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

define view C_ClearedItem
  as select from P_ClearedItem3
  
  association [1..1] to C_ClearingDocument as _Header on  $projection.CompanyCode                     = _Header.CompanyCode
                                                      and $projection.ClearingJournalEntry            = _Header.ClearingJournalEntry 
                                                      and $projection.ClearingJournalEntryFiscalYear  = _Header.ClearingJournalEntryFiscalYear
                                                      and $projection.IntercompanyTransaction         = _Header.IntercompanyTransaction // See comment for field IntercompanyTransaction in view C_ClearingDocument

                                                       
{
      @UI.lineItem: [ { position:10, importance: #HIGH } ]
      @UI.identification: [ { position: 10, importance: #HIGH } ]
  key CompanyCode as CompanyCode,
  
      @UI.lineItem: [ { position:40, importance: #HIGH } ]
      @UI.identification: [ { position: 40, importance: #HIGH } ]
      @Consumption.semanticObject: 'AccountingDocument'
  key AccountingDocument,

      @UI.lineItem: [ { position:50, importance: #HIGH } ]
      @UI.identification: [ { position: 60,  importance: #HIGH } ]
  key AccountingDocumentItem,
  
      @UI.lineItem: [ { position:180, exclude: true, importance: #LOW } ]
      @UI.identification: [ { position: 50, exclude: true, importance: #LOW } ]
  key FiscalYear,
  
      //The fields CompanyCode, FiscalYear, AccountingDocument and AccountingDocumentItem might not form an unique key

      //for line items which belong to an Accounting Document which has been archived and the line items still reside in 

      //the corresponding *_BCK Tables. The reason is that the value of field AccountingDocumentItem might change during 

      //the move of line items from BSEG/BSEG_ADD to the *_BCK tables.  

      //Due to that the field FinancialAccountType is part of the key.    

      @UI.lineItem: [ { position:120, exclude: true, importance: #MEDIUM } ]
  key FinancialAccountType,
  
      @UI.lineItem: [ { position:160, exclude: true, importance: #LOW } ]
      @UI.identification: [ { position: 20, exclude: true, importance: #LOW } ]
      ClearingJournalEntry,

      @UI.lineItem: [ { position:170, exclude: true, importance: #LOW } ]
      @UI.identification: [ { position: 30, exclude: true, importance: #LOW } ]
      ClearingJournalEntryFiscalYear,
      
      @UI.lineItem: [ { position:20, importance: #HIGH } ]
      Account,

      @UI.lineItem: [ { position:30, importance: #HIGH } ]
      AssignmentReference,

      @UI.lineItem: [ { position:60, importance: #HIGH } ]
      AccountingDocumentType,

      @UI.lineItem: [ { position:70, importance: #HIGH } ]
      PostingDate,

      @UI.lineItem: [ { position:80, importance: #HIGH } ]
      SpecialGLCode,

      @UI.lineItem: [ { position:90, importance: #MEDIUM } ]
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @DefaultAggregation:#SUM
      @ObjectModel.filter.enabled: true
      AmountInCompanyCodeCurrency,

      @UI.lineItem: [ { position:100, importance: #MEDIUM } ]
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @DefaultAggregation:#SUM
      @ObjectModel.filter.enabled: true
      CashDiscountAmtInCoCodeCrcy,

      @Semantics.currencyCode:true
      @UI.lineItem: [ { position:140, exclude: true, importance: #LOW } ]
      CompanyCodeCurrency,

      @UI.lineItem: [ { position:110, importance: #HIGH } ]
      DocumentItemText,

      @UI.lineItem: [ { position:130, exclude: true, importance: #LOW } ]
      DocumentDate,

      @UI.lineItem: [ { position:150, exclude: true, importance: #LOW } ]
//    It has been discussed and decided (also with G/L) that for all items 

//    (independently of the item's FinancialAccountType) the old determination logic 

//    as implemented in transaction FBRA,FBL5,FBL3,FBL1 should not be taken over 

//    It has been discussed and decided (also with G/L) that for all items 

//    (independently of the item's FinancialAccountType) a determination logic 

//    should not be applied at all, instead the field Invoice Reference holds

//    always the content of the DB field BSEG-REBZG

      InvoiceReference,
      
      @UI.lineItem: [ { position:160, exclude: true, importance: #LOW } ]
      AccountingDocumentCategory,
      
      @UI.lineItem: [ { position:900, exclude: true, importance: #LOW } ]
      @UI.identification: [ { position: 900, exclude: true, importance: #LOW } ]
      cast( ClearingJournalEntry as fis_augbl_depre  preserving type )                  as ClearingAccountingDocument,

      @UI.lineItem: [ { position:910, exclude: true, importance: #LOW } ]
      @UI.identification: [ { position: 910, exclude: true, importance: #LOW } ]
      cast( ClearingJournalEntryFiscalYear as fis_auggj_no_conv_depre preserving type ) as ClearingDocFiscalYear,
      
      @UI.hidden: true
      IntercompanyTransaction,
      
      @UI.hidden: true
      IsNetInvoiceCashDiscClearing,
 
      _Header
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CLEAREDITEM3"
],
"ASSOCIATED":
[
"C_CLEARINGDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/