C_ChmlCmplncRawMatVH

@EndUserText.label: 'Value Help for Components of Material Based Composition'

@AbapCatalog:
{
  sqlViewName: 'CCCIRAWMATVH',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required (no personal data fields exposed for material)

  personalData.blocking: #NOT_REQUIRED
}

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  dataCategory: #VALUE_HELP,

  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  },
  representativeKey: 'ChmlCmplncInfoUUID',
  semanticKey: ['ChmlCmplncInfoCombinedName']
}

@Metadata.ignorePropagatedAnnotations: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@UI:{
  presentationVariant: [{
    sortOrder: [{ by: 'ChmlCmplncInfoCombinedName', direction: #ASC }],
     requestAtLeast: ['Material',
                      'ProductName',
                      'MaterialIsProduced',
                      'MaterialIsSourced'
                    ]
  }]
}

@Search.searchable: true
@Consumption.ranked:true

/*
 * This view is used in the object page of the material based composition
 * to diplay all CCIs with type = 'Bulk' and role 'Produced' or 'Sourced'
 * in a value help
 */

define view C_ChmlCmplncRawMatVH
  as select from I_ChmlCmplncInfoVH as ChemicalComplianceInfo
{
      @UI.hidden: true
  key ChemicalComplianceInfo.ChmlCmplncInfoUUID,

      @UI.lineItem: [{ position: 10, importance: #HIGH }]
      @Consumption.filter.hidden: true
      ChmlCmplncInfoCombinedName,

      @UI.lineItem: [{ position: 20, importance: #HIGH }]
      Material,

      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.7,
         ranking: #HIGH
      }
      @UI.hidden: true
      ProductName,

      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.7,
         ranking: #HIGH
      }
      @UI.lineItem: [{ position: 30, importance: #HIGH }]
      ChmlCmplncInternalName,

      // needed for DCL

      @UI.hidden: true
      ProdStewardshipRespUnit,
      @UI.hidden: true
      ChmlCmplncInfoType,
      @UI.hidden: true
      MaterialIsSold,
      @UI.hidden: true
      MaterialIsTransported,
      @UI.hidden: true
      MaterialIsDisposed,
      @UI.hidden: true
      MaterialIsEmissionRelevant,
      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.7,
         ranking: #HIGH
      }
      @UI.lineItem: [{ position: 40, importance: #HIGH }]
      MaterialIsSourced,
      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.7,
         ranking: #HIGH
      }
      @UI.lineItem: [{ position: 50, importance: #HIGH }]
      MaterialIsProduced
}
-- Only for CCI type 'Bulk' and CCI role 'Sourced' or 'Produced'
where
       ChmlCmplncInfoType = 'BU'
  and(
       MaterialIsSourced  = 'X'
    or MaterialIsProduced = 'X'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCMPLNCINFOVH"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/