C_ChgRecdRefStdBOM

@AbapCatalog.sqlViewName: 'CCHGRCDOBJPGSBM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Change Record Reference Object Std BOM'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.preserveKey:true
@ObjectModel.usageType: {serviceQuality: #C,
                        dataClass: #MIXED,
                        sizeCategory: #XXL}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
   semanticKey: ['StandardObject','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant'],
   createEnabled: true,
   deleteEnabled:'EXTERNAL_CALCULATION',
   updateEnabled,
   transactionalProcessingDelegated: true
}

@Metadata.allowExtensions: true

define view C_ChgRecdRefStdBOM
  as select from I_ChangeRecordRefStdBOMTP as ChangeRecordReferenceSBMTP

  association [1..1] to C_ChangeRecordObjPg          as _ChangeRecordObjPg          on  $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID

  association [0..1] to C_ChangeRecordStdBOMVH       as _ChangeRecordStdBOMVH       on  $projection.StandardObject             = _ChangeRecordStdBOMVH.StandardObject
                                                                                    and $projection.Plant                      = _ChangeRecordStdBOMVH.Plant
                                                                                    and $projection.BillOfMaterialVariantUsage = _ChangeRecordStdBOMVH.BillOfMaterialVariantUsage
                                                                                    and $projection.BillOfMaterialVariant      = _ChangeRecordStdBOMVH.BillOfMaterialVariant

  association [0..1] to I_PlantStdVH                 as _Plant                      on  $projection.Plant = _Plant.Plant

  association [0..1] to I_BillOfMaterialUsage        as _BillOfMaterialVariantUsage on  $projection.BillOfMaterialVariantUsage = _BillOfMaterialVariantUsage.BillOfMaterialVariantUsage
                                                                                    and _BillOfMaterialVariantUsage.Language   = $session.system_language

  association [1..1] to C_ChgRecdItemRlvnceStdBOMVH  as _ChangeRecordItemRelVH      on  $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                    and $projection.ChangeRecordType          = _ChangeRecordItemRelVH.ChangeRecordType

  association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH         on  $projection.ChangeRecordItemProcgStatus   = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
                                                                                    and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
                                                                                    and $projection.ChangeRecordLifecycleStatus   = _ProcessingStatusVH.ChangeRecordLifecycleStatus
  association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt        on  $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
  association [0..*] to C_ChangeRecdDigSignStatusVH  as _DigSignStatusText          on  $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus

{
          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @Semantics.imageUrl: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_OBJECT_THUMBNAIL_VE'

          cast( '' as productimageurl )                  as ProductImageURL,
          @Consumption.valueHelpDefinition: [{
                        entity:  { name:        'C_ChangeRecordStdBOMVH',
                                element:        'StandardObject' },
             additionalBinding:[{ localElement: 'Plant',
                                 element:       'Plant' },
                                { localElement: 'BillOfMaterialVariantUsage',
                                 element:       'BillOfMaterialVariantUsage' },
                                { localElement: 'BillOfMaterialVariant',
                                 element:       'BillOfMaterialVariant' }]
           }]
          @UI.lineItem:[{importance:#HIGH } ]
          StandardObject,

          @UI.lineItem:[{importance:#HIGH } ]
          @ObjectModel.foreignKey.association: '_Plant'
          Plant,

          @UI.lineItem:[{importance:#HIGH } ]
          @ObjectModel.text.element:  [ 'BillOfMaterialVariantUsageDesc' ]
          BillOfMaterialVariantUsage,

          @ObjectModel.readOnly:true
          _BillOfMaterialVariantUsage.BillOfMaterialVariantUsageDesc,

          @UI.lineItem:[{importance:#HIGH } ]
          BillOfMaterialVariant,

          @ObjectModel.readOnly: true
          @Consumption.semanticObject: 'ChangeMaster'
          ChangeNumber,

          @Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
          @ObjectModel.foreignKey.association: '_ProcessingStatusVH'
          ChangeRecordItemProcgStatus,
          @ObjectModel.readOnly: true
          ChgRecdCurrentItemProcgStatus,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
          //          @UI.hidden: true

          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordType            as ChangeRecordType,
          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ChangeRecordReferenceSubtype,
          @UI.hidden: true
          ParentChangeRecordRefUUID,

          @Consumption: { valueHelp: '_ChangeRecordItemRelVH' }
          @ObjectModel: {foreignKey.association: '_ChangeRecordItemRelVH' }
          @ObjectModel.mandatory: true
          ChangeRecordItemRelevance,
          @UI.hidden: true
          ChangeRecordReference,
          @UI.hidden: true
          BillOfMaterial,
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordStatus,

          @Semantics.user.createdBy: true
          @ObjectModel.readOnly: true
          CreatedByUser,
          @UI.hidden: true
          CreationDateTime,

          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
          @ObjectModel.readOnly: true
          cast( '00000000' as /plmb/created_on )         as CreationDate,

          @Semantics.user.lastChangedBy: true
          @ObjectModel.readOnly: true
          LastChangedByUser,
          @UI.hidden: true
          BillOfMaterialCategory,
          @UI.hidden: true
          LastChangeDateTime,

          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
          @ObjectModel.readOnly: true
          cast( '00000000' as /plmb/changed_on )         as LastChangeDate,
          @UI.hidden: true
          @UI.lineItem:[{importance:#HIGH, hidden: true }   ]
          @EndUserText.label: 'Digital Signature Status'
          @ObjectModel.foreignKey.association: '_DigSignStatusText'
          @Consumption: { valueHelp: '_DigSignStatusText' }
          ChgRecdItmDSgntr,

          ChgRecdReasonForChange,

          ExpdCompltnDte,

          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
          ChgRecdAuthznGrpText,

          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
          ChgRecdNmbrChgSts,

          @UI.lineItem:[{
              hidden: true,
              importance:#LOW }
            ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                           as DigitalSignUserIsAuthorized,

          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #LOW, position: 90 }]
          @EndUserText.label: 'Digital Signature Status'
          _DigSignStatusText.ChgRecdDigSignStatusTxt     as ChgRecdDigSignStatusTxt,


          @UI.lineItem:[{
          hidden: true,
          importance:#LOW }
          ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                           as ChgRecdObjDgtlSgntrEnable,


          ChangeRecordVirtualRefInd,
          _Plant,
          _BillOfMaterialVariantUsage,
          _ChangeRecordItemRelVH,
          _ChangeRecordStdBOMVH,
          _ProcessingStatusVH,
          @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
          _ChangeRecordObjPg,
          _ProcessingStatusTxt,
          _DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"I_BILLOFMATERIALUSAGE",
"I_CHANGERECORDREFSTDBOMTP"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_CHANGERECORDSTDBOMVH",
"C_CHGRECDITEMRLVNCESTDBOMVH",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_BILLOFMATERIALUSAGE",
"I_CHGRECDITEMPROCGSTATUSTEXT",
"I_PLANTSTDVH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/