C_ChmlCmplncPrpsAssgmtTP

@EndUserText.label: 'Chemical Compliance Purpose Assignment'

@AbapCatalog:
{
  sqlViewName: 'CCCPRPSASSGMTTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  transactionalProcessingDelegated: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  semanticKey:  [ 'CmplncPrpsUUID' ],
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #M,
    serviceQuality: #C
  }
}

@UI:
{
  headerInfo : {
    typeName : 'Assigned Compliance Purposes',
    typeNamePlural : 'Assigned Compliance Purposes'
  },
  presentationVariant:
  {
    sortOrder:
    {
      by: 'CmplncPrpsName',
      direction: #ASC
    }
  }
}

@Search.searchable : true

define view C_ChmlCmplncPrpsAssgmtTP
  as select from I_ChmlCmplncPrpsAssgmtTP

  association [1..1] to C_ChmlCmplncInfoTP        as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  association [0..1] to P_ChmlCmplncPrpsMktRqmtCt as _PrpsMktRqmtCt  on _PrpsMktRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [0..1] to P_ChmlCmplncPrpsDGRqmtCt  as _PrpsDGRqmtCt   on _PrpsDGRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [0..1] to P_ChmlCmplncPrpsSdsRqmtCt as _PrpsSdsRqmtCt on _PrpsSdsRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [0..*] to C_CmplncPrpsNameWithFallback as _CmplncPrpsText on _CmplncPrpsText.CmplncPrpsUUID = $projection.CmplncPrpsUUID


{

      @ObjectModel.readOnly: true
      @UI.hidden: true
  key ChmlCmplncPrpsAssgmtUUID,

      @UI.hidden: true
      ChmlCmplncInfoUUID,

      @UI.hidden: true
      CmplncPrpsUUID,

      @ObjectModel.readOnly: true
      @UI:
      {
        lineItem:
        {
          position: 10,
          importance: #HIGH
        }
      }
      cast(_CmplncPrpsText.CmplncPrps as ehfnd_cmplnc_prps) as CmplncPrpsName,
      
      // For search only

      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Search: {
        defaultSearchElement : true,
        fuzzinessThreshold: 0.7,
        ranking: #MEDIUM
      }
      _CmplncPrpsText.CmplncPrpsName as CmplncPrpsFallbackName,
      
      // For search only

      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Search: {
        defaultSearchElement : true,
        fuzzinessThreshold: 0.7,
        ranking: #MEDIUM
      }
      _CmplncPrpsText.CmplncPrpsEnglishName,


      @UI:
      {
        lineItem:
        {
          position: 20,
          importance: #HIGH
        }
      }
      @ObjectModel.readOnly: true
      _PrpsMktRqmtCt.NmbrOfChmlCmplncMktRqmts,

      // Number of Compliance Requirement - Dangerous Goods

      @UI:
      {
       lineItem:
       {
         position: 30,
         importance: #HIGH
       }
      }
      @ObjectModel.readOnly: true
      _PrpsDGRqmtCt.NmbrOfChmlCmplncDngrsGdsRqmts,
      
      // Number of Compliance Requirement - Dangerous Goods

      @UI:
      {
       lineItem:
       {
         position: 40,
         importance: #HIGH
       }
      }
      @ObjectModel.readOnly: true
      _PrpsSdsRqmtCt.NmbrOfChmlCmplncDataShtRqmts,


      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ChmlCmplncInfo,
      _Purpose
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CMPLNCPRPSNAMEWITHFALLBACK",
"I_CHMLCMPLNCPRPSASSGMTTP",
"P_CHMLCMPLNCPRPSDGRQMTCT",
"P_CHMLCMPLNCPRPSMKTRQMTCT",
"P_CHMLCMPLNCPRPSSDSRQMTCT"
],
"ASSOCIATED":
[
"C_CHMLCMPLNCINFOTP",
"C_CMPLNCPRPSNAMEWITHFALLBACK",
"I_CMPLNCPRPS",
"P_CHMLCMPLNCPRPSDGRQMTCT",
"P_CHMLCMPLNCPRPSMKTRQMTCT",
"P_CHMLCMPLNCPRPSSDSRQMTCT"
],
"BASE":
[
"I_CHMLCMPLNCPRPSASSGMTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/