C_ChangeRecordCharcVal

@AbapCatalog.sqlViewName: 'CHGRECCHARVAL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.privilegedAssociations: ['_Currency']
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Characteristic Value'
@ObjectModel.representativeKey: 'Characteristic'
@AbapCatalog.preserveKey:true
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #S}
@ObjectModel.resultSet.sizeCategory: #XS
@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.presentationVariant: [{ sortOrder: [{ by: 'CharcValuePositionNumber', direction: #ASC },{ by: 'CharcFromTime', direction: #DESC }] }]
define view C_ChangeRecordCharcVal
  as select distinct from  I_ChangeRecordRefCharcTP as ChangeRecordRefCharcTP

    left outer to one join I_ClfnCharcValue         as _CharcValue on ChangeRecordRefCharcTP.CharcInternalID = _CharcValue.CharcInternalID

  association [0..*] to I_ClfnCharcValueDesc       as _CharcValueDesc on  $projection.CharcInternalID          = _CharcValueDesc.CharcInternalID
                                                                      and $projection.CharcValuePositionNumber = _CharcValueDesc.CharcValuePositionNumber

  association [0..1] to I_ChgRecdRefCharcValDpndcy as _Charc          on  $projection.CharcInternalID          = _Charc.CharcInternalID
                                                                      and $projection.CharcValuePositionNumber = _Charc.CharcValuePositionNumber


{


  key  ChangeRecordRefCharcTP.Characteristic,
  key  _CharcValue.CharcValuePositionNumber,
       ChangeRecordRefCharcTP.CharcInternalID,
       ChangeRecordRefCharcTP.CharcDataType,
       @UI.lineItem:[
             { position:10,
               importance:#HIGH }
             ]
       @UI.identification: {position: 10, importance: #HIGH}
       _CharcValue.CharcValue,

       @UI.lineItem:[
             { position:20,
               label: 'Description'}
             ]
       @UI.identification: {position: 20, importance: #HIGH}
       _CharcValueDesc[1:Language = $session.system_language].CharcValueDescription,

       fltp_to_dec( _CharcValue.CharcFromNumericValue as abap.dec(10,0) ) as CharcFromNumericValue,
       fltp_to_dec( _CharcValue.CharcToNumericValue as abap.dec(10,0) )   as CharcToNumericValue,

       @UI.lineItem:[
              { position:30,
                label: 'Default Value'}
              ]
       @UI.identification: {position: 30}
       cast(  _CharcValue.IsDefaultValue as boolean )                     as IsDefaultValue,

       @UI.lineItem:[
              { position:50,
                label: 'Subordinate Values Exist'}
              ]
       @UI.identification: {position: 50}
       _CharcValue.CharcValueHasChild,

       @UI.lineItem:[
              { position:40,
                label: 'Object Dependencies Exist'}
              ]
       @UI.identification: {position: 20}
       cast( _Charc.ObjDpnAssignmentNumber as boolean)                    as ObjDpnIsAssigned,
       //_Charc.ObjDpnAssignmentNumber,

       _CharcValue.CharcFromDate,
       _CharcValue.CharcToDate,
       _CharcValue.CharcFromTime,
       _CharcValue.CharcToTime,

       @Semantics.amount.currencyCode: 'Currency'
       _CharcValue.CharcFromAmount                                        as CharcFromAmount,
       @Semantics.amount.currencyCode: 'Currency'
       _CharcValue.CharcToAmount                                          as CharcToAmount,
       @ObjectModel.foreignKey.association: '_Currency'
       @Semantics.currencyCode: true
       _CharcValue.Currency                                               as Currency,
       _CharcValue._Currency

}
where
      ChangeRecordRefCharcTP.Characteristic is not null
  and ChangeRecordRefCharcTP.Characteristic <> ''
  and _CharcValue.ValidityEndDate           >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGERECORDREFCHARCTP",
"I_CHGRECDREFCHARCVALDPNDCY",
"I_CLFNCHARCVALUE",
"I_CLFNCHARCVALUEDESC"
],
"ASSOCIATED":
[
"I_CHGRECDREFCHARCVALDPNDCY",
"I_CLFNCHARCVALUEDESC",
"I_CURRENCY"
],
"BASE":
[
"I_CLFNCHARCVALUE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/