C_ChmlCompositionComponentVH

@AbapCatalog: {
  sqlViewName: 'CCCMPCOMPVH',
  compiler.compareFilter: true }

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Composition Component'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  usageType: {
    serviceQuality: #C,        // < 2 msec

    sizeCategory:  #L,         // < 1.000

    dataClass: #MASTER },
  dataCategory: #VALUE_HELP,
  resultSet.sizeCategory: #XS,
  representativeKey: 'SubstanceUUID' }

@VDM.viewType: #CONSUMPTION

define view C_ChmlCompositionComponentVH
  --Select data from basic view 'Chemical Component'
  as select from I_ChmlComponent as Component

{
      @Consumption.filter.hidden: true                  -- hide that field as input field in the generated VH
      @Consumption.hidden: false                        -- must be not true otherwise wouldn't the VH annotation binding work
      @ObjectModel.text.element: ['SubstanceName']
  key SubstanceUUID,

  key ChmlCompositionUUID,

      @UI.hidden: true
  key Component._ChemicalComposition.ChmlCompositionType,

      ChmlCmplncInfoUUID,
      ChmlSuplrMatlUUID,
      HostSubstanceUUID,

      @Semantics.text: true
      Component._Substance.SubstanceName as SubstanceName
}
where
      Component._ChemicalComposition.ChmlCompositionStatus =  'RE'
  and Component._ChemicalComposition.ChmlCompositionType   <> 'MATLBSD1'
  and Component._ChemicalComposition.ChmlCompositionType   <> 'MATLBSD2'
  and Component._ChemicalComposition.ChmlCompositionType   <> 'TS'
  and Component._ChemicalComposition.ChmlCompositionType   <> 'POLYMER'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCOMPONENT",
"I_CHMLCOMPOSITION",
"I_SUBSTANCEENHANCED"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/