C_ChmlCmplncBaseProdVH

@EndUserText.label: 'Value Help for Bulk Chemical Compliance Information'

@AbapCatalog:
{
  sqlViewName: 'CCCIBASPRODVH',
  compiler.compareFilter: true
}

@AccessControl:{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required (no personal data fields exposed for material)

  personalData.blocking: #NOT_REQUIRED
}

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  dataCategory: #VALUE_HELP,

  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  },
  representativeKey: 'ChmlCmplncInfoUUID',
  semanticKey: ['Material']
}

@Metadata.ignorePropagatedAnnotations: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@UI:{

  presentationVariant: [{
    sortOrder: [{ by: 'ProductName', direction: #ASC }],
    requestAtLeast: ['Material','ChmlCmplncInfoCombinedName','ChmlCmplncInternalName','ProdStewardshipRespUnit','DngrsGdsRespUnit']
  }]
}


@Search.searchable: true

/*
 * This view is used as value help for unpackaged (bulk) compliance views.
 * CAUTION: The DCL enforces EDIT (02) authorization on the respective CCIs, not only F4 or 03 ( display )
 */

define view C_ChmlCmplncBaseProdVH 
  as select from I_ChmlCmplncInfoVH as ChmlCmplncInfo
{
      @UI.hidden: true
      @ObjectModel.text.element: ['ChmlCmplncInfoCombinedName']
      @Semantics.text: true
  key ChmlCmplncInfo.ChmlCmplncInfoUUID,

      --Material number
      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.8,
         ranking: #HIGH
      }
      @UI.lineItem: [{ position: 20, importance: #HIGH }]
      Material,

      --Combined name
      @UI.lineItem: [{ position: 10, importance: #HIGH }]
      ChmlCmplncInfoCombinedName,

      --Name of assigned product
      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.8,
         ranking: #HIGH
      }
      @UI.hidden: true
      ProductName,

      --CCI Internal name
      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 0.8,
         ranking: #LOW
      }
      @UI.lineItem: [{ position: 30, importance: #HIGH }]
      ChmlCmplncInternalName,

      // needed for DCL and needed for UI - don't remove

      @UI.hidden: true     
      ProdStewardshipRespUnit,
      @UI.hidden: true
      DngrsGdsRespUnit,

      @UI.hidden: true
      ChmlCmplncInfoType,
      @UI.lineItem: [{ position: 40, importance: #LOW }]
      MaterialIsSold,
      @UI.hidden: true
      MaterialIsTransported,
      @UI.hidden: true
      MaterialIsDisposed,
      @UI.hidden: true
      MaterialIsEmissionRelevant,
      @UI.lineItem: [{ position: 50, importance: #LOW }]
      MaterialIsSourced,
      @UI.lineItem: [{ position: 60, importance: #LOW }]
      MaterialIsProduced
}
-- Only for Unpackaged Product
where
       ChmlCmplncInfoType    = 'BU'
      //No restrictions regarding logistics roles

 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCMPLNCINFOVH"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/