@AbapCatalog.sqlViewName: 'CCHGMASTEROBJPG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: [
'_ChangeMasterLogAccMActive' ,
'_ChgMstrLogAccMSecureIDAssgmt',
'_ChangeMstrLogAccMUserAuthzn' ]
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #NONE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.semanticKey: ['ChangeNumber']
@UI.headerInfo: {
typeName: 'Change Master',
typeNamePlural: 'Change Masters',
title: { type: #STANDARD, value: 'ChangeNumberDescription' },
description: { type: #STANDARD, value: 'ChangeNumber' }
}
@Search.searchable: true
@UI.presentationVariant.requestAtLeast: [ 'ChangeNumber' ]
@UI.presentationVariant.sortOrder.by: 'ChangeNumberCreationDate'
@UI.presentationVariant.sortOrder.direction: #DESC
@EndUserText.label: 'Manage Change Masters'
define view C_ChangeMasterObjPg
as select from I_ChangeMaster
association [0..*] to C_ChangeMasterObjTypeAssgmt as _ChangeMasterObjTypeAssgmt on _ChangeMasterObjTypeAssgmt.ChangeNumber = $projection.ChangeNumber
association [0..*] to C_ChangeMasterAltDate as _ChangeMasterAltDate on _ChangeMasterAltDate.ChangeNumber = $projection.ChangeNumber
{
// @Consumption.valueHelpDefinition: [
// { entity: { name: 'I_ChangeMasterVH',
// element: 'ChangeNumber' }
// }]
@Consumption.semanticObject:'ChangeMaster'
@UI:{
selectionField:[{ position: 20 }],
lineItem: [{position:20,importance: #HIGH, type: #STANDARD }]
}
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
@ObjectModel.text.association: null
@ObjectModel.text.element: null
key ChangeNumber,
@UI:{
fieldGroup: [{qualifier:'@StatusInfoOP', position:20}]
}
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_Indicator',
element: 'IndicatorValue' }
}]
_ChangeNumberStatus.ChangeIsAllowed,
@UI:{
fieldGroup: [{qualifier:'@StatusInfoOP', position:30}]
}
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_Indicator',
element: 'IndicatorValue' }
}]
_ChangeNumberStatus.DateChangeIsAllowed,
@UI:{ fieldGroup: [{qualifier:'@StatusInfoOP', position:40}]}
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_Indicator',
element: 'IndicatorValue' }
}]
_ChangeNumberStatus.DistributionIsLocked,
@UI:{
selectionField:[{ position: 40 }],
lineItem: [{position:40,importance: #HIGH, type: #STANDARD }],
fieldGroup: [{qualifier:'@StatusInfoOP', position:10, groupLabel: 'Status Information'}],
textArrangement: #TEXT_FIRST
}
@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
ChangeNumberStatus,
@UI:{
selectionField:[{ position: 50 }],
lineItem: [{position:50,importance: #HIGH, type: #STANDARD }]
}
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ChangeMasterAuthznGroupVH',
element: 'AuthorizationGroup' }
}]
AuthorizationGroup,
@UI: {
fieldGroup: [{qualifier:'@GeneralInfoOP', position:60, groupLabel: 'General Information'}],
textArrangement: #TEXT_FIRST
}
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
ChangeNumberFunction,
@UI: {
fieldGroup: [
{qualifier:'@StatusInfoOP', position:50, groupLabel: 'Status Information'}
],
textArrangement: #TEXT_FIRST
}
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
ChangeNumberReleaseKey,
@UI.hidden: true
cast (case
when ChangeNumberReleaseKey = '00'
then ''
else
_ChangeNumberReleaseKey._Text[1:Language = $session.system_language].ChangeNumberReleaseKeyText
end as /plmb/ecn_relkey_desc preserving type ) as ChangeNumberRelKeyTextCnvrtd,
@UI.hidden: true
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
_ChangeNumberReleaseKey._Text[1:Language = $session.system_language].ChangeNumberReleaseKeyText,
@UI:{
fieldGroup: [{qualifier:'@GeneralInfoOP', position:10, groupLabel: 'General Information'}]
}
ReasonForChangeText,
@UI:{
selectionField:[{ position: 10 }],
lineItem: [{position:10,importance: #HIGH, type: #STANDARD }]
}
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
ChangeNumberDescription,
@UI:{
selectionField:[{ position: 30 }],
lineItem: [{position:30,importance: #HIGH, type: #STANDARD }],
dataPoint.title: 'Valid From'
}
@Consumption.filter.selectionType: #INTERVAL
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
ChangeNumberValidFromDate,
@UI:{
fieldGroup: [{qualifier:'@AdminInfoOP', position:10, groupLabel: 'Administrative Information'},
{qualifier:'AdditionalFilters', position:10, groupLabel: 'Administrative Information'}]
}
@Consumption.filter.selectionType: #INTERVAL
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
ChangeNumberCreationDate,
@UI:{
fieldGroup: [{qualifier:'@AdminInfoOP', position:20},
{qualifier:'AdditionalFilters', position:20, groupLabel: 'Administrative Information'}],
textArrangement: #TEXT_FIRST
}
@ObjectModel.text.element: 'CreatedByUserName'
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ChangeMasterCreatedByVH',
element: 'ChangeNumberCreatedByUser' }
}]
ChangeNumberCreatedByUser,
@UI.hidden: true
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
_CreatedByUser.UserDescription as CreatedByUserName,
@UI:{
fieldGroup: [{qualifier:'@AdminInfoOP', position:30},
{qualifier:'AdditionalFilters', position:30, groupLabel: 'Administrative Information'}]
}
@Consumption.filter.selectionType: #INTERVAL
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
ChangeNumberLastChangedDate,
@UI:{
fieldGroup: [{qualifier:'@AdminInfoOP', position:40},
{qualifier:'AdditionalFilters', position:40, groupLabel: 'Administrative Information'}],
textArrangement: #TEXT_FIRST
}
@ObjectModel.text.element: 'LastChangedByUserName'
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_ChangeMasterChangedByVH',
element: 'ChangeNumberLastChangedByUser' }
}]
ChangeNumberLastChangedByUser,
@UI.hidden: true
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
_LastChangedByUser.UserDescription as LastChangedByUserName,
@UI:{
lineItem: [{position:60,importance: #HIGH, type: #STANDARD }],
fieldGroup: [{qualifier:'@GeneralInfoOP', position:30}]
}
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_Indicator',
element: 'IndicatorValue' }
}]
// @EndUserText.label: 'In Use'
IsUsedForDataDefinition,
@UI:{
fieldGroup: [{qualifier:'@GeneralInfoOP', position:40}]
}
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_Indicator',
element: 'IndicatorValue' }
}]
ChangeNumberIsMrkdForDeletion,
/* Field Controls */
@UI.hidden: true
case
when ChangeNumberReleaseKey = '00' // (With release key)
then cast (0 as fdc_ux_fc preserving type ) // Hide
else cast (1 as fdc_ux_fc preserving type ) // Show
end as UxFcChangeNumberReleaseKey,
/* Associations */
_ChangeMasterObjTypeAssgmt,
_ChangeMasterAltDate,
@Consumption.filter.hidden: true
_ChangeNumberReleaseKey,
@Consumption.filter.hidden: true
_ChangeNumberStatus,
@Consumption.filter.hidden: true
_ChangeNumberFunction,
// Access Control Management integration with C1 released views, used in DCL
@Consumption.hidden:true
_ChangeMasterLogAccMActive,
@Consumption.hidden:true
_ChgMstrLogAccMSecureIDAssgmt,
@Consumption.hidden:true
_ChangeMstrLogAccMUserAuthzn
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEMASTER",
"I_CHANGEMASTERRELEASEKEY",
"I_CHANGEMASTERRELEASEKEYTEXT",
"I_CHANGEMASTERSTATUS",
"I_USER"
],
"ASSOCIATED":
[
"C_CHANGEMASTERALTDATE",
"C_CHANGEMASTEROBJTYPEASSGMT",
"I_CHANGEMASTERFUNCTION",
"I_CHANGEMASTERLOGACCMACTIVE",
"I_CHANGEMASTERRELEASEKEY",
"I_CHANGEMASTERSTATUS",
"I_CHANGEMSTRLOGACCMUSERAUTHZN",
"I_CHGMSTRLOGACCMSECUREIDASSGMT"
],
"BASE":
[
"I_CHANGEMASTER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/