@AbapCatalog.sqlViewName: 'CCHGRECREFPSV'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Record Reference Obj Page Product Structure Variant'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
semanticKey: ['ProductStructureNodeName','Class','ProductStructureVariantName','ProdStrucVariantChangeNumber'],
createEnabled: true,
deleteEnabled,
updateEnabled:'EXTERNAL_CALCULATION' ,
transactionalProcessingDelegated: true
}
@UI.headerInfo:{
typeName: 'Product Structure Variant',
typeNamePlural: 'Product Structure Variants',
imageUrl: 'ProductImageURL',
title:{value:'ProdStrucVariantDescription'}
}
@ObjectModel.usageType: {serviceQuality: #C,
dataClass: #MIXED,
sizeCategory: #XXL}
@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.presentationVariant.requestAtLeast: [ 'ChangeRecordType', 'ChangeRecordReferenceType' ]
define view C_ChgRecdObjPgProdStrucVar
as select from I_ChgRecdRefProdStrucVarTP as ChangeRecordReferencePSVTP
association [0..1] to I_Classvh as _ClassVH on $projection.Class = _ClassVH.Class
association [0..1] to C_ProductStructureNodeVH as _NodeVH on $projection.ProductStructureNodeName = _NodeVH.ProductStructureNodeName
and $projection.Class = _NodeVH.Class
association [0..1] to C_Chgnrvh as _ChangeNumberVH on $projection.ProdStrucVariantChangeNumber = _ChangeNumberVH.ProdStrucVariantChangeNumber
association [0..1] to C_ProductStructureVariantVH as _VariantVH on $projection.Class = _VariantVH.Class
and $projection.ProductStructureNodeName = _VariantVH.ProductStructureNodeName
and $projection.ProductStructureVariantName = _VariantVH.ProductStructureVariantName
and $projection.ProdStrucVariantChangeNumber = _VariantVH.ProdStrucVariantChangeNumber
and (
$projection.Material = _VariantVH.Material
or(
$projection.Material = ''
or $projection.Material is null
)
)
association [1..1] to C_ChgRecdItemRelProdStrucVarVH as _ChgRecdItemRelProdStrucVarVH on $projection.ChangeRecordItemRelevance = _ChgRecdItemRelProdStrucVarVH.ChangeRecordItemRelevance
and $projection.ChangeRecordType = _ChgRecdItemRelProdStrucVarVH.ChangeRecordType
association [0..1] to I_MaterialText as _MaterialText on $projection.Material = _MaterialText.Material
and _MaterialText.Language = $session.system_language
association [1..1] to C_ChangeRecordObjPg as _ChangeRecordObjPg on $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID
association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
and $projection.ChangeRecordLifecycleStatus = _ProcessingStatusVH.ChangeRecordLifecycleStatus
association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
association [0..*] to C_ChangeRecdDigSignStatusVH as _DigSignStatusText on $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{
@UI.hidden: true
//@ObjectModel.readOnly: true
key ChangeRecordReferenceUUID,
@UI.hidden: true
@ObjectModel.readOnly: true
_VariantVH.ProdStrucVariantUniqueID as ProdStrucVariantUniqueID,
@UI.hidden: true
@UI.lineItem:[
{ position:5,
importance:#HIGH }
]
@UI.identification: {position: 5, importance: #HIGH}
@Semantics.imageUrl: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_OBJECT_THUMBNAIL_VE'
cast( '' as productimageurl ) as ProductImageURL,
@ObjectModel.foreignKey.association: '_ClassVH'
@UI.identification: {position: 60, importance: #HIGH}
@UI.lineItem:[
{
position:60,
importance:#HIGH }
]
//@ObjectModel.readOnly: true
Class,
@Consumption: { valueHelp: '_NodeVH' }
@UI.identification: {position: 40, importance: #HIGH}
@UI.lineItem:[
{
position:40,
importance:#HIGH }
]
@EndUserText.label: 'Node'
ProductStructureNodeName,
@UI.identification: {position: 50, importance: #MEDIUM}
@UI.lineItem:[
{
position:50,
importance:#MEDIUM }
]
@ObjectModel.readOnly: true
ProdStrucNodeDescription,
@UI.identification: {position: 10, importance: #HIGH}
@UI.lineItem:[
{
position:10,
importance:#HIGH }
]
@ObjectModel.foreignKey.association: '_VariantVH'
@Consumption: { valueHelp: '_VariantVH' }
ProductStructureVariantName,
@UI.identification: {position: 20, importance: #MEDIUM}
@UI.lineItem:[
{
position:20,
importance:#MEDIUM }
]
@ObjectModel.readOnly: true
ProdStrucVariantDescription,
@UI.identification: {position: 30, importance: #HIGH}
@UI.lineItem:[
{
position:30,
importance:#HIGH }
]
@ObjectModel.foreignKey.association: '_ChangeNumberVH'
//@ObjectModel.readOnly: true
ProdStrucVariantChangeNumber,
@UI.identification: {position: 70, importance: #MEDIUM}
@UI.lineItem:[
{
position:70,
importance:#MEDIUM }
]
//@ObjectModel.readOnly: true
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_MaterialStdVH',
element: 'Material' }
}]
@EndUserText.label: 'Material'
Material,
@UI.identification: {position: 80, importance: #MEDIUM}
@UI.lineItem:[
{
position:80,
importance:#MEDIUM }
]
@ObjectModel.readOnly: true
_MaterialText.MaterialName,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_ChgRecdItemRelProdStrucVarVH'
_ChangeRecordObjPg.ChangeRecordType as ChangeRecordType,
@UI.hidden: true
ChangeRecordUUID,
@UI.hidden: true
ChangeRecordReferenceType,
@UI.hidden: true
ParentChangeRecordRefUUID,
@UI.lineItem:[{
position:90,
importance:#MEDIUM }
]
@Consumption: { valueHelp: '_ChgRecdItemRelProdStrucVarVH' }
@ObjectModel: {foreignKey.association: '_ChgRecdItemRelProdStrucVarVH' }
@UI.identification: {position:90, importance: #MEDIUM}
@ObjectModel.mandatory: true
@UI.textArrangement: #TEXT_ONLY
ChangeRecordItemRelevance,
@UI.hidden: true
ChangeRecordReference,
@ObjectModel.readOnly:true
@UI.hidden: true
_ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordObjPg.ChangeRecordStatus,
@UI.lineItem:[ {position: 100, importance:#MEDIUM } ]
@UI.identification: [{position: 100, importance: #MEDIUM }]
@EndUserText.label: 'Processing Status'
@Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
@ObjectModel.foreignKey.association: '_ProcessingStatusVH'
@UI.textArrangement: #TEXT_FIRST
ChangeRecordItemProcgStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdCurrentItemProcgStatus,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
@UI.hidden: true
@UI.lineItem:[{importance:#MEDIUM, hidden: true } ]
@EndUserText.label: 'Digital Signature Status'
@ObjectModel.foreignKey.association: '_DigSignStatusText'
@Consumption: { valueHelp: '_DigSignStatusText' }
ChgRecdItmDSgntr,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as DigitalSignUserIsAuthorized,
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 110 }]
@EndUserText.label: 'Digital Signature Status'
_DigSignStatusText.ChgRecdDigSignStatusTxt as ChgRecdDigSignStatusTxt,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as ChgRecdObjDgtlSgntrEnable,
@UI.identification: {position: 115, importance: #MEDIUM}
ChgRecdReasonForChange,
@UI.identification: {position: 120, importance: #MEDIUM}
ExpdCompltnDte,
@UI.identification: {position: 125, importance: #MEDIUM}
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
ChgRecdAuthznGrpText,
@UI.identification: {position: 130, importance: #MEDIUM}
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
ChgRecdNmbrChgSts,
@UI.lineItem:[{position:110,importance:#MEDIUM }]
@UI.identification: {position: 110, importance: #MEDIUM}
@ObjectModel.readOnly: true
@Consumption.semanticObject: 'ChangeMaster'
ChangeNumber,
@Semantics.user.createdBy: true
@ObjectModel.readOnly: true
@UI.identification: {position: 135, importance: #MEDIUM}
CreatedByUser,
@UI.hidden: true
CreationDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position:140, importance: #MEDIUM}
cast( '00000000' as /plmb/created_on ) as CreationDate,
@Semantics.user.lastChangedBy: true
@ObjectModel.readOnly: true
@UI.identification: {position: 145, importance: #MEDIUM}
LastChangedByUser,
@UI.hidden: true
LastChangeDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 150, importance: #MEDIUM}
cast( '00000000' as /plmb/changed_on ) as LastChangeDate,
_ClassVH,
_NodeVH,
_VariantVH,
_ChangeNumberVH,
_ChgRecdItemRelProdStrucVarVH,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
_ChangeRecordObjPg,
_ProcessingStatusVH,
_ProcessingStatusTxt,
_DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_PRODUCTSTRUCTUREVARIANTVH",
"I_CHGRECDREFPRODSTRUCVARTP",
"I_MATERIALTEXT"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_CHGNRVH",
"C_CHGRECDITEMRELPRODSTRUCVARVH",
"C_CHGRECORDITEMPROCGSTATUSVH",
"C_PRODUCTSTRUCTURENODEVH",
"C_PRODUCTSTRUCTUREVARIANTVH",
"I_CHGRECDITEMPROCGSTATUSTEXT",
"I_CLASSVH",
"I_MATERIALTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/