@AbapCatalog.sqlViewName: 'CCHGRCDOBJPGBOM'
//@Search.searchable: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Change Record Reference Object BOM'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.preserveKey:true
@ObjectModel.usageType: {serviceQuality: #C,
dataClass: #MIXED,
sizeCategory: #XXL}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
semanticKey: ['Material','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant','ChangeNumberValidFromDate'],
createEnabled: true,
deleteEnabled:'EXTERNAL_CALCULATION',
updateEnabled:'EXTERNAL_CALCULATION' ,
transactionalProcessingDelegated: true
}
@UI.headerInfo:{
typeName: 'Material BOM',
typeNamePlural: 'Material BOMs',
imageUrl: 'ProductImageURL',
title:{value:'MaterialName'}
}
@UI.presentationVariant.requestAtLeast: [ 'ChangeRecordType', 'ChangeRecordLifecycleStatus', 'ChangeRecordReferenceType', 'BillOfMaterial' ]
define view C_ChangeRecordObjPgBOM
as select from I_ChangeRecordReferenceBOMTP as ChangeRecordReferenceBOMTP
association [1..1] to C_ChangeRecordObjPg as _ChangeRecordObjPg on $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID
// association [0..1] to I_ChangeRecordBillOfMaterialVH as _ChangeRecordBillOfMaterialVH on $projection.Material = _ChangeRecordBillOfMaterialVH.Material
// and $projection.Plant = _ChangeRecordBillOfMaterialVH.Plant
// and $projection.BillOfMaterialVariantUsage = _ChangeRecordBillOfMaterialVH.BillOfMaterialVariantUsage
// and $projection.BillOfMaterialVariant = _ChangeRecordBillOfMaterialVH.BillOfMaterialVariant
association [0..1] to I_ChangeRecordBillOfMaterialVH as _ChangeRecordBillOfMaterialVH on $projection.Material = _ChangeRecordBillOfMaterialVH.Material
and $projection.Plant = _ChangeRecordBillOfMaterialVH.Plant
and $projection.BillOfMaterialVariantUsage = _ChangeRecordBillOfMaterialVH.BillOfMaterialVariantUsage
and $projection.BillOfMaterialVariant = _ChangeRecordBillOfMaterialVH.BillOfMaterialVariant
// association [0..1] to I_ChangeRecordBillOfMaterialVH as _ChangeRecordBillOfMaterial on $projection.Material = _ChangeRecordBillOfMaterial.Material
// and $projection.Plant = _ChangeRecordBillOfMaterial.Plant
// and $projection.BillOfMaterialVariantUsage = _ChangeRecordBillOfMaterial.BillOfMaterialVariantUsage
// and $projection.BillOfMaterialVariant = _ChangeRecordBillOfMaterial.BillOfMaterialVariant
association [0..1] to I_Material as _Material on $projection.Material = _Material.Material
association [0..1] to I_PlantStdVH as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_BillOfMaterialUsage as _BillOfMaterialVariantUsage on $projection.BillOfMaterialVariantUsage = _BillOfMaterialVariantUsage.BillOfMaterialVariantUsage
and _BillOfMaterialVariantUsage.Language = $session.system_language
association [1..1] to C_ChangeRecordItemRelBOMVH as _ChangeRecordItemRelBOMVH on $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelBOMVH.ChangeRecordItemRelevance
and $projection.ChangeRecordType = _ChangeRecordItemRelBOMVH.ChangeRecordType
// and $projection.ChangeRecordReferenceType = _ChangeRecordItemRelBOMVH.ChangeRecordReferenceType
association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
and $projection.ChangeRecordLifecycleStatus = _ProcessingStatusVH.ChangeRecordLifecycleStatus
association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
association [0..*] to C_ChgRecdObjPgBOMComponent as _BillOfMaterialItem on $projection.BillOfMaterial = _BillOfMaterialItem.BillOfMaterial
and $projection.BillOfMaterialCategory = _BillOfMaterialItem.BillOfMaterialCategory
and $projection.BillOfMaterialVariant = _BillOfMaterialItem.BillOfMaterialVariant
and $projection.Material = _BillOfMaterialItem.Material
and $projection.Plant = _BillOfMaterialItem.Plant
and _BillOfMaterialItem.ValidityStartDate <= $projection.ChangeNumberValidFromDate
and _BillOfMaterialItem.ValidityEndDate > $projection.ChangeNumberValidFromDate
association [0..*] to C_ChangeRecdDigSignStatusVH as _DigSignStatusText on $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{
--------------------------------------------
// @UI.facet: [
// ----Facets
// {type: #COLLECTION, position: 10, id: 'BOMInfo', label: 'Material BOM Information'},
// {type: #IDENTIFICATION_REFERENCE, position: 10, id: 'BOMRef', parentId: 'BOMInfo', isSummary, isPartOfPreview },
// ----Facets: Attachments
// {type: #COLLECTION, position: 10, id: 'Attachments', label: 'Attachments'}
// ]
--------------------------------------------
@UI.facet: [{ id: 'Charc',
purpose: #STANDARD,
type: #IDENTIFICATION_REFERENCE,
label: 'Material BOM',
position: 10 },
{ id: 'CompValue',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Components',
targetElement: '_BillOfMaterialItem',
position: 20 }]
@UI.hidden: true
@ObjectModel.readOnly: true
// @Consumption.semanticObject: 'MaterialBOM'
// @UI.lineItem:[
// {type: #FOR_INTENT_BASED_NAVIGATION,
// semanticObjectAction: 'Maintenance',
// label: 'Display Material BOM',
// importance:#HIGH} ]
key ChangeRecordReferenceUUID,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordBillOfMaterialVH.BillOfMaterialHeaderUUID as BillOfMaterialHeaderUUID,
@UI.hidden: true
@UI.lineItem:[
{ position:5,
importance:#HIGH }
]
@UI.identification:{position: 5, importance: #HIGH}
@Semantics.imageUrl: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_OBJECT_THUMBNAIL_VE'
cast( '' as productimageurl ) as ProductImageURL,
@UI.lineItem:[{
position:10,
// label: 'Material',
// type: #WITH_URL,
// url: 'BOMUrl',
importance:#HIGH }
]
@UI.identification: {position: 10, importance: #HIGH}
//@Consumption.valueHelp: '_ChangeRecordBillOfMaterialVH'
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ChangeRecordBillOfMaterialVH',
element: 'Material' },
additionalBinding: [{ localElement: 'Plant',
element: 'Plant' },
{ localElement: 'BillOfMaterialVariantUsage',
element: 'BillOfMaterialVariantUsage' },
{ localElement: 'BillOfMaterialVariant',
element: 'BillOfMaterialVariant' }]
}]
@ObjectModel.text.element: [ 'MaterialName' ]
//@ObjectModel.foreignKey.association: '_Material'
//@Consumption.semanticObject: 'MaterialBOM'
Material,
@UI.lineItem:[{
position:20,
importance:#HIGH }
]
@UI.identification: {position: 20, importance: #HIGH}
@ObjectModel.foreignKey.association: '_Plant'
Plant,
@UI.lineItem:[{
position:30,
importance: #MEDIUM }
]
@UI.identification: {position:30, importance: #MEDIUM}
@ObjectModel.foreignKey.association: '_BillOfMaterialVariantUsage'
BillOfMaterialVariantUsage,
@UI.lineItem:[{
position:40,
importance:#HIGH }
]
@UI.identification: {position:40, importance: #HIGH}
BillOfMaterialVariant,
// @ObjectModel.virtualElement : true
// @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_BOM_ECN_CALCULATE'
// @ObjectModel.readOnly: true
// @UI.hidden: true
// cast( '' as aennr ) as EngineeringChangeDocument,
@UI.lineItem:[ {position: 70, importance:#MEDIUM } ]
@UI.identification: [{position: 70, importance: #MEDIUM }]
@EndUserText.label: 'Processing Status'
@Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
@ObjectModel.foreignKey.association: '_ProcessingStatusVH'
@UI.textArrangement: #TEXT_FIRST
ChangeRecordItemProcgStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdCurrentItemProcgStatus,
@ObjectModel.readOnly: true
@UI.hidden: true
_ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.foreignKey.association: '_ChangeRecordItemRelBOMVH'
_ChangeRecordObjPg.ChangeRecordType as ChangeRecordType,
@UI.hidden: true
ChangeRecordUUID,
@UI.hidden: true
ChangeRecordReferenceType,
@UI.hidden: true
ChangeRecordReferenceSubtype,
@UI.hidden: true
ParentChangeRecordRefUUID,
@UI.lineItem:[{
position:60,
importance:#MEDIUM }
]
@Consumption: { valueHelp: '_ChangeRecordItemRelBOMVH' }
@ObjectModel: {foreignKey.association: '_ChangeRecordItemRelBOMVH' }
@UI.identification: {position:60, importance: #MEDIUM}
@UI.textArrangement: #TEXT_ONLY
-- @ObjectModel.mandatory: true
ChangeRecordItemRelevance,
@UI.lineItem:[{position:80,importance:#MEDIUM }]
@UI.identification: {position: 80, importance: #MEDIUM}
@ObjectModel.readOnly: true
@Consumption.semanticObject: 'ChangeMaster'
ChangeNumber,
@UI.hidden: true
@ObjectModel.readOnly: true
_Material._Text[1:Language = $session.system_language].MaterialName as MaterialName,
@UI.hidden: true
ChangeRecordReference,
@ObjectModel.readOnly:true
@UI.hidden: true
_ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
//For BOM Navigation
@UI.hidden: true
BillOfMaterial,
@UI.hidden: true
@ObjectModel.readOnly: true
ChangeRecordStatus,
@Semantics.user.createdBy: true
@ObjectModel.readOnly: true
@UI.identification: [{importance:#MEDIUM , position: 110 }]
CreatedByUser,
@UI.hidden: true
CreationDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 115, importance: #MEDIUM}
cast( '00000000' as /plmb/created_on ) as CreationDate,
@Semantics.user.lastChangedBy: true
@ObjectModel.readOnly: true
@UI.identification: {position: 120, importance: #MEDIUM}
LastChangedByUser,
@UI.hidden: true
BillOfMaterialCategory,
@UI.hidden: true
LastChangeDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 125, importance: #MEDIUM}
cast( '00000000' as /plmb/changed_on ) as LastChangeDate,
@UI.hidden: true
ChangeRecordVirtualRefInd,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdItmTgtSts,
@UI.hidden: true
@UI.lineItem:[{importance:#MEDIUM, hidden: true } ]
@EndUserText.label: 'Digital Signature Status'
@ObjectModel.foreignKey.association: '_DigSignStatusText'
@Consumption: { valueHelp: '_DigSignStatusText' }
ChgRecdItmDSgntr,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as DigitalSignUserIsAuthorized,
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 105 }]
@EndUserText.label: 'Digital Signature Status'
_DigSignStatusText.ChgRecdDigSignStatusTxt as ChgRecdDigSignStatusTxt,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as ChgRecdObjDgtlSgntrEnable,
ChgRecdReasonForChange,
ExpdCompltnDte,
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
ChgRecdAuthznGrpText,
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
ChgRecdNmbrChgSts,
@UI.hidden: true
@ObjectModel.readOnly: true
ChangeNumberValidFromDate,
_Material,
_Plant,
_BillOfMaterialVariantUsage,
_ChangeRecordItemRelBOMVH,
_ChangeRecordBillOfMaterialVH,
_ProcessingStatusVH,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
_ChangeRecordObjPg,
_ProcessingStatusTxt,
_DigSignStatusText,
_BillOfMaterialItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"I_CHANGERECORDREFERENCEBOMTP",
"I_MATERIAL",
"I_MATERIALTEXT"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDITEMRELBOMVH",
"C_CHANGERECORDOBJPG",
"C_CHGRECDOBJPGBOMCOMPONENT",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_BILLOFMATERIALUSAGE",
"I_CHANGERECORDBILLOFMATERIALVH",
"I_CHGRECDITEMPROCGSTATUSTEXT",
"I_MATERIAL",
"I_PLANTSTDVH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/