C_CZ_StRpTxItmWithEUTxClCrrtnC

@AbapCatalog.sqlViewName: 'CSRCZEUTXCLFNCC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@Analytics.dataCategory: #CUBE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'EU Sales Tax Item View - Correction Run'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions:true


define view C_CZ_StRpTxItmWithEUTxClCrrtnC
  with parameters

    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id,
    P_DocumentType  : farp_blart

  as select from I_StRpTaxItmWithEUTaxClass

        left outer join I_JournalEntry on
          I_StRpTaxItmWithEUTaxClass.CompanyCode = I_JournalEntry.CompanyCode and
          I_StRpTaxItmWithEUTaxClass.FiscalYear = I_JournalEntry.FiscalYear and
          I_StRpTaxItmWithEUTaxClass.AccountingDocument = I_JournalEntry.AccountingDocument

        left outer join P_CZ_StRpRptdTxItmWithEUTxClfn
              ( P_StatryRptgEntity  :$parameters.P_StatryRptgEntity ,
                P_StatryRptCategory :$parameters.P_StatryRptCategory,
                P_StatryRptRunID    :$parameters.P_StatryRptRunID ) as ReportedTaxItems
              on I_StRpTaxItmWithEUTaxClass.CompanyCode = ReportedTaxItems.CompanyCode
              and I_StRpTaxItmWithEUTaxClass.AccountingDocument = ReportedTaxItems.AccountingDocument
              and I_StRpTaxItmWithEUTaxClass.FiscalYear = ReportedTaxItems.FiscalYear

{
  key I_StRpTaxItmWithEUTaxClass.CompanyCode,
  key I_StRpTaxItmWithEUTaxClass.AccountingDocument,
  key I_StRpTaxItmWithEUTaxClass.FiscalYear,
  key TaxCode,
  key TransactionTypeDetermination,
  key TaxItem,
  key I_StRpTaxItmWithEUTaxClass.StatryRptCategory,
  key I_StRpTaxItmWithEUTaxClass.StatryRptRunID,
  key I_StRpTaxItmWithEUTaxClass.StatryRptgEntity,
      Debtor,
      case IsOneTimeAccount
        when 'X' then _OneTimeAccount.BusinessPartnerName1
        else CustomerName
      end as CustomerName,
      I_StRpTaxItmWithEUTaxClass.VATRegistration,
      TaxItemGroup,
      TaxJurisdiction,
      I_StRpTaxItmWithEUTaxClass.Country,
      @Semantics.currencyCode:true
      ReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast((AmountInReportingCurrency * -1) as glo_amount_rptg_crcy) as AmountInReportingCurrency,
      ReportingCountry,
      I_StRpTaxItmWithEUTaxClass.IsReversal,
      I_StRpTaxItmWithEUTaxClass.IsReversed,
      TaxableEntity,
      ReportingDate,
      I_StRpTaxItmWithEUTaxClass.PostingDate,
      I_StRpTaxItmWithEUTaxClass.DocumentDate,
      I_StRpTaxItmWithEUTaxClass.TaxReportingDate,
      I_StRpTaxItmWithEUTaxClass.IsEUTriangularDeal,
      DelivOfGoodsDestCountry,
      DelivOfGoodsOriginCountry,
      EUTaxClassification,
      I_StRpTaxItmWithEUTaxClass.TaxType,
      I_JournalEntry.ReverseDocument,

      cast((case
        when EUTaxClassification = '3' or EUTaxClassification = '4' then '3' //Services

        when EUTaxClassification = '1' and AccountingDocumentType = :P_DocumentType then '1' //Relocation of asset

        when EUTaxClassification = '1' and IsEUTriangularDeal = 'X' then '2' //Triangular deal

        when EUTaxClassification = '1' then '0' //Goods

      end) as ficz_ecsl_operation_key) as OfficialTaxOperationKey,

      cast((case
        when ReportedTaxItems.AccountingDocument is not null then '1'
        else '0'
      end) as ficz_ecsl_document_status) as InternalDocumentStatus,
      BusinessPartner,
      BusinessPartnerName

}
where
      ReportingCountry = 'CZ'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"I_ONETIMEACCOUNTBP",
"I_STRPTAXITMWITHEUTAXCLASS",
"P_CZ_STRPRPTDTXITMWITHEUTXCLFN"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/